Rellena un área de dibujo con una imagen de mapa de bits. El mapa de bits rellena el área a base de repeticiones o mosaicos. El relleno surtirá efecto hasta que llame al método beginFill(), beginBitmapFill() o beginGradientFill(). Al llamar al método clear(), se borra el relleno.

Flash Player no muestra el relleno hasta que se llama al método endFill().

Parámetros

  matrix = new flash.geom.Matrix();
  matrix.rotate(Math.PI/4);
  

Véase también

package {
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.geom.Matrix;

    public class Graphics_beginBitmapFillExample extends Sprite {

        private var url:String = "image1.jpg";
        private var loader:Loader = new Loader();

        public function Graphics_beginBitmapFillExample() {

            var request:URLRequest = new URLRequest(url);

            loader.load(request);
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, drawImage);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function drawImage(event:Event):void {

            var mySprite:Sprite = new Sprite();
            var myBitmap:BitmapData = new BitmapData(loader.width, loader.height, false);

            myBitmap.draw(loader, new Matrix());

            var matrix:Matrix = new Matrix();
            matrix.rotate(Math.PI/4);

            mySprite.graphics.beginBitmapFill(myBitmap, matrix, true);
            mySprite.graphics.drawRect(100, 50, 200, 90);
            mySprite.graphics.endFill();

            addChild(mySprite);
        }

         private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}

Especifica un relleno simple de un solo color que Flash Player utiliza para las posteriores llamadas a otros métodos de Graphics (como, por ejemplo, lineTo() o drawCircle()) para el objeto. El relleno surtirá efecto hasta que llame al método beginFill(), beginBitmapFill() o beginGradientFill(). Al llamar al método clear(), se borra el relleno.

Flash Player no muestra el relleno hasta que se llama al método endFill().

Parámetros

Véase también

Especifica un relleno degradado que Flash Player utiliza para las posteriores llamadas a otros métodos de Graphics (como, por ejemplo, lineTo() o drawCircle()) para el objeto. El relleno surtirá efecto hasta que llame al método beginFill(), beginBitmapFill() o beginGradientFill(). Al llamar al método clear(), se borra el relleno.

Flash Player no muestra el relleno hasta que se llama al método endFill().

Parámetros

	type:String — Un valor de la clase GradientType que especifica el tipo de degradado que debe utilizarse: GradientType.LINEAR o GradientType.RADIAL.
	colors:Array — Matriz de valores de color RGB hexadecimales que se utiliza en el degradado; por ejemplo, rojo es 0xFF0000, azul es 0x0000FF, etc. Puede utilizar hasta 15 colores. Para cada color, asegúrese de especificar un valor correspondiente en los parámetros de alfas y proporciones.
	alphas:Array — Matriz de valores alfa para los colores correspondientes de la matriz de colores; los valores válidos son del 0 al 100. Si el valor es inferior a 0, el valor predeterminado es 0. Si el valor es superior a 1, el valor predeterminado es 1.
	ratios:Array — Matriz de proporciones de distribución de color; los valores válidos van de 0 a 255. Este valor define el porcentaje de la anchura donde el color se muestrea al 100%. El valor 0 representa la posición izquierda del cuadro de degradado, mientras que 255 representa la posición derecha del cuadro de degradado. Nota: este valor representa posiciones del cuadro de degradado, no el espacio de coordenadas del degradado final, que podría ser más ancho o más delgado que el cuadro de degradado. Introduzca un valor con el parámetro colors. Por ejemplo, en el caso de un degradado lineal con dos colores, azul y verde, el siguiente ejemplo ilustra la colocación de los colores en el degradado en función de los diferentes valores en la matriz ratios: ratios Degradado [0, 127] [0, 255] [127, 255] Los valores de la matriz deben aumentar secuencialmente; por ejemplo, [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — Matriz de transformación definida por la clase flash.geom.Matrix. La clase flash.geom.Matrix incluye un método createGradientBox() que permite configurar cómodamente la matriz para utilizarla con el método beginGradientFill().
	spreadMethod:String (default = "pad") — Un valor de la clase SpreadMethod que especifica el modo de extensión que debe utilizarse: SpreadMethod.PAD, SpreadMethod.REFLECT o SpreadMethod.REPEAT. Por ejemplo, imagine un degradado lineal sencillo entre dos colores: import flash.geom.* import flash.display.* var fillType:String = GradientType.LINEAR; var colors:Array = [0xFF0000, 0x0000FF]; var alphas:Array = [1, 1]; var ratios:Array = [0x00, 0xFF]; var matr:Matrix = new Matrix(); matr.createGradientBox(20, 20, 0, 0, 0); var spreadMethod:String = SpreadMethod.PAD; this.graphics.beginGradientFill(fillType, colors, alphas, ratios, matr, spreadMethod); this.graphics.drawRect(0,0,100,100); En este caso se utiliza SpreadMethod.PAD como método de extensión, por lo que el relleno con degradado tendrá este aspecto: Si utiliza SpreadMethod.REFLECT como método de extensión, el relleno con degradado tendrá este aspecto: Si utiliza SpreadMethod.REPEAT como método de extensión, el relleno con degradado tendrá este aspecto:
	interpolationMethod:String (default = "rgb") — Valor de la clase InterpolationMethod que especifica el valor que debe utilizarse: InterpolationMethod.linearRGB o InterpolationMethod.RGB Por ejemplo, imagine un degradado lineal sencillo entre dos colores (con el parámetro spreadMethod definido como SpreadMethod.REFLECT). Los diferentes métodos de interpolación afectan al aspecto de este modo: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Número que controla la ubicación del punto focal del degradado. El valor 0 significa que el punto focal está en el centro. El valor 1 significa que el punto focal se encuentra en un borde del círculo del degradado. El valor -1 significa que el punto focal se encuentra en el otro borde del círculo del degradado. Un valor menor que -1 o mayor que 1 se redondea a -1 o 1. Por ejemplo, en el ejemplo siguiente, se muestra focalPointRatio definido en 0,75:

Véase también

Borra el gráfico que se había dibujado en este objeto Graphics y restablece la configuración de relleno y estilo de línea.

Dibuja una curva con el estilo de línea actual desde la posición de dibujo actual hasta (anchorX, anchorY) utilizando el punto de control especificado con (controlX, controlY). La posición de dibujo actual se establece entonces como (anchorX, anchorY). Si el clip de película en el que está dibujando incluye contenido creado con las herramientas de dibujo de Flash, las llamadas al método curveTo() se dibujarán debajo de este contenido. Si llama al método curveTo() antes de realizar ninguna llamada al método moveTo(), la posición predeterminada para el dibujo actual será (0, 0). Si falta alguno de los parámetros, este método fallará y la posición del dibujo actual no cambiará.

La curva dibujada es una curva cuadrática de Bézier. Las curvas cuadráticas de Bézier constan de dos puntos de anclaje y un punto de control. La curva interpola los dos puntos de anclaje y se dirige al punto de control.

Parámetros

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_curveToExample1 extends Sprite
    {
        public function Graphics_curveToExample1():void
        {
            var roundObject:Shape = new Shape();

            roundObject.graphics.beginFill(0x00FF00);
            roundObject.graphics.moveTo(250, 0);
            roundObject.graphics.curveTo(300, 0, 300, 50);
            roundObject.graphics.curveTo(300, 100, 250, 100);
            roundObject.graphics.curveTo(200, 100, 200, 50);
            roundObject.graphics.curveTo(200, 0, 250, 0);
            roundObject.graphics.endFill();

            this.addChild(roundObject);
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_curveToExample2 extends Sprite
    {
        public function Graphics_curveToExample2() {
            var newMoon:Shape = new Shape();

            newMoon.graphics.lineStyle(1, 0);
            newMoon.graphics.beginFill(0xFFFFFF);
            newMoon.graphics.moveTo(100, 100);
            newMoon.graphics.curveTo(30, 150, 100, 200);
            newMoon.graphics.curveTo(50, 150, 100, 100);
            graphics.endFill();

            this.addChild(newMoon);
        }
    }
}

Dibuja un círculo. Debe establecer el estilo de línea, el relleno o ambos antes de llamar al método drawCircle() llamando al método linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() o beginBitmapFill().

Parámetros

Véase también

Dibuja una elipse. Debe establecer el estilo de línea, el relleno o ambos antes de llamar al método drawEllipse() llamando al método linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() o beginBitmapFill().

Parámetros

Véase también

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_drawEllipseExample extends Sprite
    {
        public static const SMALL:uint = 0;
        public static const MEDIUM:uint = 1;
        public static const LARGE:uint = 2;

        public function Graphics_drawEllipseExample()
        {
            drawEgg(SMALL, 0, 100);
            drawEgg(MEDIUM, 100, 60);
            drawEgg(LARGE, 250, 35);
        }

        public function drawEgg(eggSize:uint, x:Number, y:Number):void  {

            var myEgg:Shape = new Shape();

            myEgg.graphics.beginFill(0xFFFFFF);
            myEgg.graphics.lineStyle(1);

            switch(eggSize) {
                case SMALL:
                    myEgg.graphics.drawEllipse(x, y, 60, 70);
                    break;
                case MEDIUM:
                    myEgg.graphics.drawEllipse(x, y, 120, 150);
                    break;
                case LARGE:
                    myEgg.graphics.drawEllipse(x, y, 150, 200);
                    break;
                default:
                    trace ("Wrong size! There is no egg.");
                break;
            }

            myEgg.graphics.endFill();

            this.addChild(myEgg);
        }
    }
}

Dibuja un rectángulo. Debe establecer el estilo de línea, el relleno o ambos antes de llamar al método drawRect() llamando al método linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() o beginBitmapFill().

Parámetros

Véase también

Dibuja un rectángulo redondeado. Debe establecer el estilo de línea, el relleno o ambos antes de llamar al método drawRoundRect() llamando al método linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() o beginBitmapFill().

Parámetros

Véase también

Aplica un relleno a las líneas y curvas añadidas desde la última llamada al método beginFill(), beginGradientFill() o beginBitmapFill(). Flash utiliza el relleno especificado en la anterior llamada al método beginFill(), beginGradientFill() o beginBitmapFill(). Si la posición de dibujo actual no es la misma que la posición anterior especificada en un método moveTo() y se ha definido un relleno, el trazado se cerrará con una línea y luego se rellenará.

Véase también

Especifica un degradado para el estilo de línea que Flash Player utiliza en las posteriores llamadas a otros métodos de Graphics (como, por ejemplo, lineTo() o drawCircle()) para el objeto. El estilo de línea surtirá efecto hasta que llame a los métodos lineStyle() o lineGradientStyle() con diferentes parámetros. Puede efectuar una llamada al método lineGradientStyle() en mitad de un trazado para especificar diferentes estilos para los distintos segmentos de línea de un trazado.

Realice una llamada a lineStyle() antes de hacerlo a lineGradientStyle() para activar un trazo, pues en caso contrario el valor del estilo de línea seguirá siendo undefined.

Las llamadas a clear() volverán a establecer el estilo de línea con el valor undefined.

Parámetros

	type:String — Un valor de la clase GradientType que especifica el tipo de degradado que debe utilizarse, GradientType.LINEAR o GradientType.RADIAL.
	colors:Array — Matriz de valores de color RGB hexadecimales que se utiliza en el degradado (por ejemplo, rojo es 0xFF0000, azul es 0x0000FF, etc.).
	alphas:Array — Matriz de valores alfa para los colores correspondientes de la matriz colors; los valores válidos van de 0 a 100. Si el valor es inferior a 0, Flash Player utiliza 0. Si el valor es superior a 100, Flash Player utiliza 100.
	ratios:Array — Matriz de proporciones de distribución de color; los valores válidos van de 0 a 255. Este valor define el porcentaje de la anchura donde el color se muestrea al 100%. El valor 0 representa la posición izquierda del cuadro de degradado, mientras que 255 representa la posición derecha del cuadro de degradado. Este valor representa posiciones del cuadro de degradado, no el espacio de coordenadas del degradado final, que podría ser más ancho o más delgado que el cuadro de degradado. Introduzca un valor con el parámetro colors. Por ejemplo, en el caso de un degradado lineal con dos colores, azul y verde, la siguiente figura ilustra la colocación de los colores en el degradado en función de los diferentes valores en la matriz ratios: ratios Degradado [0, 127] [0, 255] [127, 255] Los valores de la matriz deben aumentar secuencialmente; por ejemplo, [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — Matriz de transformación definida por la clase flash.geom.Matrix. La clase flash.geom.Matrix incluye un método createGradientBox(), que permite configurar cómodamente la matriz para utilizarla con el método lineGradientStyle().
	spreadMethod:String (default = "pad") — Un valor de la clase SpreadMethod que especifica el modo de extensión que debe utilizarse: SpreadMethod.PAD SpreadMethod.REFLECT SpreadMethod.REPEAT
	interpolationMethod:String (default = "rgb") — Valor de la clase InterpolationMethod que especifica el valor que debe utilizarse. Por ejemplo, imagine un degradado lineal sencillo entre dos colores (con el parámetro spreadMethod definido como SpreadMethod.REFLECT). Los diferentes métodos de interpolación afectan al aspecto de este modo: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Número que controla la ubicación del punto focal del degradado. El valor 0 significa que el punto focal está en el centro. El valor 1 significa que el punto focal se encuentra en un borde del círculo del degradado. El valor -1 significa que el punto focal se encuentra en el otro borde del círculo del degradado. Los valores menores que -1 o mayores que 1 se redondean a -1 o 1. En el ejemplo siguiente, se muestra un degradado con focalPointRatio como -0,75:

Véase también

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.geom.Matrix;
    import flash.display.GradientType;

    public class Graphics_lineGradientStyleExample extends Sprite
    {
        public function Graphics_lineGradientStyleExample()
        {
            var myShape:Shape = new Shape();
            var gradientBoxMatrix:Matrix = new Matrix();

            gradientBoxMatrix.createGradientBox(200, 40, 0, 0, 0);

            myShape.graphics.lineStyle(5);

            myShape.graphics.lineGradientStyle(GradientType.LINEAR, [0xFF0000,
            0x00FF00, 0x0000FF], [1, 1, 1], [0, 128, 255], gradientBoxMatrix);

            myShape.graphics.drawRect(0, 0, 200, 40);
            myShape.graphics.drawCircle(100, 120, 50);

            this.addChild(myShape);

        }
    }
}

Especifica un estilo de línea que Flash utiliza para las posteriores llamadas a otros métodos de Graphics (como, por ejemplo, lineTo() o drawCircle()) para el objeto. El estilo de línea surtirá efecto hasta que llame a los métodos lineGradientStyle() o lineStyle() con diferentes parámetros. Puede efectuar una llamada a lineStyle() en mitad de un trazado para especificar diferentes estilos para los distintos segmentos de línea del trazado.

Nota: las llamadas al método clear() volverán a establecer el estilo de línea con el valor undefined.

Parámetros

Véase también

Dibuja una línea utilizando el estilo de línea actual desde la posición de dibujo actual hasta (x, y); la posición de dibujo actual se establece posteriormente como (x, y). Si el objeto de visualización en el que está dibujando incluye contenido creado con las herramientas de dibujo de Flash, las llamadas al método lineTo() se dibujarán debajo de este contenido. Si llama a lineTo() antes de realizar ninguna llamada al método moveTo(), la posición de predeterminada para el dibujo actual será (0, 0). Si falta alguno de los parámetros, este método fallará y la posición del dibujo actual no cambiará.

Parámetros

package {
    import flash.display.Sprite;
    import flash.display.LineScaleMode;
    import flash.display.CapsStyle;
    import flash.display.JointStyle;
    import flash.display.Shape;


    public class Graphics_lineToExample extends Sprite {

        public function Graphics_lineToExample() {

            var trapezoid:Shape = new Shape();

            trapezoid.graphics.lineStyle(10, 0xFFD700, 1, false, LineScaleMode.VERTICAL,
                               CapsStyle.NONE, JointStyle.MITER, 10);

            trapezoid.graphics.moveTo(100, 100);

            trapezoid.graphics.lineTo(120, 50);
            trapezoid.graphics.lineTo(200, 50);
            trapezoid.graphics.lineTo(220, 100);
            trapezoid.graphics.lineTo(100, 100);

            this.addChild(trapezoid);
        }
    }
}

Mueve la posición de dibujo actual a (x, y). Si falta alguno de los parámetros, este método fallará y la posición del dibujo actual no cambiará.

Parámetros

package {
    import flash.display.Sprite;
    import flash.display.CapsStyle;
    import flash.display.LineScaleMode;

    public class Graphics_moveToExample extends Sprite
    {
        public function Graphics_moveToExample() {

            graphics.lineStyle(3, 0x990000, 0.25, false,
                            LineScaleMode.NONE, CapsStyle.SQUARE);

            graphics.moveTo(10, 20);
            graphics.lineTo(20, 20);
            graphics.moveTo(30, 20);
            graphics.lineTo(50, 20);
            graphics.moveTo(60, 20);
            graphics.lineTo(80, 20);
            graphics.moveTo(90, 20);
            graphics.lineTo(110, 20);
            graphics.moveTo(120, 20);
            graphics.lineTo(130, 20);
        }
    }
}

1. Declare una propiedad size para utilizarla posteriormente en la determinación del tamaño de cada forma.
2. Declare propiedades que establezcan el color de fondo en naranja, el color del borde en gris oscuro, el tamaño del borde en 0 píxeles, el radio de la esquina en 9 píxeles y defina el espacio entre el borde del escenario y los demás objetos en 5 píxeles.
3. Utilice las propiedades declaradas en los pasos anteriores junto con los métodos incorporados de la clase Graphics para dibujar el círculo, el rectángulo redondeado y el cuadrado en las coordenadas x = 0, y = 0.
4. Vuelva a dibujar cada una de las formas en la parte superior del escenario, comenzando en x = 5, y = 5, con un espaciado de 5 píxeles entre las formas.

package {
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class GraphicsExample extends Sprite {
        private var size:uint         = 80;
        private var bgColor:uint      = 0xFFCC00;
        private var borderColor:uint  = 0x666666;
        private var borderSize:uint   = 0;
        private var cornerRadius:uint = 9;
        private var gutter:uint       = 5;

        public function GraphicsExample() {
            doDrawCircle();
            doDrawRoundRect();
            doDrawRect();
            refreshLayout();
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = gutter;
            lastChild.y = gutter;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = gutter;
                lastChild = child;
            }
        }

        private function doDrawCircle():void {
            var child:Shape = new Shape();
            var halfSize:uint = Math.round(size / 2);
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawCircle(halfSize, halfSize, halfSize);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRoundRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRoundRect(0, 0, size, size, cornerRadius);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRect(0, 0, size, size);
            child.graphics.endFill();
            addChild(child);
        }
    }
}