fl.controls.Button (ActionScript 3.0)

Paquete	fl.controls
Clase	public class Button
Herencia	Button LabelButton BaseButton UIComponent Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object
Implementa	IFocusManagerComponent

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

El componente Button representa un botón rectangular de uso frecuente. Los componentes Button muestran una etiqueta de texto, un icono o ambos elementos.

Los componentes Button se suelen asociar a un método de controlador de eventos que detecta un evento click y realiza la tarea especificada tras distribuir el evento click. Si el usuario hace clic en un botón activado, éste distribuye los eventos click y buttonDown. Incluso si no está activado, un botón distribuye otros eventos, entre los que se incluyen mouseMove, mouseOver, mouseOut, rollOver, rollOut, mouseDown y mouseUp.

La apariencia del botón se puede cambiar asociando un aspecto diferente a cada estado del botón. Los componentes Button también se pueden definir para que funcionen como botones de comando o de activación.

Ver los ejemplos

Propiedades públicas

Ocultar propiedades públicas heredadas

Mostrar propiedades públicas heredadas

	Propiedad		Definido por
		accessibilityProperties : AccessibilityProperties Las opciones de accesibilidad actuales para este objeto de visualización.	DisplayObject
		alpha : Number Indica el valor de transparencia alfa del objeto especificado.	DisplayObject
		autoRepeat : Boolean Obtiene o define un valor booleano que indica si el evento buttonDown se distribuye varias veces cuando el usuario mantiene presionado el botón del ratón sobre el componente.	BaseButton
		blendMode : String Un valor de la clase BlendMode que especifica el modo de mezcla que debe utilizarse.	DisplayObject
		buttonMode : Boolean Especifica el modo de botón de este elemento sprite.	Sprite
		cacheAsBitmap : Boolean Si se define como true, Flash Player deja en caché una representación interna de mapa de bits del objeto de visualización.	DisplayObject
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		contextMenu : ContextMenu Especifica el menú contextual asociado a este objeto.	InteractiveObject
		doubleClickEnabled : Boolean Especifica si este objeto recibe eventos doubleClick.	InteractiveObject
		dropTarget : DisplayObject [read-only] Especifica el objeto de visualización sobre el que se está arrastrando el elemento sprite o sobre el que se ha colocado el elemento sprite.	Sprite
		emphasized : Boolean Obtiene o define un valor booleano que indica si se dibuja un borde alrededor del componente Button cuando el botón no está presionado.	Button
		enabled : Boolean Obtiene o define un valor que indica si el componente puede aceptar la entrada del usuario.	BaseButton
		filters : Array Matriz indexada que contiene todos los objetos de filtro actualmente asociados con el objeto de visualización.	DisplayObject
		focusEnabled : Boolean Obtiene o define un valor booleano que indica si el componente puede recibir selecciones cuando el usuario hace clic sobre él.	UIComponent
		focusManager : IFocusManager Obtiene o define la clase FocusManager que controla la selección de este componente y sus homólogos.	UIComponent
		focusRect : Object Especifica si este objeto muestra un rectángulo de selección.	InteractiveObject
		graphics : Graphics [read-only] Especifica el objeto Graphics que pertenece a este elemento sprite, donde pueden ejecutarse comandos de dibujo vectorial.	Sprite
		height : Number Obtiene o define la altura del componente, expresada en píxeles.	UIComponent
		hitArea : Sprite Designa otro elemento sprite para que actúe como área activa de un elemento sprite.	Sprite
		label : String Obtiene o define la etiqueta de texto del componente.	LabelButton
		labelPlacement : String Posición de la etiqueta respecto a un icono especificado.	LabelButton
		loaderInfo : LoaderInfo [read-only] Devuelve un objeto LoaderInfo que contiene información sobre la carga del archivo al que pertenece este objeto de visualización.	DisplayObject
		mask : DisplayObject El objeto de visualización que origina la llamada se enmascara mediante el objeto mask especificado.	DisplayObject
		mouseChildren : Boolean Determina si los elementos secundarios del objeto están habilitados para ratón.	DisplayObjectContainer
		mouseEnabled : Boolean Especifica si este objeto recibe mensajes de ratón.	InteractiveObject
		mouseFocusEnabled : Boolean Obtiene o define un valor booleano que indica si el componente puede recibir selecciones cuando el usuario hace clic sobre él.	UIComponent
		mouseX : Number [read-only] Indica la coordenada x de la posición del ratón en píxeles.	DisplayObject
		mouseY : Number [read-only] Indica la coordenada y de la posición del ratón en píxeles.	DisplayObject
		name : String Indica el nombre de instancia de DisplayObject.	DisplayObject
		numChildren : int [read-only] Devuelve el número de elementos secundarios de este objeto.	DisplayObjectContainer
		opaqueBackground : Object Especifica si el objeto de visualización es opaco con un determinado color de fondo.	DisplayObject
		parent : DisplayObjectContainer [read-only] Indica el objeto DisplayObjectContainer que contiene este objeto de visualización.	DisplayObject
		prototype : Object [static] Una referencia al objeto prototipo de una clase u objeto de función.	Object
		root : DisplayObject [read-only] Para un objeto de visualización en un archivo SWF cargado, la propiedad root es el objeto de visualización de nivel más alto en la parte de la estructura de árbol de la lista de visualización representada por dicho archivo SWF.	DisplayObject
		rotation : Number Indica el giro de la instancia de DisplayObject, expresado en grados, con respecto a su orientación original.	DisplayObject
		scale9Grid : Rectangle La cuadrícula de escala aplicada actualmente.	DisplayObject
		scaleX : Number Multiplica la anchura actual del componente por un factor de escala.	UIComponent
		scaleY : Number Multiplica la altura actual del componente por un factor de escala.	UIComponent
		scrollRect : Rectangle Los límites del rectángulo de desplazamiento del objeto de visualización.	DisplayObject
		selected : Boolean Obtiene o define un valor booleano que indica si un botón puede cambiar a la posición activado o desactivado.	LabelButton
		soundTransform : SoundTransform Controla el sonido dentro de este elemento sprite.	Sprite
		stage : Stage [read-only] El escenario del objeto de visualización.	DisplayObject
		tabChildren : Boolean Determina si los elementos secundarios del objeto están habilitados para tabulación.	DisplayObjectContainer
		tabEnabled : Boolean Especifica si este objeto está en el orden de tabulación.	InteractiveObject
		tabIndex : int Especifica el orden de tabulación de los objetos de un archivo SWF.	InteractiveObject
		textField : TextField Referencia al campo de texto interno del componente.	LabelButton
		textSnapshot : TextSnapshot [read-only] Devuelve un objeto TextSnapshot para esta instancia de DisplayObjectContainer.	DisplayObjectContainer
		toggle : Boolean Obtiene o define un valor booleano que indica si un botón se puede activar y desactivar.	LabelButton
		transform : Transform Objeto con propiedades pertenecientes a una matriz, transformación de color y límites de píxel de un objeto de visualización.	DisplayObject
		useHandCursor : Boolean Valor booleano que indica si debe aparecer la mano que señala (cursor de mano) cuando el ratón pasa por encima de un elemento sprite en el que la propiedad buttonMode se ha definido con el valor true.	Sprite
		version : String = "3.0.0.15" Número de versión de los componentes.	UIComponent
		visible : Boolean Obtiene o define un valor que indica si la instancia del componente actual es visible.	UIComponent
		width : Number Obtiene o define la anchura del componente, expresada en píxeles.	UIComponent
		x : Number Obtiene o define la coordenada x que representa la posición del componente a lo largo del eje x en su contenedor principal.	UIComponent
		y : Number Obtiene o define la coordenada y que representa la posición del componente a lo largo del eje y en su contenedor principal.	UIComponent

Métodos públicos

Ocultar métodos públicos heredados

Mostrar métodos públicos heredados

	Método		Definido por
		Button() Crea una instancia de componente Button nueva.	Button
		addChild(child:DisplayObject):DisplayObject Añade una instancia secundaria de DisplayObject a esta instancia de DisplayObjectContainer.	DisplayObjectContainer
		addChildAt(child:DisplayObject, index:int):DisplayObject Añade una instancia secundaria de DisplayObject a esta instancia de DisplayObjectContainer.	DisplayObjectContainer
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registra un objeto de detector de eventos con un objeto EventDispatcher, de modo que el detector reciba la notificación de un evento.	EventDispatcher
		areInaccessibleObjectsUnderPoint(point:Point):Boolean Indica si las restricciones de seguridad provocarían la omisión de objetos de visualización de la lista devuelta al llamar al método DisplayObjectContainer.getObjectsUnderPoint() con el punto point especificado.	DisplayObjectContainer
		clearStyle(style:String):void Elimina una propiedad de estilo de esta instancia de componente.	UIComponent
		contains(child:DisplayObject):Boolean Determina si el objeto de visualización especificado es un elemento secundario de la instancia de DisplayObjectContainer o la propia instancia.	DisplayObjectContainer
		dispatchEvent(event:Event):Boolean Distribuye un evento en el flujo del evento.	EventDispatcher
		drawFocus(focused:Boolean):void Muestra u oculta el indicador de selección en este componente.	UIComponent
		drawNow():void Inicia de forma inmediata una operación de dibujo, sin invalidarlo todo como ocurre con invalidateNow.	UIComponent
		getBounds(targetCoordinateSpace:DisplayObject):Rectangle Devuelve un rectángulo que define el área del objeto de visualización relativo al sistema de coordenadas del objeto targetCoordinateSpace.	DisplayObject
		getChildAt(index:int):DisplayObject Devuelve la instancia del objeto de visualización secundario que sale del índice especificado.	DisplayObjectContainer
		getChildByName(name:String):DisplayObject Devuelve el objeto de visualización secundario que sale con el nombre especificado.	DisplayObjectContainer
		getChildIndex(child:DisplayObject):int Devuelve la posición de índice de una instancia secundaria de DisplayObject.	DisplayObjectContainer
		getFocus():InteractiveObject Recupera el objeto que está seleccionado actualmente.	UIComponent
		getObjectsUnderPoint(point:Point):Array Devuelve una matriz de objetos que quedan bajo el punto especificado y son elementos secundarios (o terciarios, etc.) de esta instancia de DisplayObjectContainer.	DisplayObjectContainer
		getRect(targetCoordinateSpace:DisplayObject):Rectangle Devuelve un rectángulo que define el límite del objeto de visualización, basado en el sistema de coordenadas definido por el parámetro targetCoordinateSpace, excluyendo los trazos en las formas.	DisplayObject
		getStyle(style:String):Object Recupera una propiedad de estilo que se define en la cadena de búsqueda de estilo del componente.	UIComponent
		getStyleDefinition():Object [static] Devuelve la asignación de estilos predeterminada del componente actual.	Button
		globalToLocal(point:Point):Point Convierte el objeto point de las coordenadas del escenario (globales) en las coordenadas del objeto de visualización (locales).	DisplayObject
		hasEventListener(type:String):Boolean Comprueba si el objeto EventDispatcher tiene detectores registrados para un tipo concreto de evento.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		hitTestObject(obj:DisplayObject):Boolean Evalúa el objeto de visualización para comprobar si se solapa o presenta un punto de intersección con el objeto de visualización obj.	DisplayObject
		hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean Evalúa el objeto de visualización para comprobar si se solapa o presenta un punto de intersección con el punto especificado por los parámetros x e y.	DisplayObject
		invalidate(property:String, callLater:Boolean = true):void Marca una propiedad como no válida y vuelve a dibujar el componente en el siguiente fotograma a menos que se especifique lo contrario.	UIComponent
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		localToGlobal(point:Point):Point Convierte el objeto point de coordenadas del objeto de visualización (locales) en coordenadas del escenario (globales).	DisplayObject
		mergeStyles(... list):Object [static] Combina los estilos de varias clases en un objeto.	UIComponent
		move(x:Number, y:Number):void Mueve el componente a la posición especificada dentro de su elemento principal.	UIComponent
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		removeChild(child:DisplayObject):DisplayObject Elimina la instancia child de DisplayObject especificada de la lista de elementos secundarios de la instancia de DisplayObjectContainer.	DisplayObjectContainer
		removeChildAt(index:int):DisplayObject Elimina una instancia de DisplayObject secundaria de la posición de índice especificada en la lista de elementos secundarios de DisplayObjectContainer.	DisplayObjectContainer
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Elimina un detector del objeto EventDispatcher.	EventDispatcher
		setChildIndex(child:DisplayObject, index:int):void Cambia la posición de un elemento secundario existente en el contendor de objeto de visualización.	DisplayObjectContainer
		setFocus():void Selecciona este componente.	UIComponent
		setMouseState(state:String):void Establece el estado del ratón a través de ActionScript.	BaseButton
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		setSize(width:Number, height:Number):void Define el componente en la anchura y altura especificadas.	UIComponent
		setStyle(style:String, value:Object):void Define una propiedad de estilo en esta instancia de componente.	UIComponent
		startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void Permite al usuario arrastrar el elemento sprite especificado.	Sprite
		stopDrag():void Finaliza el método startDrag().	Sprite
		swapChildren(child1:DisplayObject, child2:DisplayObject):void Intercambia el orden z (de delante a atrás) de los dos objetos secundarios especificados.	DisplayObjectContainer
		swapChildrenAt(index1:int, index2:int):void Intercambia el orden z (de delante a atrás) de los objetos secundarios situados en las posiciones de índice especificadas en la lista de elementos secundarios.	DisplayObjectContainer
		toString():String Devuelve la representación de cadena del objeto especificado.	Object
		validateNow():void Valida y actualiza las propiedades y el diseño de este objeto y lo vuelve a dibujar, si es necesario.	UIComponent
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object
		willTrigger(type:String):Boolean Comprueba si hay registrado un detector de eventos con este objeto EventDispatcher o con cualquiera de sus ascendientes para el tipo de evento concreto.	EventDispatcher

Eventos

Ocultar eventos heredados

Mostrar eventos heredados

	Resumen	Definido por
activate	Se distribuye cuando Flash Player queda seleccionado por el sistema operativo y pasa a estar activo.	EventDispatcher
added	Se distribuye cuando un objeto de visualización se añade a la lista de visualización.	DisplayObject
addedToStage	Se distribuye cuando un objeto de visualización se añade a la lista de visualización del escenario, bien directamente o a través de un subárbol que contiene el objeto de visualización.	DisplayObject
buttonDown	Se distribuye cuando el usuario presiona el componente Button.	BaseButton
change	Se distribuye si cambia el valor de la propiedad "selected" de un componente Button de activación.	BaseButton
click	Se distribuye tras presionar el botón de activación con el ratón o la barra espaciadora.	LabelButton
deactivate	Se distribuye cuando Flash Player deja de estar seleccionado por el sistema operativo y pasa a estar inactivo.	EventDispatcher
doubleClick	Se distribuye cuando un usuario pulsa y suelta el botón principal de un dispositivo de señalización dos veces en una sucesión rápida sobre el mismo objeto InteractiveObject cuando el indicador doubleClickEnabled de dicho objeto se ha definido como true.	InteractiveObject
enterFrame	Se distribuye cuando la cabeza lectora entra en un nuevo fotograma.	DisplayObject
focusIn	Se distribuye después de que un objeto de visualización quede seleccionado.	InteractiveObject
focusOut	Se distribuye después de que un objeto de visualización deje de estar seleccionado.	InteractiveObject
hide	Se distribuye cuando la visibilidad del componente cambia de visible a invisible.	UIComponent
keyDown	Se distribuye cuando el usuario pulsa una tecla.	InteractiveObject
keyFocusChange	Se distribuye cuando el usuario intenta cambiar la selección empleando la navegación mediante teclado.	InteractiveObject
keyUp	Se distribuye cuando el usuario suelta una tecla.	InteractiveObject
labelChange	Se distribuye cuando se modifica el valor de la etiqueta.	LabelButton
mouseDown	Se distribuye cuando el usuario pulsa el botón del dispositivo de señalización sobre una instancia de InteractiveObject en la ventana de Flash Player.	InteractiveObject
mouseFocusChange	Se distribuye cuando el usuario intenta cambiar la selección empleando un dispositivo de señalización.	InteractiveObject
mouseMove	Se distribuye cuando el usuario mueve el dispositivo de señalización mientras éste se encuentra sobre un InteractiveObject.	InteractiveObject
mouseOut	Se distribuye cuando el usuario mueve un dispositivo de señalización hacia el exterior de una instancia de InteractiveObject.	InteractiveObject
mouseOver	Se distribuye cuando el usuario pasa el dispositivo de señalización por encima de una instancia de InteractiveObject en la ventana de Flash Player.	InteractiveObject
mouseUp	Se distribuye cuando el usuario suelta el botón del dispositivo de señalización sobre una instancia de InteractiveObject en la ventana de Flash Player.	InteractiveObject
mouseWheel	Se distribuye cuando se hace girar una rueda de ratón sobre una instancia de InteractiveObject en la ventana de Flash Player.	InteractiveObject
move	Se distribuye cuando se mueve el componente.	UIComponent
removed	Se distribuye cuando un objeto de visualización se va a eliminar de la lista de visualización.	DisplayObject
removedFromStage	Se distribuye cuando un objeto de visualización se va a eliminar de la lista de visualización, bien directamente o a través de la eliminación de un subárbol que contiene el objeto de visualización.	DisplayObject
render	Se distribuye cuando la lista de visualización se va a actualizar y mostrar.	DisplayObject
resize	Se distribuye cuando se cambia el tamaño del componente.	UIComponent
rollOut	Se distribuye cuando el usuario mueve un dispositivo de señalización hacia el exterior de una instancia de InteractiveObject.	InteractiveObject
rollOver	Se distribuye cuando el usuario mueve un dispositivo de señalización sobre una instancia de InteractiveObject.	InteractiveObject
show	Se distribuye cuando la visibilidad del componente cambia de invisible a visible.	UIComponent
tabChildrenChange	Se distribuye cuando cambia el valor del indicador tabChildren del objeto.	InteractiveObject
tabEnabledChange	Se distribuye cuando cambia el indicador tabEnabled del objeto.	InteractiveObject
tabIndexChange	Se distribuye cuando cambia el valor de la propiedad tabIndex del objeto.	InteractiveObject

Estilos

Ocultar estilos heredados

Mostrar estilos heredados

	Descripción	Definido por
disabledIcon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón no está desactivado.	LabelButton
disabledSkin	Tipo: Class Nombre de la clase que se utiliza como aspecto para el fondo y el borde cuando el botón no está seleccionado y está desactivado.	LabelButton
disabledTextFormat	Tipo: flash.text.TextFormat El objeto TextFormat que se utilizará para representar la etiqueta del componente cuando el botón esté desactivado.	UIComponent
downIcon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón no está seleccionado y el botón del ratón está presionado.	LabelButton
downSkin	Tipo: Class Nombre de la clase que se utiliza como aspecto para el fondo y el borde cuando el botón no está seleccionado y el botón del ratón está presionado.	LabelButton
embedFonts	Tipo: Boolean Indica si se utilizan contornos de fuentes incorporadas para representar el campo de texto.	LabelButton
emphasizedPadding	Tipo: Number Formato: Length El relleno que se aplicará alrededor de los botones de un aspecto resaltado, expresado en píxeles. El valor predeterminado es `2`.	Button
emphasizedSkin	Tipo: Class El aspecto que se utilizará cuando un botón esté resaltado. El valor predeterminado es `Button_emphasizedSkin`.	Button
focusRectPadding	Tipo: Number Formato: Length El relleno que separa los límites externos del componente de los bordes externos del indicador de selección, expresado en píxeles.	UIComponent
focusRectSkin	Tipo: Class El aspecto que se utilizará para mostrar los indicadores de selección.	UIComponent
icon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón de activación no está seleccionado y el ratón no está sobre el componente.	LabelButton
overIcon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón no está seleccionado y el ratón está sobre el componente.	LabelButton
overSkin	Tipo: Class Nombre de la clase que se utiliza como aspecto para el fondo y el borde cuando el botón no está seleccionado y el ratón está sobre el componente.	LabelButton
repeatDelay	Tipo: Number Formato: Time El número de milisegundos de espera después de que el evento `buttonDown` se distribuyera por primera vez antes de enviar un segundo evento `buttonDown`.	LabelButton
repeatInterval	Tipo: Number Formato: Time El intervalo, en milisegundos, entre los eventos `buttonDown` que se distribuyen después del retardo especificado por el estilo `repeatDelay`.	LabelButton
selectedDisabledIcon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón está seleccionado y desactivado.	LabelButton
selectedDisabledSkin	Tipo: Class Nombre de la clase que se utiliza como aspecto para el fondo y el borde cuando un botón de activación está seleccionado y desactivado.	LabelButton
selectedDownIcon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón está seleccionado y el botón del ratón está presionado.	LabelButton
selectedDownSkin	Tipo: Class Nombre de la clase que se utiliza como aspecto para el fondo y el borde cuando un botón de activación está seleccionado y el botón del ratón está presionado.	LabelButton
selectedOverIcon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón está seleccionado y el ratón está sobre el componente.	LabelButton
selectedOverSkin	Tipo: Class Nombre de la clase que se utiliza como aspecto para el fondo y el borde cuando un botón de activación está seleccionado y el ratón está sobre el componente.	LabelButton
selectedUpIcon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón está seleccionado y el botón del ratón no está presionado.	LabelButton
selectedUpSkin	Tipo: Class Nombre de la clase que se utiliza como aspecto para el fondo y el borde cuando un botón de activación está seleccionado y el ratón no está sobre el componente.	LabelButton
textFormat	Tipo: flash.text.TextFormat El objeto TextFormat que se utilizará para representar la etiqueta del componente.	UIComponent
textPadding	Tipo: Number Formato: Length El espaciado entre el texto y los bordes del componente, así como el espaciado entre el texto y el icono, expresado en píxeles.	LabelButton
upIcon	Tipo: Class Nombre de la clase que se utiliza como icono cuando el botón de activación no está seleccionado y el ratón no está sobre el componente.	LabelButton
upSkin	Tipo: Class Nombre de la clase que se utiliza como aspecto para el fondo y el borde cuando el botón no está seleccionado y el ratón no está sobre el componente.	LabelButton

Información sobre propiedades

emphasized

propiedad

emphasized:Boolean [read-write]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Obtiene o define un valor booleano que indica si se dibuja un borde alrededor del componente Button cuando el botón no está presionado. El valor true indica que el botón está rodeado de un borde cuando no se encuentra presionado; false determina que no lo está.

El valor predeterminado es false.

Implementación
public function get emphasized():Boolean
public function set emphasized(value:Boolean):void

Véase también

emphasizedPadding
emphasizedSkin

Ejemplo

En el ejemplo siguiente, se define el estilo emphasizedPadding de la instancia Button en función del valor de un componente Slider:


import fl.controls.Button;
import fl.controls.Slider;
import fl.events.SliderEvent;

var styleObject:Object = Button.getStyleDefinition();
var defaultEmphasizedPadding:uint = styleObject.emphasizedPadding;

var myButton:Button = new Button();
myButton.label = "emphasizedPadding:" + defaultEmphasizedPadding;
myButton.emphasized = true;
myButton.width = 150;
myButton.move(20, 20);
addChild(myButton);

var mySlider:Slider = new Slider();
mySlider.snapInterval = 1;
mySlider.tickInterval = 1;
mySlider.liveDragging = true;
mySlider.value = defaultEmphasizedPadding;
mySlider.width = myButton.width;
mySlider.move(20, 60);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myButton.label = "emphasizedPadding:" + event.value;
    myButton.setStyle("emphasizedPadding", event.value);
}

Información sobre constructores

Button

()

constructor

public function Button()

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Crea una instancia de componente Button nueva.

Información sobre métodos

getStyleDefinition

()

método

public static function getStyleDefinition():Object

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Devuelve la asignación de estilos predeterminada del componente actual. La asignación de estilos contiene el tipo adecuado para el componente, en función del estilo que ese componente utilice. Por ejemplo, el estilo disabledTextFormat contiene un valor null o un objeto TextFormat. Puede utilizar estos estilos y llamar a setStyle() en el componente actual. El código siguiente sustituye el estilo predeterminado disabledTextFormat en el componente especificado:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Valor devuelto

Object — Objeto de estilos predeterminados.

Véase también

UIComponent.getStyle()
UIComponent.setStyle()
StyleManager

Ejemplo

En el ejemplo siguiente, se crea un navegador de estilos para varias clases de componentes:

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Ejemplos Cómo utilizar los ejemplos

ButtonExample.as

En este ejemplo se muestra cómo crear y aplicar un estilo a los botones dinámicamente.

Para realizar el ejemplo, siga estos pasos:

Añada los componentes Button y TextArea a la biblioteca.
Guarde este código como ButtonExample.as en el mismo directorio del archivo FLA.
Defina la clase Document como ButtonExample en el archivo FLA.

package
{
    import fl.controls.Button;
    import fl.controls.TextArea;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextFormat;

    public class ButtonExample extends Sprite
    {
        private var b1:Button;
        private var b2:Button;
        private var b3:Button;
        private var ta:TextArea;

        public function ButtonExample() {
            createTraceField();
            setupButtons();
        }
        private function createTraceField():void {
            ta = new TextArea();
            ta.setSize(200, 300);
            ta.move(200, 10);
            addChild(ta);
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();
            b3 = new Button();

            b1.width = 160;
            b2.width = 160;
            b3.width = 160;

            b1.move(10,10);
            b2.move(10,40);
            b3.move(10,70);

            b1.label = "Default Button";
            b2.label = "Custom Styled Button";
            b3.label = "Toggle Button";

            b2.setStyle("textFormat", new TextFormat("Georgia"));

            b3.toggle = true;

            b1.addEventListener(MouseEvent.CLICK, buttonClick);
            b2.addEventListener(MouseEvent.CLICK, buttonClick);
            b3.addEventListener(MouseEvent.CLICK, buttonClick);

            addChild(b1);
            addChild(b2);
            addChild(b3);
        }
        private function buttonClick(e:MouseEvent) {
            var button:Button = e.target as Button;
            ta.appendText(button.label + "\n");
        }
    }
}

Página actual: http://livedocs.adobe.com/flash/9.0_es/ActionScriptLangRefV3/fl/controls/Button.html

Referencia del lenguaje y componentes ActionScript 3.0		Todos los paquetes \| Todas las clases \| Elementos del lenguaje \| Índice \| Apéndices \| Convenciones \| Marcos Quitar marcos
Button	Propiedades \| Métodos \| Eventos \| Estilos \| Ejemplos