public static const NONE:String = "none"
| Versión del lenguaje: | ActionScript 3.0 |
| Versión del reproductor: | Flash Player 9 |
Se utiliza para especificar la inexistencia de extremos en el parámetro caps del método flash.display.Graphics.lineStyle().
public static const ROUND:String = "round"
| Versión del lenguaje: | ActionScript 3.0 |
| Versión del reproductor: | Flash Player 9 |
Se utiliza para especificar extremos redondeados en el parámetro caps del método flash.display.Graphics.lineStyle().
public static const SQUARE:String = "square"
| Versión del lenguaje: | ActionScript 3.0 |
| Versión del reproductor: | Flash Player 9 |
Se utiliza para especificar extremos cuadrados en el parámetro caps del método flash.display.Graphics.lineStyle().
En el ejemplo siguiente, se utiliza la clase
CapsStyleExample para dibujar tres líneas paralelas, cada una con un estilo de extremo de línea diferente.
- Las propiedades de cada línea se establecen de la siguiente manera:
- La longitud de línea se establece en 80 píxeles.
- El color del borde se define en naranja.
- El tamaño del borde se establece en 30 píxeles.
- El color de resaltado se define en gris.
- El tamaño del resaltado se establece en 0 píxeles.
- El valor alfa se establece en 1, con lo que se convierte en sólido.
- El consejo de píxeles se establece como false (no se sugieren trazos a píxeles completos).
- El modo de escala de línea se define como normal, con lo que se escala el grosor.
- El estilo de juntas de los extremos de borde se establecen en
MITER.
- El límite de esquina se define en 1, lo que indica que la esquina se corta cerca de la línea.
- El constructor de la clase crea tres líneas verticales, comenzando en x = 0, y = 0 al llamar tres veces al método
drawLine() empleando tres estilos de extremo de línea diferentes (ninguno, redondeado y cuadrado). Cada una de las tres llamadas al método drawLine() utiliza el estilo de extremo y las propiedades enumeradas anteriormente para dibujar una línea vertical y el resaltado de línea asociado. Las llamadas crean primero un nuevo objeto Shape child y utilizan después métodos de la clase Graphics para configurar el estilo de línea y dibujar las líneas y resaltados. Cada instancia de child se añade a la lista de visualización y se dibuja en el escenario.
- Los segmentos de línea conectados se vuelven a dibujar con el método
refreshLayout() en y = 80 píxeles y comenzando en x = 80 píxeles, con una separación de 25 píxeles entre los segmentos de línea.
package {
import flash.display.CapsStyle;
import flash.display.DisplayObject;
import flash.display.Graphics;
import flash.display.JointStyle;
import flash.display.LineScaleMode;
import flash.display.Shape;
import flash.display.Sprite;
public class CapsStyleExample extends Sprite {
private var lineLength:uint = 80;
private var borderColor:uint = 0xFFCC00;
private var borderSize:uint = 30;
private var highlightColor:uint = 0x666666;
private var highlightSize:uint = 0;
private var gutter:uint = 25;
private var borderAlpha:uint = 1;
private var borderPixelHinting:Boolean = false;
private var borderScaleMode:String = LineScaleMode.NORMAL;
private var borderJointStyle:String = JointStyle.MITER;
private var borderMiterLimit:uint = 1;
public function CapsStyleExample() {
drawLine(CapsStyle.NONE);
drawLine(CapsStyle.ROUND);
drawLine(CapsStyle.SQUARE);
refreshLayout();
}
private function drawLine(capsStyle:String):void {
var child:Shape = new Shape();
child.graphics.lineStyle(borderSize,
borderColor,
borderAlpha,
borderPixelHinting,
borderScaleMode,
capsStyle,
borderJointStyle,
borderMiterLimit);
child.graphics.lineTo(0, 0);
child.graphics.lineTo(0, lineLength);
child.graphics.endFill();
child.graphics.moveTo(0, 0);
child.graphics.lineStyle(highlightSize, highlightColor);
child.graphics.lineTo(0, 0);
child.graphics.lineTo(0, lineLength);
addChild(child);
}
private function refreshLayout():void {
var ln:uint = numChildren;
var child:DisplayObject;
var lastChild:DisplayObject = getChildAt(0);
lastChild.x = lineLength;
lastChild.y = lineLength;
for (var i:uint = 1; i < ln; i++) {
child = getChildAt(i);
child.x = gutter + lastChild.x + lastChild.width;
child.y = lineLength;
lastChild = child;
}
}
}
}
Object
Ocultar propiedades públicas heredadas
Mostrar propiedades públicas heredadas