Contiene el objeto de visualización raíz del archivo SWF o el archivo de imagen (JPG, PNG o GIF) que se cargó empleando los métodos load() o loadBytes().

Véase también

Devuelve un objeto LoaderInfo que corresponde al objeto que se está cargando. Los objetos LoaderInfo se comparten entre el objeto Loader y el objeto de contenido cargado. El objeto LoaderInfo proporciona información de progreso de carga y estadísticas sobre el archivo cargado.

Los eventos relacionados con la carga se distribuyen mediante el objeto LoaderInfo al que hace referencia la propiedad contentLoaderInfo del objeto Loader. La propiedad contentLoaderInfo se establece como un objeto LoaderInfo válido, antes incluso de que se cargue el contenido, de modo que se puedan añadir detectores de eventos al objeto antes de la carga.

Véase también

Crea un objeto Loader que puede utilizar para cargar archivos como, por ejemplo, archivos SWF, JPEG, GIF o PNG. Llame al método load() para cargar el activo como elemento secundario de la instancia de Loader. Posteriormente, puede añadir el objeto Loader a la lista de visualización (por ejemplo, empleando el método addChild() de una instancia de DisplayObjectContainer). El activo aparece en el escenario conforme se va cargando.

También puede utilizar una instancia "offlist" de Loader, es decir, sin añadirla a un contenedor de objeto de visualización de la lista de visualización. En este modo, la instancia de Loader podría utilizarse para cargar un archivo SWF que contuviera módulos adicionales de una aplicación.

Para detectar cuándo termina de cargarse el archivo SWF, puede utilizar los eventos del objeto LoaderInfo asociado a la propiedad contentLoaderInfo del objeto Loader. Al llegar a ese punto, puede ejecutarse el código del archivo SWF de módulo para inicializar e iniciar el módulo. En el modo offlist (fuera de la lista), una instancia de Loader podría utilizarse para cargar un archivo SWF que contuviera componentes o elementos multimedia adicionales. Una vez más, puede utilizar las notificaciones de eventos de objeto LoaderInfo para detectar cuándo terminan de cargarse los componentes. Al llegar a este punto, la aplicación puede comenzar a utilizar los componentes y elementos multimedia de la biblioteca del archivo SWF mediante la creación de instancias de las clases de ActionScript 3.0 que representan a dichos componentes y elementos.

Para determinar el estado de un objeto Loader, controle los siguientes eventos del objeto LoaderInfo asociado a la propiedad contentLoaderInfo del objeto Loader:

• El evento open se distribuye cuando comienza la carga.
• El evento ioError o securityError se distribuye si el archivo no se puede cargar o si se produce un error durante el proceso de carga.
• El evento progress se activa continuamente mientras se está cargando el archivo.
• El evento complete se distribuye cuando finaliza la descarga de un archivo, pero antes de que estén disponibles los métodos y propiedades del clip de película cargado.
• El evento init se distribuye una vez que estén accesibles las propiedades y los métodos del archivo SWF cargado, de manera que pueda comenzar a manipular el archivo SWF cargado. Se distribuye este evento antes que el controlador complete. Al transmitir mediante flujo archivos SWF, el evento init puede tener lugar bastante antes que el evento complete. En la mayoría de los casos, utilice el controlador init.

Véase también

Cancela una operación de método load() que está actualmente en curso para la instancia de Loader.

Véase también

Carga un archivo SWF, JPEG, JPEG progresivo, GIF sin animar o PNG en un objeto que es un elemento secundario de este objeto Loader. Si carga un archivo GIF animado, sólo aparece el primer fotograma. Dado que el objeto Loader sólo puede contener un único elemento secundario, la emisión de una solicitud load() posteriormente pone fin a la solicitud anterior, si ésta continúa pendiente, y comienza una nueva carga.

Un archivo SWF o imagen cargada en un objeto Loader hereda las propiedades de posición, giro y escala de los objetos de visualización principales del objeto Loader.

Utilice el método unload() para eliminar películas o imágenes cargadas con este método o cancelar una operación de carga que se encuentra en curso.

Cuando utilice el método load(), tenga en cuenta el modelo de seguridad de Flash Player:

• Puede cargar contenido de cualquier origen accesible.
• No se admite la carga si el archivo SWF que realiza la llamada se encuentra en el entorno limitado de red y el archivo que debe cargarse está en un sistema local.
• Si el contenido cargado es un archivo SWF, un archivo SWF de otro entorno limitado de seguridad no podrá usar sus scripts, a no ser que dicho uso de scripts haya sido aprobado a través de una llamada al método Security.allowDomain() del archivo del contenido cargado.
• Los archivos SWF escritos en ActionScript 1.0 o 2.0, que se cargan como objetos AVM1Movie, no pueden utilizar los scripts de archivos SWF escritos en ActionScript 3.0, que se cargan como objetos Sprite o MovieClip. Puede utilizar la clase LocalConnection para que estos archivos se comuniquen entre sí.
• Si el contenido cargado es una imagen, un archivo SWF situado fuera del entorno limitado de seguridad no podrá obtener acceso a sus datos, a no ser que el dominio de dicho archivo SWF se haya incluido en un archivo de política de varios dominios en el dominio de origen de la imagen.
• Es posible que los clips de película del entorno limitado local con el sistema de archivos no puedan utilizar scripts de clips de película en el entorno limitado local con acceso a la red y viceversa.
• Asimismo, se puede impedir que un archivo SWF utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.

Para más información, consulte las siguientes secciones:

• El capítulo de seguridad de la guía Programación con ActionScript 3.0 y los últimos comentarios realizados en LiveDocs
• El documento técnico sobre la seguridad de Flash Player 9

Parámetros

Véase también

Se carga a partir de datos binarios almacenados en un objeto ByteArray.

Parámetros

Véase también

Elimina un elemento secundario del objeto Loader que se cargó utilizando el método load(). El elemento property (propiedad) del objeto LoaderInfo asociado se restablece con el valor null. El elemento secundario no se destruye necesariamente, ya que otros objetos pueden contener referencias a él; sin embargo, deja de ser elemento secundario del objeto Loader.

La práctica más recomendable consiste en cerrar explícitamente los flujos de los objetos de un archivo SWF secundario como, por ejemplo, los objetos LocalConnection, NetConnection, NetStream y Sound, antes de descargar dicho archivo SWF secundario. En caso contrario, podría continuar reproduciéndose el sonido del archivo SWF secundario aunque se hubiera descargado el archivo SWF secundario. Para cerrar los flujos del archivo SWF secundario, añada un detector de eventos al elemento secundario que detecte el evento unload. Cuando el elemento principal llame a Loader.unload(), se distribuirá el evento unload al elemento secundario. En el ejemplo siguiente, se muestra cómo puede lograr esto:

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Véase también

1. Se crea una propiedad url, que es la ubicación y el nombre del archivo de imagen.
2. En el constructor LoaderExample, se crea un nuevo objeto Loader denominado loader que, a continuación, se transfiere al método configureListeners(), descrito en el paso 3.
3. El constructor crea una nueva instancia de un objeto URLRequest, request, con url para que se conozcan el nombre del archivo y la ubicación.
4. El objeto request se transfiere seguidamente al método loader del objeto load(), que carga la imagen en la lista de visualización.
5. Se registra un detector de eventos clickHandler para el evento click en el cargador. Tras un clic del ratón, se descarga la imagen cargada.
6. El método configureListeners() añade siete detectores de eventos con los siguientes métodos:
   • El método completeHandler() se ejecuta cuando termina de cargarse la imagen.
   • El método httpStatusHandler() se ejecuta si la imagen no se carga localmente y sólo si la solicitud de red queda disponible y Flash Player puede detectarla.
   • El método initHandler() se ejecuta antes del método completeHandler() y después del método progressHandler(). Normalmente, el evento init resulta más útil al cargar los archivos SWF.
   • El método ioErrorHandler() se ejecuta si el archivo de imagen no se encuentra disponible o no está accesible.
   • El método openHandler() se ejecuta cuando se abre por primera vez el archivo de imagen.
   • El método progressHandler() se ejecuta cuando el archivo de imagen comienza a cargarse y de nuevo cuando la imagen termina de cargarse.
   • El método unLoadHandler() se ejecuta cuando la imagen se descarga con el método unload() al hacer el usuario clic en la imagen.

Recuerde los siguientes requisitos:

• este ejemplo requiere que coloque un archivo denominado Image.gif en el mismo directorio que el archivo SWF compilado. Utilice una imagen que tenga un área que se ajuste a las dimensiones del archivo SWF principal.
• Aunque en este ejemplo se utilizan todos los eventos disponibles en el objeto LoaderInfo, en la mayoría de los casos sólo se requiere un subconjunto. En especial, al cargar sólo un archivo de imagen, el evento complete (y quizás el evento ioError) son suficientes al cargar una imagen local.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}