Indica si el carácter de punto (.) del patrón de una expresión normal coincide con caracteres de nueva línea. Utilice el indicador s al construir una expresión normal para definir dotall = true.

Véase también

var str:String = "<p>Hello\n"
        + "again</p>"
        + "<p>Hello</p>";

var pattern:RegExp = /<p>.*?<\/p>/;
trace(pattern.dotall) // false
trace(pattern.exec(str)); // <p>Hello</p>

pattern = /<p>.*?<\/p>/s;
trace(pattern.dotall) // true
trace(pattern.exec(str));

Especifica si debe utilizarse el modo ampliado para la expresión normal. Cuando un objeto RegExp está en modo ampliado, no se tienen en cuenta los caracteres de espacio en blanco de la cadena constructora. Esto permite que los constructores resulten más legibles.

Utilice el indicador x al construir una expresión normal para definir extended = true.

Véase también

var rePhonePattern1:RegExp = /\d{3}-\d{3}-\d{4}|\(\d{3}\)\s?\d{3}-\d{4}/;
var str:String = "The phone number is (415)555-1212.";

trace(rePhonePattern1.extended) // false
trace(rePhonePattern1.exec(str)); // (415)555-1212

var rePhonePattern2:RegExp = / \d{3}-\d{3}-\d{4}  |   \( \d{3} \) \ ? \d{3}-\d{4}  /x;
trace(rePhonePattern2.extended) // true
trace(rePhonePattern2.exec(str)); // (415)555-1212

Especifica si debe utilizarse la coincidencia global para la expresión normal. Si global == true, la propiedad lastIndex se define después de que se encuentre una coincidencia. La próxima vez que se solicite una coincidencia, el motor de expresión normal comenzará desde la posición lastIndex de la cadena. Utilice el indicador g al construir una expresión normal para definir global con el valor true.

Véase también

var pattern:RegExp = /foo\d/;
var str:String = "foo1 foo2";
trace(pattern.global); // false
trace(pattern.exec(str)); // foo1
trace(pattern.lastIndex); // 0
trace(pattern.exec(str)); // foo1

pattern = /foo\d/g;
trace(pattern.global); // true
trace(pattern.exec(str)); // foo1
trace(pattern.lastIndex); // 4
trace(pattern.exec(str)); // foo2

Especifica si la expresión normal no distingue entre mayúsculas y minúsculas. Utilice el indicador i al construir una expresión normal para definir ignoreCase = true.

Véase también

var pattern:RegExp = /bob/;
var str:String = "Bob bob";
trace(pattern.ignoreCase); // false
trace(pattern.exec(str)); // bob

pattern = /bob/i;
trace(pattern.ignoreCase); // true
trace(pattern.exec(str)); // Bob

Especifica la posición de índice de la cadena en la que debe comenzar la siguiente búsqueda. Esta propiedad afecta a los métodos exec() y test() de la clase RegExp. Sin embargo, los métodos match(), replace() y search() de la clase String no tienen en cuenta la propiedad lastIndex y comienzan todas las búsquedas desde el principio de la cadena.

Si el método exec() o test() encuentran una coincidencia y el indicador g (global) está definido como true para la expresión normal, el método establece automáticamente la propiedad lastIndex con la posición de índice del carácter situado después del último carácter de la subcadena coincidente en la última coincidencia. Si el indicador g (global) se define como false, el método no define la propiedad lastIndex.

Puede definir la propiedad lastIndex para ajustar la posición de inicio en la cadena para la comparación con la expresión normal.

Véase también

var pattern:RegExp = /\w\d/g;
var str:String = "a1 b2 c3 d4";
pattern.lastIndex = 2;
trace(pattern.exec(str)); // b2
trace(pattern.lastIndex); // 5
trace(pattern.exec(str)); // c3
trace(pattern.lastIndex); // 8
trace(pattern.exec(str)); // d4
trace(pattern.lastIndex); // 11
trace(pattern.exec(str)); // null

Especifica si está definido el indicador m (multiline). Si está definido, el símbolo de intercalación (^) y el símbolo del dólar ($) de una expresión normal coinciden antes y después de las nuevas líneas. Utilice el indicador m al construir una expresión normal para definir multiline = true.

Véase también

var pattern:RegExp = /^bob/;
var str:String = "foo\n"
                + "bob";
trace(pattern.multiline); // false
trace(pattern.exec(str)); // null

pattern = /^bob/m;
trace(pattern.multiline); // true
trace(pattern.exec(str)); // bob

Especifica la parte del patrón de la expresión normal.

Véase también

var re1:RegExp = /aabb/gi;
trace(re1.source); // aabb

var re2:RegExp = new RegExp("x+y*", "i");
trace(re2.source); // x+y*

Le permite construir una expresión normal a partir de dos cadenas. Una cadena define el patrón de la expresión normal, mientras que la otra define los indicadores utilizados en la expresión normal.

Véase también

Realiza una búsqueda de la expresión normal en la cadena str en cuestión.

Si el indicador g (global) no está definido para la expresión normal, la búsqueda comienza al principio de la cadena (en la posición de índice 0); la búsqueda omite la propiedad lastIndex de la expresión normal.

Si el indicador g (global) está definido para la expresión normal, la búsqueda comienza en la posición de índice especificada por la propiedad lastIndex de la expresión normal. Si la búsqueda coincide con una subcadena, la propiedad lastIndex cambia para que se corresponda con la posición del final de la coincidencia.

Parámetros

Véase también

         var myPattern:RegExp = /(\w*)sh(\w*)/ig;
         var str:String = "She sells seashells by the seashore";
         var result:Object = myPattern.exec(str);
         trace(result);
         

         var myPattern:RegExp = /(\w*)sh(\w*)/ig;
         var str:String = "She sells seashells by the seashore";
         var result:Object = myPattern.exec(str);
                  while (result != null) {
             trace( result.index, "\t", result);
             result = myPattern.exec(str);
         }
         

 0 She,,e 10 seashells,sea,ells 27 seashore,sea,ore 

Comprueba la coincidencia de la expresión normal con la cadena str en cuestión.

Si el indicador g (global) no está definido para la expersión normal, la búsqueda comienza al principio de la cadena (en la posición de índice 0); la búsqueda omite la propiedad lastIndex de la expersión normal.

Si el indicador g (global) está definido para la expresión normal, la búsqueda comienza en la posición de índice especificada por la propiedad lastIndex de la expresión normal. Si la búsqueda coincide con una subcadena, la propiedad lastIndex cambia para que se corresponda con la posición del final de la coincidencia.

Parámetros

Véase también

var re1:RegExp = /\w/g;
var str:String = "a b c";
trace(re1.lastIndex); // 0
trace(re1.test(str)); // true
trace(re1.lastIndex); // 1
trace(re1.test(str)); // true
trace(re1.lastIndex); // 3
trace(re1.test(str)); // true
trace(re1.lastIndex); // 5
trace(re1.test(str)); // false