fl.controls.dataGridClasses.DataGridColumn (ActionScript 3.0)

	Propiedad	Definido por
		cellRenderer : Object Clase que se utiliza para representar los elementos de esta columna.	DataGridColumn
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		dataField : String Identifica el nombre del campo o la propiedad del elemento del proveedor de datos asociado a la columna.	DataGridColumn
		editable : Boolean = true Indica si se pueden editar los elementos de la columna.	DataGridColumn
		editorDataField : String = "text" Identifica el nombre de la propiedad del editor de elementos que contiene los nuevos datos para el elemento de la lista.	DataGridColumn
		headerRenderer : Object Clase que se utiliza para representar el encabezado de esta columna.	DataGridColumn
		headerText : String El nombre de columna que se va a mostrar en el encabezado de columna.	DataGridColumn
		imeMode : String Modo del editor de método de entrada (IME).	DataGridColumn
		itemEditor : Object = fl.controls.dataGridClasses.DataGridCellEditor Indica la clase de las instancias del editor de elementos que se va a utilizar para la columna, si es editable.	DataGridColumn
		labelFunction : Function Función que determina el texto que se va a mostrar en esta columna.	DataGridColumn
		minWidth : Number Anchura mínima de la columna expresada en píxeles.	DataGridColumn
		prototype : Object [static] Una referencia al objeto prototipo de una clase u objeto de función.	Object
		resizable : Boolean = true Indica si se permite al usuario cambiar la anchura de la columna.	DataGridColumn
		sortable : Boolean = true Indica si el usuario puede hacer clic en el encabezado de la columna actual para ordenar el proveedor de datos.	DataGridColumn
		sortCompareFunction : Function Función callback que se llama al ordenar los datos de la columna.	DataGridColumn
		sortDescending : Boolean = false Indica si la clase DataGridColumn se almacena en orden ascendente o descendente.	DataGridColumn
		sortOptions : uint = 0 Uno o varios contactos definidos, identificados por el nombre o el número y separados por el operador en modo bit O (\|).	DataGridColumn
		visible : Boolean Indica si la columna está visible.	DataGridColumn
		width : Number Anchura de la columna, expresada en píxeles.	DataGridColumn

	Método	Definido por
		DataGridColumn(columnName:String = null) Crea una nueva instancia de DataGridColumn.	DataGridColumn
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		itemToLabel(data:Object):String Devuelve la cadena que el procesador de elementos muestra para el objeto de datos especificado.	DataGridColumn
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		toString():String Devuelve una representación de cadena del objeto DataGridColumn.	DataGridColumn
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object

Información sobre propiedades

cellRenderer

propiedad

cellRenderer:Object [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Clase que se utiliza para representar los elementos de esta columna. Esta propiedad puede ser de tipo Class, Sprite o String. Si el tipo de la propiedad es String, el valor String debe ser un nombre de clase completo.

El valor predeterminado es null.

Implementación
public function get cellRenderer():Object
public function set cellRenderer(value:Object):void

Véase también

DataGridColumn.headerRenderer

Ejemplo

En el siguiente ejemplo se especifica un procesador de celdas personalizado para una columna de cuadrícula de datos:


import fl.controls.dataGridClasses.DataGridColumn;

var dgc:DataGridColumn = new DataGridColumn("Field");
dgc.cellRenderer = "MyCustomCellRendererClass";
dg.addColumn(dgc);

dataField

propiedad

public var dataField:String

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Identifica el nombre del campo o la propiedad del elemento del proveedor de datos asociado a la columna.

editable

propiedad

public var editable:Boolean = true

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Indica si se pueden editar los elementos de la columna. Un valor true indica que se pueden editar los elementos de la columna; mientras que un valor false indica todo lo contrario.

Si esta propiedad se define como true y la propiedad editable de DataGrid también es true, los elementos de la columna son editables y se pueden editar de forma individual haciendo clic en un elemento o desplazándose a éste con las teclas Tabulador y de flecha.

El valor predeterminado es true.

editorDataField

propiedad

public var editorDataField:String = "text"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Identifica el nombre de la propiedad del editor de elementos que contiene los nuevos datos para el elemento de la lista.

Por ejemplo, el valor predeterminado itemEditor es TextInput, por lo que el valor predeterminado de la propiedad editorDataField es "text". Este valor especifica la propiedad text del componente TextInput.

El valor predeterminado es "text".

headerRenderer

propiedad

headerRenderer:Object [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Clase que se utiliza para representar el encabezado de esta columna.

Esta propiedad puede ser de tipo Class, Sprite o String. Si el tipo de la propiedad es String, el valor String debe ser un nombre de clase completo.

El valor predeterminado es null.

Implementación
public function get headerRenderer():Object
public function set headerRenderer(value:Object):void

Véase también

DataGridColumn.cellRenderer
HeaderRenderer

headerText

propiedad

headerText:String [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

El nombre de columna que se va a mostrar en el encabezado de columna. De forma predeterminada, el componente DataGrid utiliza el valor de la propiedad dataField como nombre de columna.

Implementación
public function get headerText():String
public function set headerText(value:String):void

Ejemplo

En el ejemplo siguiente, se crea una nueva cuadrícula de datos y se especifica el texto del encabezado para cada columna:


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({name:"Person A", sales:13453});
dp.addItem({name:"Person B", sales:23432});
dp.addItem({name:"Person C", sales:9454});

var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Employee:";

var salesCol:DataGridColumn = new DataGridColumn("sales");
salesCol.headerText = "Sales:";
salesCol.labelFunction = currencyFormatter;
salesCol.sortOptions = Array.NUMERIC;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(salesCol);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(320, 240);
addChild(myDataGrid);

function currencyFormatter(item:Object):String {
    return "$" + item.sales.toFixed(0);
}

imeMode

propiedad

imeMode:String [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Modo del editor de método de entrada (IME). IME permite a los usuarios introducir texto en chino, japonés y coreano. La clase flash.system.IMEConversionMode define constantes que se van a utilizar como valores válidos para esta propiedad.

Si esta propiedad es null, el modo de IME se define como el valor de la propiedad imeMode del componente DataGrid.

El valor predeterminado es null.

Implementación
public function get imeMode():String
public function set imeMode(value:String):void

Véase también

flash.system.IMEConversionMode

itemEditor

propiedad

public var itemEditor:Object = fl.controls.dataGridClasses.DataGridCellEditor

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Indica la clase de las instancias del editor de elementos que se va a utilizar para la columna, si es editable. Esta propiedad puede ser de tipo Class, Sprite o String. Si el tipo de la propiedad es String, el valor String debe ser un nombre de clase completo.

El valor predeterminado es "fl.controls.dataGridClasses.DataGridCellEditor".

Ejemplo

En el ejemplo siguiente, se especifica un editor de celdas personalizado para una columna de cuadrícula de datos:


import fl.controls.dataGridClasses.DataGridColumn;

var dgc:DataGridColumn = new DataGridColumn("Field");
dgc.itemEditor = "MyCustomItemEditorClass";
dg.addColumn(dgc);

labelFunction

propiedad

labelFunction:Function [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Función que determina el texto que se va a mostrar en esta columna. De forma predeterminada, la columna muestra el texto del campo en los datos que coinciden con el nombre de la columna. No obstante, también se puede utilizar una columna para mostrar el texto de más de un campo de datos, o bien para mostrar el contenido que no está en el formato adecuado. Esto se puede hacer mediante la propiedad labelFunction para especificar una función callback.

Si están definidas las propiedades labelFunction y labelField, tendrá preferencia labelFunction.

El valor predeterminado es null.

Implementación
public function get labelFunction():Function
public function set labelFunction(value:Function):void

Ejemplo

En el ejemplo siguiente, se crea una cuadrícula de datos y se define una etiqueta personalizada para una de las columnas de cuadrícula de datos:


import fl.controls.DataGrid;
import fl.controls.ScrollPolicy;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var i:uint;
var totalRows:uint = 16;
var dp:DataProvider = new DataProvider();
for (i = 0; i < totalRows; i++) {
    dp.addItem({col1:getRandomNumber(), col2:getRandomNumber(), col3:getRandomNumber(), col4:getRandomNumber()});
}

var c1:DataGridColumn = new DataGridColumn("col1");
c1.sortOptions = Array.NUMERIC;
var c2:DataGridColumn = new DataGridColumn("col2");
c2.sortOptions = Array.NUMERIC;
var c3:DataGridColumn = new DataGridColumn("col3");
c3.sortOptions = Array.NUMERIC;
c3.labelFunction = currencyFormatter;

var dg:DataGrid = new DataGrid();
dg.setSize(200, 300);
dg.addColumn(c1);
dg.addColumn(c2);
dg.addColumn(c3);
dg.dataProvider = dp;
addChild(dg);

function getRandomNumber():Number {
    return Math.random() * 100;
}

function currencyFormatter(data:Object):String {
    var value:Number = Number(data.col3);
    return "$" + value.toFixed(2);
}

En el ejemplo siguiente, se crea un nuevo objeto DataGridColumn y se especifica la propiedad labelFunction y sortCompareFunction:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var data:XML = <data>
        <item name="Employee A" isManager="1" />
        <item name="Employee B" isManager="0" />
        <item name="Employee C" isManager="1" />
    </data>;

var dp:DataProvider = new DataProvider(data);

var nameDGC:DataGridColumn = new DataGridColumn("name");
nameDGC.sortCompareFunction = isManager;
nameDGC.labelFunction = nameLabelFunction;

var myDataGrid:DataGrid = new DataGrid()
myDataGrid.addColumn(nameDGC);
myDataGrid.dataProvider = dp;
myDataGrid.width = 200;
myDataGrid.rowCount = myDataGrid.length;
myDataGrid.move(10, 10);
addChild(myDataGrid);

function nameLabelFunction(item:Object):String {
    var managerString:String = "";
    if (item.isManager == "1") {
        managerString = " (Manager)";
    }
    return item.name + managerString;
}

function isManager(itemA:Object, itemB:Object):int {
    if (itemA.isManager > itemB.isManager) {
        return -1;
    } else if (itemA.isManager < itemB.isManager) {
        return 1;
    } else {
        return 0;
    }
}

minWidth

propiedad

minWidth:Number [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Anchura mínima de la columna expresada en píxeles.

El valor predeterminado es 20.

Implementación
public function get minWidth():Number
public function set minWidth(value:Number):void

Véase también

DataGridColumn.width

Ejemplo

En el ejemplo siguiente, se muestra la anchura de cada columna en la cuadrícula de datos cada vez que cambia ésta:


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var data:XML = <data>
        <row col1="item 1.A" col2="item 1.B" col3="item 1.C" />
        <row col1="item 2.A" col2="item 2.B" col3="item 2.C" />
        <row col1="item 3.A" col2="item 3.B" col3="item 3.C" />
    </data>;

var dp:DataProvider = new DataProvider(data);

var c1:DataGridColumn = new DataGridColumn("col1");
c1.minWidth = 100;
var c2:DataGridColumn = new DataGridColumn("col2");
var c3:DataGridColumn = new DataGridColumn("col3");

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.addColumn(c3);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(300, 200);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var column:DataGridColumn;
    for each (column in myDataGrid.columns) {
        trace(column.dataField, "width:" + column.width, "minWidth:" + column.minWidth);
    }
    trace("---");
}

resizable

propiedad

public var resizable:Boolean = true

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Indica si se permite al usuario cambiar la anchura de la columna. Un valor true indica que el usuario puede cambiar la anchura de la columna; mientras que un valor false indica todo lo contrario.

El valor predeterminado es true.

sortable

propiedad

public var sortable:Boolean = true

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Indica si el usuario puede hacer clic en el encabezado de la columna actual para ordenar el proveedor de datos. Un valor true indica que la columna se puede ordenar haciendo clic en su encabezado; mientras que un valor false indica que no se puede ordenar de esta manera.

El valor predeterminado es true.

Ejemplo

En el ejemplo siguiente, se crea una nueva cuadrícula de datos con una columna que no se puede ordenar:


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var data:XML = <dataProvider>
        <data col1="Person A" col2="11.383" />
        <data col1="Person B" col2="3.399" />
        <data col1="Person C" col2="25.624" />
    </dataProvider>

var dp:DataProvider = new DataProvider(data);

var c1:DataGridColumn = new DataGridColumn("col1");
var c2:DataGridColumn = new DataGridColumn("col2");
c2.sortable = false;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(160, 120);
addChild(myDataGrid);

En el ejemplo siguiente, se crea un componente DataGrid con una columna que no se puede ordenar al definir la propiedad sortable de la columna de cuadrícula de datos como false:


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var xmlDP:XML = <items>
        <item name="Person 1" bio="Person 1 bio" />
        <item name="Person 2" bio="Person 2 bio" />
    </items>;

var dp:DataProvider = new DataProvider(xmlDP);

var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Name:";

var bioCol:DataGridColumn = new DataGridColumn("bio");
bioCol.headerText = "Bio:";
bioCol.sortable = false;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(bioCol);
myDataGrid.dataProvider = dp;
myDataGrid.rowCount = dp.length;
myDataGrid.width = 200;
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var myDG:DataGrid = event.currentTarget as DataGrid;
    trace("dataField:" + event.dataField);
    trace("columnIndex:" + event.columnIndex);
    trace("{DataGrid}.sortDescending:" + myDG.sortDescending);
    trace("{DataGridColumn}.sortDescending:" + myDG.getColumnAt(event.columnIndex).sortDescending);
    trace("");
}

sortCompareFunction

propiedad

sortCompareFunction:Function [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Función callback que se llama al ordenar los datos de la columna. Si no se especifica esta propiedad, los datos se clasifican mediante la cadena o el número, en función de la propiedad sortOptions. Una vez especificada, la propiedad sortCompareFunction permite crear su propio método de clasificación personalizado para la columna de cuadrícula de datos actual.

El valor predeterminado es null.

Implementación
public function get sortCompareFunction():Function
public function set sortCompareFunction(value:Function):void

Véase también

sortOptions

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto DataGridColumn y se especifica la propiedad labelFunction y sortCompareFunction:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var data:XML = <data>
        <item name="Employee A" isManager="1" />
        <item name="Employee B" isManager="0" />
        <item name="Employee C" isManager="1" />
    </data>;

var dp:DataProvider = new DataProvider(data);

var nameDGC:DataGridColumn = new DataGridColumn("name");
nameDGC.sortCompareFunction = isManager;
nameDGC.labelFunction = nameLabelFunction;

var myDataGrid:DataGrid = new DataGrid()
myDataGrid.addColumn(nameDGC);
myDataGrid.dataProvider = dp;
myDataGrid.width = 200;
myDataGrid.rowCount = myDataGrid.length;
myDataGrid.move(10, 10);
addChild(myDataGrid);

function nameLabelFunction(item:Object):String {
    var managerString:String = "";
    if (item.isManager == "1") {
        managerString = " (Manager)";
    }
    return item.name + managerString;
}

function isManager(itemA:Object, itemB:Object):int {
    if (itemA.isManager > itemB.isManager) {
        return -1;
    } else if (itemA.isManager < itemB.isManager) {
        return 1;
    } else {
        return 0;
    }
}

sortDescending

propiedad

public var sortDescending:Boolean = false

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Indica si la clase DataGridColumn se almacena en orden ascendente o descendente. Un valor true indica que la propiedad DataGridColumn se ha ordenado en orden descendente; mientras que un valor false indica que lo ha hecho en orden ascendente.

El valor predeterminado es false.

sortOptions

propiedad

public var sortOptions:uint = 0

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Uno o varios contactos definidos, identificados por el nombre o el número y separados por el operador en modo bit O (|). Estas constantes se utilizan para especificar la operación de ordenación.

El valor predeterminado es 0.

Véase también

Array.sort()

Ejemplo

En el ejemplo siguiente, se utiliza la propiedad sortOptions para especificar que una columna de cuadrícula de datos se debería ordenar numéricamente.


import fl.data.DataProvider;
import fl.controls.dataGridClasses.DataGridColumn;

var data:XML = <players>
        <player name="Player 1" score="1234" />
        <player name="Player 2" score="198" />
        <player name="Player 3" score="987" />
    </players>;

var dp:DataProvider = new DataProvider(data);

var nameDGC:DataGridColumn = new DataGridColumn("name");
var scoreDGC:DataGridColumn = new DataGridColumn("score");
scoreDGC.sortOptions = Array.NUMERIC;

dg.addColumn(nameDGC);
dg.addColumn(scoreDGC);
dg.dataProvider = dp;

visible

propiedad

visible:Boolean [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Indica si la columna está visible. Un valor true indica que la columna está visible; mientras que un valor false indica todo lo contrario.

El valor predeterminado es true.

Implementación
public function get visible():Boolean
public function set visible(value:Boolean):void

Ejemplo

En el ejemplo siguiente, se crea una instancia de componente DataGrid con dos columnas. Puede activar la propiedad visible de cada una de estas columnas haciendo clic en la instancia Button correspondiente del escenario.


import fl.controls.Button;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({name:"Person A", average:0.297});
dp.addItem({name:"Person B", average:0.288});
dp.addItem({name:"Person C", average:0.310});

var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Name:";

var averageCol:DataGridColumn = new DataGridColumn("average");
averageCol.headerText = "Average:";
averageCol.labelFunction = numberFormatter;
averageCol.sortOptions = Array.NUMERIC;
averageCol.visible = false;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(averageCol);
myDataGrid.dataProvider = dp;
myDataGrid.rowCount = dp.length;
myDataGrid.width = 320;
myDataGrid.move(10, 10);
addChild(myDataGrid);

var nameButton:Button = new Button();
nameButton.label = "Toggle name";
nameButton.toggle = true;
nameButton.selected = nameCol.visible;
nameButton.move(myDataGrid.x, myDataGrid.y + myDataGrid.height + 10);
nameButton.addEventListener(Event.CHANGE, changeHandler);
addChild(nameButton);

var averageButton:Button = new Button();
averageButton.label = "Toggle average";
averageButton.toggle = true;
averageButton.selected = averageCol.visible;
averageButton.move(nameButton.x + nameButton.width + 10, nameButton.y);
averageButton.addEventListener(Event.CHANGE, changeHandler);
addChild(averageButton);

function numberFormatter(item:Object):String {
    return Number(item.average).toFixed(3);
}

function changeHandler(event:Event):void {
    var colIndex:int = -2;
    var col:DataGridColumn;
    switch (event.currentTarget) {
        case nameButton:
            colIndex = myDataGrid.getColumnIndex("name");
            break;
        case averageButton:
            colIndex = myDataGrid.getColumnIndex("average");
            break;
        default:
            return;
    }

    if (colIndex > -1) {
        col = myDataGrid.getColumnAt(colIndex);
        col.visible = !col.visible;
        myDataGrid.removeColumnAt(colIndex);
        myDataGrid.addColumnAt(col, colIndex);
    }
    myDataGrid.spaceColumnsEqually();
}

width

propiedad

width:Number [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Anchura de la columna, expresada en píxeles.

El valor predeterminado es 100.

Implementación
public function get width():Number
public function set width(value:Number):void

Véase también

DataGridColumn.minWidth

Información sobre constructores

DataGridColumn

()

constructor

public function DataGridColumn(columnName:String = null)

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Crea una nueva instancia de DataGridColumn.

Parámetros

columnName:String (default = null) — El nombre de columna que se va a mostrar en el encabezado de columna. Si no se ha especificado ningún nombre, se utiliza el valor dataField.

Véase también

DataGridColumn.headerText

Información sobre métodos

itemToLabel

()

método

public function itemToLabel(data:Object):String

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Devuelve la cadena que el procesador de elementos muestra para el objeto de datos especificado. Si la clase DataGridColumn o el componente DataGrid tienen una propiedad labelFunction que no es null, se aplica la función al objeto de datos. En caso contrario, el método extrae el contenido del campo especificado con la propiedad dataField u obtiene el valor de la cadena del objeto de datos. Si el método no puede convertir el parámetro en cadena, devuelve un solo espacio vacío.

Parámetros

data:Object — El objeto que se va a representar.

Valor devuelto

String — La cadena que puede mostrarse se basa en el objeto data especificado.

toString

()

método

public function toString():String

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Devuelve una representación de cadena del objeto DataGridColumn.

Valor devuelto

String — "[object DataGridColumn]"

Ejemplos Cómo utilizar los ejemplos

DataGridColumnExample.as

En este ejemplo, se muestra cómo manipular las columnas de un componente DataGrid mediante programación.

Para realizar el ejemplo, siga estos pasos:

Añada los componentes DataGrid y Button a la biblioteca.
Guarde este código como DataGridColumnExample.as en el mismo directorio que el archivo FLA.
Defina la clase Document como DataGridColumnExample en el archivo FLA.

package
{
    import fl.controls.Button;
    import fl.controls.DataGrid;
    import fl.controls.dataGridClasses.DataGridColumn;
    import fl.data.DataProvider;
    import fl.events.DataChangeEvent;
    import flash.display.Sprite;
    import flash.events.MouseEvent;

    public class DataGridColumnExample extends Sprite
    {
        private var dg:DataGrid;
        private var dp:DataProvider;
        private var names:Array = [ "Mary", "Bob", "Sue", "Joe" ];


        public function DataGridColumnExample() {
            dp = new DataProvider();
            dp.addEventListener(DataChangeEvent.DATA_CHANGE,dataChanged);

            dg = new DataGrid();
            addChild(dg);
            dg.move(10,45);
            dg.setSize(450,300);
            dg.addColumn(new DataGridColumn("name"));
            dg.addColumn(new DataGridColumn("phone"));
            dg.addColumn(new DataGridColumn("email"));

            var firstColumn = dg.columns[0];
            firstColumn.resizable = false;
            var secondColumn = dg.columns[1];
            secondColumn.sortable = false;
            var thirdColumn = dg.columns[2];
            thirdColumn.sortable = false;

            var addContactBtn:Button = new Button();
            addContactBtn.label = "Add Contact";
            addContactBtn.move(10,10);
            addContactBtn.addEventListener(MouseEvent.CLICK, addContact);
            addChild(addContactBtn);
        }

        private function getRandomPhone():String {
            return randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+randomDigit();
        }
        private function randomDigit():String {
            return String(Math.round(Math.random()*10)%10);
        }
        private function getRandomName():String {
            return names[Math.round(Math.random()*names.length)%names.length];
        }
        private function addContact(e:MouseEvent):void {
            var randomName:String = getRandomName()
            dp.addItem( { name: randomName, phone: getRandomPhone(), email: randomName + "@fictitious.com" } );
        }
        private function dataChanged(e:DataChangeEvent):void {
            var changedItems:Array = e.items;
            dg.addItem(changedItems[0]);
        }
    }
}

Página actual: http://livedocs.adobe.com/flash/9.0_es/ActionScriptLangRefV3/fl/controls/dataGridClasses/DataGridColumn.html

Referencia del lenguaje y componentes ActionScript 3.0		Todos los paquetes \| Todas las clases \| Elementos del lenguaje \| Índice \| Apéndices \| Convenciones \| Marcos Quitar marcos
DataGridColumn	Propiedades \| Métodos \| Ejemplos

Paquete	fl.controls.dataGridClasses
Clase	public class DataGridColumn
Herencia	DataGridColumn Object