El objeto BitmapData al que se hace referencia.

Controla si el objeto Bitmap se ajusta al píxel más cercano. La clase PixelSnapping incluye valores posibles:

• PixelSnapping.NEVER: no se produce ajuste en píxeles.
• PixelSnapping.ALWAYS: la imagen siempre se ajusta al píxel más cercano, con independencia de la transformación.
• PixelSnapping.AUTO: la imagen de mapa de bits se ajusta al píxel más cercano si ésta se dibuja sin rotación ni sesgo y se dibuja con un factor de escala del 99,9% al 100,1%. Si se cumplen estas condiciones, la imagen de mapa de bits se dibuja al 100% de escala y se ajusta al píxel más cercano. Internamente, este valor permite que la imagen se dibuje lo antes posible mediante el procesador de vectores.

Controla si el mapa de bits se suaviza al aplicársele escala. Si el valor es true, el mapa de bits se suaviza al aplicársele escala. Si el valor es false, el mapa de bits no se suaviza al aplicársele escala.

Inicializa un objeto Bitmap para hacer referencia al objeto BitmapData especificado.

	bitmapData:BitmapData (default = null) — El objeto BitmapData al que se hace referencia.
	pixelSnapping:String (default = "auto") — Especifica si el objeto Bitmap se ajusta al píxel más cercano.
	smoothing:Boolean (default = false) — Indica si el mapa de bits se suaviza al aplicársele escala. Los siguientes ejemplos muestran el mismo mapa de bits al que se la ha aplicado una escala de factor 3, con smoothing definido con el valor false (izquierda) y true (derecha):

1. Se crea una propiedad url, que es la ubicación y el nombre del archivo de imagen.
2. El constructor de la clase llama al método configureAssets() que, a su vez, llama al método completeHandler().
3. configureAssets() crea un objeto Loader que, a su vez, crea la instancia de un detector de eventos que se distribuye cuando el método completeHandler() finaliza la manipulación de la imagen.
4. A continuación, el método buildChild() crea una nueva instancia de un objeto URLRequest, request, con url para que se conozcan el nombre del archivo y la ubicación.
5. El objeto request se transfiere posteriormente al método loader.load(), que carga la imagen en la memoria mediante un objeto de visualización.
6. La imagen se incluye entonces en la lista de visualización, que muestra inmediatamente la imagen en la pantalla con las coordenadas x = 0, y = 0.
7. El método completeHandler() realiza las siguientes tareas:
   1. Crea un segundo objeto Loader, junto con un objeto Bitmap, que se inicializa con el objeto Loader.
   2. Crea un segundo objeto Bitmap, duplicate, que a su vez llama al método duplicateImage(), que crea un duplicado de la imagen original.
   3. Crea un objeto BitmapData que se asigna al objeto BitmapData del objeto duplicate.
   4. Crea un nuevo objeto Rectangle inicializado con las mismas coordenadas, anchura y altura que la imagen original.
   5. Crea un nuevo objeto Point, que se establece de forma predeterminada en x = 0, y = 0.
   6. Crea las siguientes variables:
      • operation: aplica el nuevo color cuando el valor del umbral es mayor o igual que el original.
      • threshold: el valor con el que se compara cada píxel se define en gris claro con un alfa de 0xCC.
      • color: el color con el que se definirán los píxeles que superen la prueba de umbral, que en este caso es amarillo sólido.
      • mask: definido como lo contrario exacto del color (azul transparente).
      • copySource: definido como false, lo que indica que los valores de píxel no se copian si no pasa el valor de umbral. Este valor no significa nada porque la imagen está duplicada y sólo se modifican los píxeles que superan la prueba de umbral.
   7. Llama al método threshold() mediante las variables anteriores. La ecuación del umbral resultante es la siguiente: if (current pixel Value & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) then set pixel to 0xFFFFFF00.

Notas:

• Necesitará compilar el archivo SWF con la opción "Seguridad de reproducción local" establecida como "Acceder sólo a archivos locales".
• Este ejemplo requiere la colocación de un archivo llamado Image.gif en el mismo directorio que el archivo SWF.
• Se recomienda utilizar una imagen de 80 píxeles de anchura como máximo.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}