Obtiene o define un valor que indica si el componente puede aceptar la interacción del usuario. Un valor true indica que el componente puede aceptar la interacción del usuario; un valor false indica que no puede aceptarla.

Si la propiedad enabled se define como false, el color del contenedor aparece atenuado y la entrada del usuario está bloqueada (con la excepción de los componentes Label y ProgressBar).

El valor predeterminado es true.

Obtiene o define un valor booleano que indica si el componente puede recibir selecciones cuando el usuario hace clic sobre él. Un valor true indica que puede recibir selecciones; un valor false indica que no puede recibirlas.

Si esta propiedad es false, se transfiere la selección al primer elemento principal cuya propiedad mouseFocusEnabled se haya definido como true.

El valor predeterminado es true.

Véase también

Obtiene o define la clase FocusManager que controla la selección de este componente y sus homólogos. Cada componente emergente mantiene su propio bucle de selección y su instancia de FocusManager. Utilice esta propiedad para acceder a la instancia de FocusManager correcta para este componente.

Obtiene o define la altura del componente, expresada en píxeles.

La definición de esta propiedad provoca que se distribuya un evento resize. Consulte el evento resize para obtener información detallada sobre cuándo se distribuirá.

Si la propiedad scaleY del componente no es 1.0, la altura del componente que se obtiene de sus coordenadas internas no coincidirá con el valor de altura de las coordenadas principales. Por ejemplo, un componente que tiene 100 píxeles de altura y una propiedad scaleY de 2, tiene un valor de 100 píxeles en la coordenada principal, aunque internamente almacena un valor que indica que su altura es de 50 píxeles.

Obtiene o define un valor booleano que indica si el componente puede recibir selecciones cuando el usuario hace clic sobre él. Un valor true indica que puede recibir selecciones; un valor false indica que no puede recibirlas.

Si esta propiedad es false, se transfiere la selección al primer elemento principal cuya propiedad mouseFocusEnabled se haya definido como true.

El valor predeterminado es true.

Véase también

Multiplica la anchura actual del componente por un factor de escala.

Véase también

Multiplica la altura actual del componente por un factor de escala.

Véase también

Número de versión de los componentes.

import fl.controls.CheckBox;

var myCheckBox:CheckBox = new CheckBox();
trace(myCheckBox.version);

Obtiene o define un valor que indica si la instancia del componente actual es visible. Un valor true indica que el componente actual es visible; un valor false indica que no lo es.

Cuando esta propiedad se define como true, el objeto distribuye un evento show. Cuando esta propiedad se define como false, el objeto distribuye un evento hide. En ambos casos, los elementos secundarios del objeto no generan un evento show o hide a menos que el objeto escriba específicamente una implementación para hacerlo.

El valor predeterminado es true.

Véase también

Obtiene o define la anchura del componente, expresada en píxeles.

La definición de esta propiedad provoca que se distribuya un evento resize. Consulte el evento resize para obtener información detallada sobre cuándo se distribuirá.

Si la propiedad scaleX del componente no es 1.0, la anchura del componente que se obtiene de sus coordenadas internas no coincidirá con el valor de anchura de las coordenadas principales. Por ejemplo, un componente que tiene 100 píxeles de anchura y una propiedad scaleX de 2, tiene un valor de 100 píxeles en la coordenada principal, aunque internamente almacena un valor que indica que su anchura es de 50 píxeles.

Véase también

Obtiene o define la coordenada x que representa la posición del componente a lo largo del eje x en su contenedor principal. Este valor se describe en píxeles y se calcula desde la izquierda.

La definición de esta propiedad provoca que se distribuya el evento ComponentEvent.MOVE.

El valor predeterminado es 0.

Véase también

Obtiene o define la coordenada y que representa la posición del componente a lo largo del eje y en su contenedor principal. Este valor se describe en píxeles y se calcula desde la parte superior.

La definición de esta propiedad provoca que se distribuya el evento move.

Véase también

Crea una nueva instancia del componente UIComponent.

Elimina una propiedad de estilo de esta instancia de componente.

No provoca necesariamente que el método getStyle() devuelva un valor undefined.

Parámetros

Véase también

Muestra u oculta el indicador de selección en este componente.

La clase UIComponent implementa este método mediante la creación y posición de una instancia de la clase que se especifica mediante el estilo focusSkin.

Parámetros

Inicia de forma inmediata una operación de dibujo, sin invalidarlo todo como ocurre con invalidateNow.

Recupera el objeto que está seleccionado actualmente.

Observe que este método no devuelve necesariamente el componente que está seleccionado. Puede devolver el subcomponente interno del componente seleccionado. Para obtener el componente que está seleccionado, utilice la propiedad focusManager.focus.

Recupera una propiedad de estilo que se define en la cadena de búsqueda de estilo del componente.

El tipo que este método devuelve varía según la propiedad de estilo que dicho método recupere. En el rango de tipos posibles se incluyen Boolean; String; Number; int; un uint para un color RGB; un tipo Class para un aspecto o cualquier objeto.

Si llama a este método para recuperar una propiedad de estilo específica, ésta será de un tipo conocido que puede almacenar en una variable del mismo tipo. No es necesaria una conversión del tipo. En lugar de ello, bastará con una sentencia de asignación sencilla como la siguiente:

var backgroundColor:uint = getStyle("backgroundColor");

Si la propiedad de estilo no se ha definido en la cadena de búsqueda de estilo, este método devolverá un valor undefined. Observe que undefined es un valor especial distinto a false, "", NaN, 0 o null. undefined no es un valor de estilo válido. Puede utilizar el método estático StyleManager.isValidStyleValue() para comprobar si se ha definido un valor.

Parámetros

Véase también

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var myComboBox:ComboBox = new ComboBox();
myComboBox.setStyle("textPadding", 6);
myComboBox.setStyle("disabledAlpha", 0.8);

var styleObject:Object = ComboBox.getStyleDefinition();
var styleDP:DataProvider = new DataProvider();
var styleName:String;
var styleDefaultValue:String;
var styleCurrentValue:String;

for (styleName in styleObject) {
    styleDefaultValue = String(styleObject[styleName]);
    styleCurrentValue = String(myComboBox.getStyle(styleName));
    styleDP.addItem({name:styleName, defaultValue:styleDefaultValue, currentValue:styleCurrentValue});
}
styleDP.sortOn("name", Array.CASEINSENSITIVE);

var c1:DataGridColumn = new DataGridColumn("name");
c1.headerText = "Style name:";
var c2:DataGridColumn = new DataGridColumn("defaultValue");
c2.headerText = "Default style value:";
var c3:DataGridColumn = new DataGridColumn("currentValue");
c3.headerText = "Current style value:"

var styleDataGrid:DataGrid = new DataGrid();
styleDataGrid.addColumn(c1); // name
styleDataGrid.addColumn(c2); // defaultValue
styleDataGrid.addColumn(c3); // currentValue
styleDataGrid.dataProvider = styleDP;
styleDataGrid.setSize(stage.stageWidth - 20, stage.stageHeight - 20);
styleDataGrid.move(10, 10);
addChild(styleDataGrid);

Devuelve la asignación de estilos predeterminada del componente actual. La asignación de estilos contiene el tipo adecuado para el componente, en función del estilo que ese componente utilice. Por ejemplo, el estilo disabledTextFormat contiene un valor null o un objeto TextFormat. Puede utilizar estos estilos y llamar a setStyle() en el componente actual. El código siguiente sustituye el estilo predeterminado disabledTextFormat en el componente especificado:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Véase también

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Marca una propiedad como no válida y vuelve a dibujar el componente en el siguiente fotograma a menos que se especifique lo contrario.

Parámetros

Combina los estilos de varias clases en un objeto. Si un estilo se define en varios objetos, se utilizará el primero de ellos que se encuentre.

Parámetros

Mueve el componente a la posición especificada dentro de su elemento principal. Esto produce el mismo efecto que si se cambiara la ubicación del componente mediante la definición de sus propiedades x e y. La llamada a este método desencadena el evento ComponentEvent.MOVE que se distribuirá.

Para sustituir el método updateDisplayList() en un componente personalizado, utilice el método move() en lugar de definir las propiedades x e y, ya que una llamada al método move() provoca que un objeto de evento move se distribuya inmediatamente después de que finalice la operación de movimiento. En cambio, cuando se cambia la ubicación del componente mediante la definición de las propiedades x e y, el objeto de evento se distribuye en la siguiente actualización de pantalla.

Parámetros

Véase también

Selecciona este componente. A su vez, el componente puede asignar la selección a un subcomponente.

Nota: sólo los componentes TextInput y TextArea muestran un indicador de selección cuando este método realiza la selección. Todos los componentes muestran un indicador de selección cuando el usuario usa el tabulador para acceder al componente.

Define el componente en la anchura y altura especificadas.

Parámetros

Define una propiedad de estilo en esta instancia de componente. Este estilo puede sustituir a otro que se definió de forma global.

La llamada a este método puede producir una reducción en el rendimiento. Utilícelo sólo cuando sea necesario.

Parámetros

Véase también

import fl.controls.Button;

var myFormat:TextFormat = new TextFormat();
myFormat.font = "Georgia";

var b:Button = new Button();
b.label = "Hello World";
b.setStyle("textFormat", myFormat);
addChild(b);

import fl.controls.Button;

var flashIcon:Loader = new Loader();
flashIcon.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
flashIcon.load(new URLRequest("http://www.helpexamples.com/flash/images/logo.png"));

var myButton:Button = new Button();
myButton.label = "Flash";
myButton.move(10, 10);
addChild(myButton);

function completeHandler(event:Event):void {
    flashIcon.width = 16;
    flashIcon.height = 16;
    myButton.setStyle("icon", flashIcon);
}

Valida y actualiza las propiedades y el diseño de este objeto y lo vuelve a dibujar, si es necesario.

Las propiedades que requieren una computación sustancial normalmente no se procesan hasta que se termina de ejecutar el script. Esto se debe a que para la definición de una propiedad se podría requerir el procesamiento de otras propiedades. Por ejemplo, para definir la propiedad width puede que sea necesario volver a calcular las anchuras de los elementos secundarios o principales del objeto. Y si el script vuelve a calcular la anchura del objeto más de una vez, es posible que también se deban volver a calcular estas propiedades interdependientes. Utilice este método para sustituir manualmente este comportamiento.

Se distribuye cuando la visibilidad del componente cambia de visible a invisible.

Este evento tiene las propiedades siguientes:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Véase también

Se distribuye cuando se mueve el componente.

Este evento tiene las propiedades siguientes:

import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20);
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

Se distribuye cuando se cambia el tamaño del componente.

Este evento tiene las propiedades siguientes:

import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

Se distribuye cuando la visibilidad del componente cambia de invisible a visible.

Este evento tiene las propiedades siguientes:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Véase también