Obtiene o define una cadena que indica cómo cambia de tamaño y se alinea una etiqueta para que encaje el valor de su propiedad text. Los valores siguientes son válidos:

• TextFieldAutoSize.NONE: la etiqueta no cambia de tamaño ni se alinea para que encaje el texto.
• TextFieldAutoSize.LEFT: los lados derecho e inferior de la etiqueta cambian de tamaño para que encaje el texto. Los lados izquierdo y superior no cambian de tamaño.
• TextFieldAutoSize.CENTER: los lados izquierdo y derecho de la etiqueta cambian de tamaño para que encaje el texto. El centro horizontal de la etiqueta permanece fijo en su posición central horizontal original.
• TextFieldAutoSize.RIGHT: los lados izquierdo e inferior de la etiqueta cambian de tamaño para que encaje el texto. Los lados superior y derecho no cambian de tamaño.

El valor predeterminado es TextFieldAutoSize.NONE.

Véase también

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Obtiene o define un valor que indica si se deben eliminar espacios en blanco adicionales como, por ejemplo, espacios y saltos de línea, de un componente Label con texto HTML. true indica que el espacio en blanco se va a eliminar; false determina lo contrario.

La propiedad condenseWhite sólo afecta al texto definido con htmlText, no con la propiedad text. Si utiliza la propiedad text para definir texto, condenseWhite se omitirá.

Si establece la propiedad condenseWhite como true, debe utilizar comandos HTML estándar, como <br> y <p>, para incluir saltos de línea en el campo de texto.

El valor predeterminado es false.

Véase también

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Obtiene o define la altura del componente, expresada en píxeles.

La definición de esta propiedad provoca que se distribuya un evento resize. Consulte el evento resize para obtener información detallada sobre cuándo se distribuirá.

Si la propiedad scaleY del componente no es 1.0, la altura del componente que se obtiene de sus coordenadas internas no coincidirá con el valor de altura de las coordenadas principales. Por ejemplo, un componente que tiene 100 píxeles de altura y una propiedad scaleY de 2, tiene un valor de 100 píxeles en la coordenada principal, aunque internamente almacena un valor que indica que su altura es de 50 píxeles.

Véase también

Obtiene o define el texto mostrado por el componente Label, incluido el lenguaje de marcado HTML que indica los estilos del texto. Puede especificar texto HTML en esta propiedad con el subconjunto de etiquetas HTML admitido por el objeto TextField.

Si el valor predeterminado de la propiedad text cambia en el inspector de propiedades, este valor modificado tiene prioridad sobre cualquier valor de la propiedad htmlText en el inspector. Para utilizar la propiedad htmlText en el inspector de propiedades, el campo de la propiedad text debe incluir el valor Label, exactamente como se muestra. Cuando se codifica con ActionScript, no es necesario establecer el valor de la propiedad text; el valor predeterminado es Label.

El valor predeterminado es "".

Véase también

Obtiene o define un valor que indica si el texto se puede seleccionar. El valor true determina que se puede seleccionar; false indica lo contrario.

El texto que el usuario puede seleccionar, se puede copiar desde el componente Label.

El valor predeterminado es false.

Obtiene o define el texto sin formato que mostrará el componente Label.

Tenga en cuenta que los caracteres que representan marcado HTML no tienen formato especial en la cadena y se muestran tal y como se introducen.

Para mostrar texto que incluya etiquetas HTML, utilice la propiedad htmlText. HTML sustituirá todo el texto definido con la propiedad htmlText y text devolverá una versión sin formato del texto HTML con todas las etiquetas HTML eliminadas.

Si text cambia a partir del valor predeterminado en el inspector de propiedades, tiene prioridad sobre la propiedad htmlText en el inspector.

El valor predeterminado es "Label".

Véase también

Referencia al campo de texto interno del componente Label.

Obtiene o define la anchura del componente, expresada en píxeles.

La definición de esta propiedad provoca que se distribuya un evento resize. Consulte el evento resize para obtener información detallada sobre cuándo se distribuirá.

Si la propiedad scaleX del componente no es 1.0, la anchura del componente que se obtiene de sus coordenadas internas no coincidirá con el valor de anchura de las coordenadas principales. Por ejemplo, un componente que tiene 100 píxeles de anchura y una propiedad scaleX de 2, tiene un valor de 100 píxeles en la coordenada principal, aunque internamente almacena un valor que indica que su anchura es de 50 píxeles.

Véase también

Obtiene o define un valor que indica si el campo de texto admite ajuste de texto. true determina que así es; false indica lo contrario.

El valor predeterminado es false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Crea una instancia de componente Label nueva.

Devuelve la asignación de estilos predeterminada del componente actual. La asignación de estilos contiene el tipo adecuado para el componente, en función del estilo que ese componente utilice. Por ejemplo, el estilo disabledTextFormat contiene un valor null o un objeto TextFormat. Puede utilizar estos estilos y llamar a setStyle() en el componente actual. El código siguiente sustituye el estilo predeterminado disabledTextFormat en el componente especificado:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Véase también

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Se distribuye tras un cambio de altura o anchura del componente.

Nota: este evento no tiene lugar si se utiliza código ActionScript para modificar el texto de la etiqueta.

Este evento tiene las propiedades siguientes:

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

Para realizar el ejemplo, siga estos pasos:

1. Añada los componentes Label y Button a la biblioteca.
2. Guarde este código como LabelExample.as en el mismo directorio que el archivo FLA.
3. Defina la clase Document como LabelExample en el archivo FLA.

package
{
    import fl.controls.Button;
    import fl.controls.Label;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;

    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";

        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10, 50);
            b2.move(10, 80);

            b1.setSize(120, 22);
            b2.setSize(120, 22);

            b1.label = "Make normal label";
            b2.label = "Make HTML label";

            b1.addEventListener(MouseEvent.CLICK, buttonClick);
            b2.addEventListener(MouseEvent.CLICK, buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10, 10);
            simpleLabel.text = "";
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }

        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }

        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}