PaqueteNivel superior
Clasepublic final dynamic class Date
HerenciaDate Inheritance Object

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La clase Date representa la información de fecha y hora. Una instancia de la clase Date representa un punto concreto en el tiempo para el que pueden consultarse o modificarse propiedades tales como month (mes), day (día), hours (horas) y seconds (segundos). La clase Date permite recuperar los valores de fecha y hora relativos a la hora universal (hora de Greenwich, ahora conocida como hora universal o UTC) o a la hora local, determinada por la configuración de zona horaria local del sistema operativo en el que se ejecuta Flash Player. Los métodos de la clase Date no son estáticos, pero afectan solamente al objeto Date concreto especificado al llamar al método. Los métodos Date.UTC() y Date.parse() son excepciones; son métodos estáticos.

La clase Date controla el horario de verano de forma distinta en función del sistema operativo y la versión de Flash Player. Flash Player 6 y posteriores controlan el horario de verano en los siguientes sistemas operativos de estas formas:

Flash Player 5 controla el cambio de hora en los siguientes sistemas operativos como se indica a continuación:

Para utilizar la clase Date, construya una instancia Date mediante el operador new.

ActionScript 3.0 añade varias propiedades de acceso que pueden utilizarse en lugar de muchos de los métodos de la clase Date que acceden a las instancias de Date o las modifican. ActionScript 3.0 también incluye diversas variantes nuevas del método toString() que se incluyen para lograr la compatibilidad con ECMA-262 edición 3, entre las que figuran éstas: Date.toLocaleString(), Date.toTimeString(), Date.toLocaleTimeString(), Date.toDateString() y Date.toLocaleDateString().

Para calcular la hora relativa o el tiempo transcurrido, consulte el método getTimer() del paquete flash.utils.

Ver los ejemplos

Véase también

flash.utils.getTimer()
Utilización de fechas y horas

Propiedades públicas
 PropiedadDefinido por
 Inheritedconstructor : Object
Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.
Object
  date : Number
El día del mes (un entero del 1 al 31) especificado por un objeto Date de acuerdo con la hora local.
Date
  dateUTC : Number
El día del mes (un entero del 1 al 31) de un objeto Date de acuerdo con la hora universal (UTC).
Date
  day : Number
[read-only] El día de la semana (0 para domingo, 1 para lunes, etc.) especificado por este objeto Date de acuerdo con la hora local.
Date
  dayUTC : Number
[read-only] El día de la semana (0 para domingo, 1 para lunes, etc.) de este objeto Date de acuerdo con la hora universal (UTC).
Date
  fullYear : Number
El año completo (un número de cuatro dígitos como, por ejemplo, 2000) de un objeto Date de acuerdo con la hora local.
Date
  fullYearUTC : Number
Los cuatro dígitos del año de un objeto Date de acuerdo con la hora universal (UTC).
Date
  hours : Number
La hora (un entero del 0 al 23) de la parte correspondiente al día de un objeto Date de acuerdo con la hora local.
Date
  hoursUTC : Number
La hora (un entero del 0 al 23) del día de un objeto Date de acuerdo con la hora universal (UTC).
Date
  milliseconds : Number
La parte correspondiente a los milisegundos (un entero del 0 al 999) de un objeto Date de acuerdo con la hora local.
Date
  millisecondsUTC : Number
La parte correspondiente a los milisegundos (un entero del 0 al 999) de un objeto Date de acuerdo con la hora universal (UTC).
Date
  minutes : Number
La parte correspondiente a los minutos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora local.
Date
  minutesUTC : Number
La parte correspondiente a los minutos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora universal (UTC).
Date
  month : Number
La parte correspondiente al mes (0 para enero, 1 para febrero, etc.) de un objeto Date de acuerdo con la hora local.
Date
  monthUTC : Number
La parte correspondiente al mes (de 0 [enero] a 11 [diciembre]) de un objeto Date de acuerdo con la hora universal (UTC).
Date
 Inheritedprototype : Object
[static] Una referencia al objeto prototipo de una clase u objeto de función.
Object
  seconds : Number
La parte correspondiente a los segundos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora local.
Date
  secondsUTC : Number
La parte correspondiente a los segundos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora universal (UTC).
Date
  time : Number
El número de milisegundos desde la media noche del 1 de enero de 1970, hora universal, para un objeto Date.
Date
  timezoneOffset : Number
[read-only] La diferencia, en minutos, entre la hora local del equipo y la hora universal (UTC).
Date
Métodos públicos
 MétodoDefinido por
  
Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)
Construye un nuevo objeto Date que contiene la fecha y la hora especificadas.
Date
  
getDate():Number
Devuelve el día del mes (un entero del 1 al 31) especificado por un objeto Date de acuerdo con la hora local.
Date
  
getDay():Number
Devuelve el día de la semana (0 para domingo, 1 para lunes, etc.) especificado por este objeto Date de acuerdo con la hora local.
Date
  
getFullYear():Number
Devuelve el año completo (un número de cuatro dígitos como, por ejemplo, 2000) de un objeto Date de acuerdo con la hora local.
Date
  
getHours():Number
Devuelve la hora (un entero del 0 al 23) de la parte correspondiente al día de un objeto Date de acuerdo con la hora local.
Date
  
getMilliseconds():Number
Devuelve la parte correspondiente a los milisegundos (un entero del 0 al 999) de un objeto Date de acuerdo con la hora local.
Date
  
getMinutes():Number
Devuelve la parte correspondiente a los minutos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora local.
Date
  
getMonth():Number
Devuelve el mes (0 para enero, 1 para febrero, etc.) de este objeto Date de acuerdo con la hora local.
Date
  
getSeconds():Number
Devuelve la parte correspondiente a los segundos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora local.
Date
  
getTime():Number
Devuelve el número de milisegundos desde la media noche del 1 de enero de 1970, hora universal, para un objeto Date.
Date
  
getTimezoneOffset():Number
Devuelve la diferencia, en minutos, entre la hora local del equipo y la hora universal (UTC).
Date
  
getUTCDate():Number
Devuelve el día del mes (un entero del 1 al 31) de un objeto Date de acuerdo con la hora universal (UTC).
Date
  
getUTCDay():Number
Devuelve el día de la semana (0 para domingo, 1 para lunes, etc.) de este objeto Date de acuerdo con la hora universal (UTC).
Date
  
getUTCFullYear():Number
Devuelve los cuatro dígitos del año de un objeto Date de acuerdo con la hora universal (UTC).
Date
  
getUTCHours():Number
Devuelve la hora (un entero del 0 al 23) del día de un objeto Date de acuerdo con la hora universal (UTC).
Date
  
getUTCMilliseconds():Number
Devuelve la parte correspondiente a los milisegundos (un entero del 0 al 999) de un objeto Date de acuerdo con la hora universal (UTC).
Date
  
getUTCMinutes():Number
Devuelve la parte correspondiente a los minutos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora universal (UTC).
Date
  
getUTCMonth():Number
Devuelve la parte correspondiente al mes (de 0 [enero] a 11 [diciembre]) de un objeto Date de acuerdo con la hora universal (UTC).
Date
  
getUTCSeconds():Number
Devuelve la parte correspondiente a los segundos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora universal (UTC).
Date
 Inherited
hasOwnProperty(name:String):Boolean
Indica si un objeto tiene definida una propiedad especificada.
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.
Object
  
parse(date:String):Number
[static] Convierte una cadena que representa una fecha en un número que indica el número de milisegundos transcurridos desde el 1 de enero de 1970, UTC.
Date
 Inherited
propertyIsEnumerable(name:String):Boolean
Indica si existe la propiedad especificada y si es enumerable.
Object
  
setDate(day:Number):Number
Establece el día del mes, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos.
Date
  
setFullYear(year:Number, month:Number, day:Number):Number
Establece el año, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos.
Date
  
setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
Establece la hora, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos.
Date
  
setMilliseconds(millisecond:Number):Number
Establece los milisegundos, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos.
Date
  
setMinutes(minute:Number, second:Number, millisecond:Number):Number
Establece los minutos, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos.
Date
  
setMonth(month:Number, day:Number):Number
Establece el mes y, opcionalmente, el día del mes, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos.
Date
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.
Object
  
setSeconds(second:Number, millisecond:Number):Number
Establece los segundos, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos.
Date
  
setTime(millisecond:Number):Number
Establece la fecha en milisegundos desde la media noche del 1 de enero de 1970 y devuelve la nueva hora en milisegundos.
Date
  
setUTCDate(day:Number):Number
Establece el día del mes, en la hora universal (UTC), y devuelve la nueva hora en milisegundos.
Date
  
setUTCFullYear(year:Number, month:Number, day:Number):Number
Establece el año, en la hora universal (UTC), y devuelve la nueva hora en milisegundos.
Date
  
setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
Establece la hora, en la hora universal (UTC), y devuelve la nueva hora en milisegundos.
Date
  
setUTCMilliseconds(millisecond:Number):Number
Establece los milisegundos, en la hora universal (UTC), y devuelve la nueva hora en milisegundos.
Date
  
setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number
Establece los minutos, en la hora universal (UTC), y devuelve la nueva hora en milisegundos.
Date
  
setUTCMonth(month:Number, day:Number):Number
Establece el mes y, opcionalmente, el día, en la hora universal (UTC) y devuelve la nueva hora en milisegundos.
Date
  
setUTCSeconds(second:Number, millisecond:Number):Number
Establece los segundos y, opcionalmente, los milisegundos, en la hora universal (UTC) y devuelve la nueva hora en milisegundos.
Date
  
toDateString():String
Devuelve una representación de cadena del día y la fecha solamente y no incluye la hora ni la zona horaria.
Date
  
toLocaleDateString():String
Devuelve una representación de cadena del día y la fecha solamente y no incluye la hora ni la zona horaria.
Date
  
toLocaleString():String
Devuelve una representación de cadena del día, la fecha y la hora expresados en la hora local.
Date
  
toLocaleTimeString():String
Devuelve una representación de cadena (String) de la hora solamente, sin incluir el día, la fecha o la zona horaria.
Date
  
toString():String
Devuelve una representación de cadena (String) del día, la fecha, la hora y la zona horaria.
Date
  
toTimeString():String
Devuelve una representación de cadena de la hora y la zona horaria solamente y no incluye el día ni la fecha.
Date
  
toUTCString():String
Devuelve una representación de cadena (String) del día, la fecha y la hora expresados en la hora universal (UTC).
Date
  
UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number
[static] Devuelve el número de milisegundos entre la media noche del 1 de enero de 1970, hora universal, y la hora especificada en los parámetros.
Date
  
valueOf():Number
Devuelve el número de milisegundos desde la media noche del 1 de enero de 1970, hora universal, para un objeto Date.
Date
Información sobre propiedades
datepropiedad
date:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

El día del mes (un entero del 1 al 31) especificado por un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.


Implementación
    AS3 function get date():Number
    AS3 function set date(value:Number):void

Véase también

getDate()
setDate()
Administración de fechas de calendario y horas
dateUTCpropiedad 
dateUTC:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

El día del mes (un entero del 1 al 31) de un objeto Date de acuerdo con la hora universal (UTC).


Implementación
    AS3 function get dateUTC():Number
    AS3 function set dateUTC(value:Number):void

Véase también

getUTCDate()
setUTCDate()
daypropiedad 
day:Number  [read-only]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

El día de la semana (0 para domingo, 1 para lunes, etc.) especificado por este objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.


Implementación
    AS3 function get day():Number

Véase también

getDay()
Administración de fechas de calendario y horas
dayUTCpropiedad 
dayUTC:Number  [read-only]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

El día de la semana (0 para domingo, 1 para lunes, etc.) de este objeto Date de acuerdo con la hora universal (UTC).


Implementación
    AS3 function get dayUTC():Number

Véase también

getUTCDay()
fullYearpropiedad 
fullYear:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

El año completo (un número de cuatro dígitos como, por ejemplo, 2000) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.


Implementación
    AS3 function get fullYear():Number
    AS3 function set fullYear(value:Number):void

Véase también

getFullYear()
setFullYear()
Administración de fechas de calendario y horas
fullYearUTCpropiedad 
fullYearUTC:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Los cuatro dígitos del año de un objeto Date de acuerdo con la hora universal (UTC).


Implementación
    AS3 function get fullYearUTC():Number
    AS3 function set fullYearUTC(value:Number):void

Véase también

getUTCFullYear()
setUTCFullYear()
hourspropiedad 
hours:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La hora (un entero del 0 al 23) de la parte correspondiente al día de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.


Implementación
    AS3 function get hours():Number
    AS3 function set hours(value:Number):void

Véase también

getHours()
setHours()
Administración de fechas de calendario y horas
hoursUTCpropiedad 
hoursUTC:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La hora (un entero del 0 al 23) del día de un objeto Date de acuerdo con la hora universal (UTC).


Implementación
    AS3 function get hoursUTC():Number
    AS3 function set hoursUTC(value:Number):void

Véase también

getUTCHours()
setUTCHours()
millisecondspropiedad 
milliseconds:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La parte correspondiente a los milisegundos (un entero del 0 al 999) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.


Implementación
    AS3 function get milliseconds():Number
    AS3 function set milliseconds(value:Number):void

Véase también

getMilliseconds()
setMilliseconds()
Administración de fechas de calendario y horas
millisecondsUTCpropiedad 
millisecondsUTC:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La parte correspondiente a los milisegundos (un entero del 0 al 999) de un objeto Date de acuerdo con la hora universal (UTC).


Implementación
    AS3 function get millisecondsUTC():Number
    AS3 function set millisecondsUTC(value:Number):void

Véase también

getUTCMilliseconds()
setUTCMilliseconds()
minutespropiedad 
minutes:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La parte correspondiente a los minutos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.


Implementación
    AS3 function get minutes():Number
    AS3 function set minutes(value:Number):void

Véase también

getMinutes()
setMinutes()
Administración de fechas de calendario y horas
minutesUTCpropiedad 
minutesUTC:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La parte correspondiente a los minutos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora universal (UTC).


Implementación
    AS3 function get minutesUTC():Number
    AS3 function set minutesUTC(value:Number):void

Véase también

getUTCMinutes()
setUTCMinutes()
monthpropiedad 
month:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La parte correspondiente al mes (0 para enero, 1 para febrero, etc.) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.


Implementación
    AS3 function get month():Number
    AS3 function set month(value:Number):void

Véase también

getMonth()
setMonth()
Administración de fechas de calendario y horas
monthUTCpropiedad 
monthUTC:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La parte correspondiente al mes (de 0 [enero] a 11 [diciembre]) de un objeto Date de acuerdo con la hora universal (UTC).


Implementación
    AS3 function get monthUTC():Number
    AS3 function set monthUTC(value:Number):void

Véase también

getUTCMonth()
setUTCMonth()
secondspropiedad 
seconds:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La parte correspondiente a los segundos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.


Implementación
    AS3 function get seconds():Number
    AS3 function set seconds(value:Number):void

Véase también

getSeconds()
setSeconds()
Administración de fechas de calendario y horas
secondsUTCpropiedad 
secondsUTC:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La parte correspondiente a los segundos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora universal (UTC).


Implementación
    AS3 function get secondsUTC():Number
    AS3 function set secondsUTC(value:Number):void

Véase también

getUTCSeconds()
setUTCSeconds()
timepropiedad 
time:Number  [read-write]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

El número de milisegundos desde la media noche del 1 de enero de 1970, hora universal, para un objeto Date. Utilice este método para representar un instante concreto en el tiempo al comparar dos o más objetos Date.


Implementación
    AS3 function get time():Number
    AS3 function set time(value:Number):void

Véase también

getTime()
setTime()
timezoneOffsetpropiedad 
timezoneOffset:Number  [read-only]

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La diferencia, en minutos, entre la hora local del equipo y la hora universal (UTC). Concretamente, este valor representa los minutos que se deben añadir a la hora local del equipo para que equivalgan a UTC. Si la hora del equipo es posterior a la hora UTC, el valor será negativo.


Implementación
    AS3 function get timezoneOffset():Number

Véase también

getTimezoneOffset()
Información sobre constructores
Date()constructor
public function Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Construye un nuevo objeto Date que contiene la fecha y la hora especificadas.

El constructor Date() toma hasta siete parámetros (year, month,..., millisecond) para especificar una fecha y una hora en milisegundos. La fecha que contiene el objeto Date recién construido depende del número y el tipo de datos de los argumentos pasados.

Si pasa una cadena al constructor de la clase Date, la fecha puede tener diversos formatos, pero debe incluir al menos el mes, el día del mes y el año. Por ejemplo, Feb 1 2005 es válido, mientras que Feb 2005 no lo es. En la siguiente lista se indican algunos de los formatos válidos:

Parámetros
yearOrTimevalue:Object — Si se especifican otros parámetros, este número representa un año (por ejemplo, 1965); en caso contrario, representa un valor de hora. Si el número representa un año, un valor de 0 a 99 indica de 1900 a 1999; en caso contrario deben especificarse los cuatro dígitos del año. Si el número representa un valor de hora (no se especifican otros parámetros), es el número de milisegundos antes o después de las 0:00:00 GMT del 1 de enero de 1970; un valor negativo representa una hora anterior a las 0:00:00 GMT del 1 de enero de 1970, y un valor positivo representa una hora posterior.
 
month:Number — Un entero de 0 (enero) a 11 (diciembre).
 
date:Number (default = 1) — Entero de 1 a 31.
 
hour:Number (default = 0) — Entero de 0 (medianoche) a 23 (11 de la noche).
 
minute:Number (default = 0) — Entero de 1 a 59.
 
second:Number (default = 0) — Entero de 1 a 59.
 
millisecond:Number (default = 0) — Entero de 0 a 999 milisegundos.

Véase también

getMonth()
getDate()
getFullYear()
Administración de fechas de calendario y horas
Información sobre métodos
getDate()método
AS3 function getDate():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el día del mes (un entero del 1 al 31) especificado por un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Valor devuelto
Number — El día del mes (1 - 31) que representa un objeto Date.

Véase también

getMonth()
getFullYear()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama al método getDate(), que recupera el día del mes. 
package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}
getDay()método 
AS3 function getDay():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el día de la semana (0 para domingo, 1 para lunes, etc.) especificado por este objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Valor devuelto
Number — Versión numérica del día de la semana (0 - 6) que representa un objeto Date.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Array weekDayLabels con los elementos [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] y un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). A continuación, se llama al método getDay() dos veces. Primero muestra el día del mes como 6 y, a continuación, muestra el día de la semana utilizando weekDayLabels. 

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday
getFullYear()método 
AS3 function getFullYear():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el año completo (un número de cuatro dígitos como, por ejemplo, 2000) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Valor devuelto
Number — El año completo que representa un objeto Date.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). A continuación, se llama al método getFullYear(), que recupera el año con cuatro dígitos. 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974
getHours()método 
AS3 function getHours():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la hora (un entero del 0 al 23) de la parte correspondiente al día de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Valor devuelto
Number — La hora (0 -23) del día que representa un objeto Date.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama a los métodos getHours() y getMinutes(), que recuperan las horas y los minutos en formato de 24 horas. Por último, se crea una cadena localTime y se asigna al resultado de la llamada a la función getUSClockTime() que, a su vez, vuelve a llamar a getHours() y getMinutes(), con lo que se obtiene la hora 03:05 PM. 

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getMilliseconds()método 
AS3 function getMilliseconds():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la parte correspondiente a los milisegundos (un entero del 0 al 999) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Valor devuelto
Number — La parte correspondiente a los milisegundos de un objeto Date.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Luego se llama al método getMilliseconds(), que recupera los milisegundos del objeto Date now en el momento en que se creó. 

var now:Date = new Date();
trace(now.getMilliseconds());
getMinutes()método 
AS3 function getMinutes():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la parte correspondiente a los minutos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Valor devuelto
Number — La parte correspondiente a los minutos de un objeto Date.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Luego se llama al método getMinutes(), que recupera los minutos del objeto Date now en el momento en que se creó. 

var now:Date = new Date();
trace(now);
trace(now.getMinutes());
getMonth()método 
AS3 function getMonth():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el mes (0 para enero, 1 para febrero, etc.) de este objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Valor devuelto
Number — La parte correspondiente al mes (0 - 11) de un objeto Date.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Array monthLabels con elementos de January a December y un nuevo objeto Date now sin parámetros. A continuación, se llama al método getMonth() dos veces. La primera devuelve el número del mes y la segunda el nombre del mes en el que se creó el objeto Date now. 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);
getSeconds()método 
AS3 function getSeconds():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la parte correspondiente a los segundos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Valor devuelto
Number — La parte correspondiente a los segundos (de 0 a 59) de un objeto Date.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Luego se llama al método getSeconds(), que recupera los segundos del objeto Date now en el momento en que se creó. 

var now:Date = new Date();
trace(now.getSeconds());
getTime()método 
AS3 function getTime():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el número de milisegundos desde la media noche del 1 de enero de 1970, hora universal, para un objeto Date. Utilice este método para representar un instante concreto en el tiempo al comparar dos o más objetos Date.

Nota: el método getTime() incorpora años bisiestos por lo que los cálculos aritméticos no necesitan una lógica adicional para los cambios en los años bisiestos.

Valor devuelto
Number — El número de milisegundos desde el 1 de enero de 1970 que representa un objeto Date.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date mlk con los parámetros year (1929), month (0 = January) y day (15). Luego se llama al método getTime(), que recupera los milisegundos transcurridos desde la medianoche del 1 de enero de 1970 (valor negativo, ya que el año está definido como 1929). 

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros y, después, utiliza los métodos siguientes de la clase DateMath (creada a continuación) para añadir la hora al objeto Date now original a partir de la hora en que se creó:
  • addSeconds(): añade 30 segundos a now.
  • addMinutes(): añade 30 minutos a now.
  • addHours(): añade 6 horas al objeto Date now.
  • addDays(): añade 30 días al objeto Date now.
  • addWeeks(): añade 4 semanas a now.

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}
getTimezoneOffset()método 
AS3 function getTimezoneOffset():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la diferencia, en minutos, entre la hora local del equipo y la hora universal (UTC).

Valor devuelto
Number — Los minutos que se deben añadir al valor de hora local del equipo para que equivalgan a UTC. Si la hora del equipo es posterior a la hora UTC, el valor devuelto será negativo.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Se llama al método getTimezoneOffset(), que recupera la diferencia (en minutos) de la hora en que se creó now y la hora universal. La diferencia de la zona horaria se convierte a horas dividiendo el resultado entre 60. 

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);
getUTCDate()método 
AS3 function getUTCDate():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el día del mes (un entero del 1 al 31) de un objeto Date de acuerdo con la hora universal (UTC).

Valor devuelto
Number — El día UTC del mes (del 1 al 31) que representa un objeto Date.

Véase también

getDate()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama al método getUTCDate(), que recupera el día del mes, según la hora UTC. 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30
getUTCDay()método 
AS3 function getUTCDay():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el día de la semana (0 para domingo, 1 para lunes, etc.) de este objeto Date de acuerdo con la hora universal (UTC).

Valor devuelto
Number — El día UTC de la semana (del 0 al 6) que representa un objeto Date.

Véase también

getDay()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Array weekDayLabels con los elementos [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] y un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). A continuación, se llama al método getUTCDay() dos veces. Primero muestra el día del mes como 6 y después muestra el día de la semana utilizando weekDayLabels, según la hora UTC. 

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday
getUTCFullYear()método 
AS3 function getUTCFullYear():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve los cuatro dígitos del año de un objeto Date de acuerdo con la hora universal (UTC).

Valor devuelto
Number — El año UTC en cuatro dígitos que representa un objeto Date.

Véase también

getFullYear()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama al método getUTCFullYear(), que recupera el año con cuatro dígitos, según la hora UTC. 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974
getUTCHours()método 
AS3 function getUTCHours():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la hora (un entero del 0 al 23) del día de un objeto Date de acuerdo con la hora universal (UTC).

Valor devuelto
Number — La hora UTC del día (de 0 a 23) que representa un objeto Date.

Véase también

getHours()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama a los métodos getHours() y getMinutes(), que recuperan las horas y los minutos en formato de 24 horas. Por último, se crea una cadena localTime y se asigna al resultado de la llamada a la función getUSClockTime() que, a su vez, vuelve a llamar a getHours() y getMinutes(), con lo que se obtiene la hora 03:05 PM. Por último, se crea una variable String utcTime del mismo modo que localTime y, en este caso, el resultado es el mismo 

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getUTCMilliseconds()método 
AS3 function getUTCMilliseconds():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la parte correspondiente a los milisegundos (un entero del 0 al 999) de un objeto Date de acuerdo con la hora universal (UTC).

Valor devuelto
Number — La parte correspondiente a los milisegundos UTC de un objeto Date.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Luego se llama al método getUTCMilliseconds(), que recupera los milisegundos del objeto Date now en el momento en que se creó, según la hora UTC 

var now:Date = new Date();
trace(now.getUTCMilliseconds());
getUTCMinutes()método 
AS3 function getUTCMinutes():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la parte correspondiente a los minutos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora universal (UTC).

Valor devuelto
Number — La parte correspondiente a los minutos UTC de un objeto Date.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Luego se llama al método getUTCMinutes(), que recupera los minutos del objeto Date now en el momento en que se creó, según la hora UTC 

var now:Date = new Date();
trace(now.getUTCMinutes());
getUTCMonth()método 
AS3 function getUTCMonth():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la parte correspondiente al mes (de 0 [enero] a 11 [diciembre]) de un objeto Date de acuerdo con la hora universal (UTC).

Valor devuelto
Number — La parte correspondiente al mes UTC de un objeto Date.

Véase también

getMonth()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Array monthLabels con elementos de January a December y un nuevo objeto Date now sin parámetros. Luego se llama al método getUTCMonth() dos veces. La primera devuelve el número del mes y la segunda, el nombre del mes en el que se creó el objeto Date now, según la hora UTC 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);
getUTCSeconds()método 
AS3 function getUTCSeconds():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve la parte correspondiente a los segundos (un entero del 0 al 59) de un objeto Date de acuerdo con la hora universal (UTC).

Valor devuelto
Number — La parte correspondiente a los segundos UTC de un objeto Date.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Luego se llama al método getUTCSeconds(), que recupera los segundos del objeto Date now en el momento en que se creó, según la hora UTC 

var now:Date = new Date();
trace(now.getUTCSeconds());
parse()método 
public static function parse(date:String):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Convierte una cadena que representa una fecha en un número que indica el número de milisegundos transcurridos desde el 1 de enero de 1970, UTC.

Parámetros

date:String — Una representación de cadena de una fecha que sigue el formato de la salida de Date.toString(). El formato de fecha para la salida de Date.toString() es: 
     Día Mes DD HH:MM:SS TZD AAAA

Por ejemplo: 

     Miércoles Abril 12 15:30:17 GMT-0700 2006

La designación de zona horaria (TZD) siempre tiene el formato GMT-HHMM o UTC-HHMM, que indica el desplazamiento de horas y minutos con respecto a la hora del meridiano de Greenwich (GMT), también conocida como hora universal (UTC). Los términos de año, mes y día pueden ir separados por una barra diagonal (/) o por espacios, pero nunca por un guión -). Otros formatos admitidos son los siguientes (puede incluir representaciones parciales de estos formatos; es decir, sólo el mes, el día y el año):

     MM/DD/AAAA HH:MM:SS TZD HH:MM:SS TZD Día Mes/DD/AAAA Mes DD AAAA HH:MM:SS TZD Día Mes DD HH:MM:SS TZD AAAA Día DD Mes HH:MM:SS TZD AAAA Mes/DD/AAAA HH:MM:SS TZD AAAA/MM/DD HH:MM:SS TZD

Valor devuelto
Number — Un número que representa los milisegundos transcurridos desde el 1 de enero de 1970, UTC.

Véase también

Date.toString()

Ejemplo

El siguiente ejemplo asigna una cadena de fecha a dateParsed para el 30 de noviembre de 1974. Se llama al método Date.parse(), que convierte la fecha en milisegundos desde el 1 de enero de 1970. 
var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000
setDate()método 
AS3 function setDate(day:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece el día del mes, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Parámetros

day:Number — Entero de 1 a 31.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama al método getDate(), que recupera el día del mes. Posteriormente, se llama a setDate() con el parámetro day definido como 20. Después, se vuelve a llamar a getDate(), que recupera el nuevo día del mes definido. 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20
setFullYear()método 
AS3 function setFullYear(year:Number, month:Number, day:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece el año, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos. Si se especifican los parámetros month y day, éstos se establecen con la hora local. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

La llamada a este método no modifica los demás campos de Date, aunque Date.getUTCDay() y Date.getDay() pueden indicar un nuevo valor si cambia el día de la semana como resultado de la llamada a este método.

Parámetros

year:Number — Número de cuatro dígitos que especifica un año. Los números de dos dígitos no representan años de cuatro dígitos; por ejemplo, 99 no es el año 1999, sino el año 99.
 
month:Number — Un entero de 0 (enero) a 11 (diciembre).
 
day:Number — Un número entre 1 y 31.

Valor devuelto
Number — La nueva hora en milisegundos.

Véase también

getUTCDay()
getDay()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama al método getFullYear(), que recupera el año con cuatro dígitos. Posteriormente, se llama a setFullYear() con el parámetro year definido como 2000. Después, se vuelve a llamar a getFullYear(), que recupera el nuevo año definido. 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000
setHours()método 
AS3 function setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece la hora, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Parámetros

hour:Number — Entero de 0 (medianoche) a 23 (11 de la noche).
 
minute:Number — Entero de 1 a 59.
 
second:Number — Entero de 1 a 59.
 
millisecond:Number — Entero de 1 a 999.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama a los métodos getHours() y getMinutes(), que recuperan las horas y los minutos. Posteriormente, se llama a setHours() con el parámetro hour definido como 12. Después, se vuelve a llamar a getHours() y a getMinutes(), que recupera las nuevas horas y minutos definidos. 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20
setMilliseconds()método 
AS3 function setMilliseconds(millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece los milisegundos, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Parámetros

millisecond:Number — Entero de 1 a 999.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Se llama al método getMilliseconds(), que recupera los milisegundos en el momento de la creación de now. Posteriormente, se vuelve a llamar a otro nuevo objeto Date before mediante una llamada a setMilliseconds() con el parámetro millisecond definido como 4 y se vuelve a llamar a getMilliseconds(), que recupera los nuevos milisegundos definidos. 

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());
setMinutes()método 
AS3 function setMinutes(minute:Number, second:Number, millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece los minutos, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Parámetros

minute:Number — Entero de 1 a 59.
 
second:Number — Entero de 1 a 59.
 
millisecond:Number — Entero de 1 a 999.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Se llama al método getMinutes(), que recupera los minutos en el momento de la creación de now. Posteriormente, se vuelve a llamar a otro nuevo objeto Date before mediante una llamada a setMinutes() con el parámetro minute definido como 0 y se vuelve a llamar a getMinutes(), que recupera los nuevos minutos definidos. 

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());
setMonth()método 
AS3 function setMonth(month:Number, day:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece el mes y, opcionalmente, el día del mes, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Parámetros

month:Number — Un entero de 0 (enero) a 11 (diciembre).
 
day:Number — Entero de 1 a 31.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Array monthLabels con elementos de January a December y un nuevo objeto now sin parámetros. Se llama al método getMonth(), que recupera el mes en que se creó now. Posteriormente, se llama a setMonth() con el parámetro month definido como 0. Después, se vuelve a llamar a getMonth(), que recupera el nuevo mes definido. 

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January
setSeconds()método 
AS3 function setSeconds(second:Number, millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece los segundos, de acuerdo con la hora local, y devuelve la nueva hora en milisegundos. La hora local la determina el sistema operativo en el que se ejecuta Flash Player.

Parámetros

second:Number — Entero de 1 a 59.
 
millisecond:Number — Entero de 1 a 999.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Se llama al método getseconds(), que recupera los segundos en el momento de la creación de now. Posteriormente, se llama a setSeconds() con el parámetro second definido como 0. Después, se vuelve a llamar a getSeconds(), que recupera los nuevos segundos definidos. 

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0
setTime()método 
AS3 function setTime(millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece la fecha en milisegundos desde la media noche del 1 de enero de 1970 y devuelve la nueva hora en milisegundos.

Parámetros

millisecond:Number — Un valor de entero, donde 0 es la medianoche del 1 de enero, hora universal (UTC).

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Se llama al método setTime(), con el parámetro millisecond definido como -1292601600000, que define la hora en Tue Jan 15 00:00:00 GMT-0800 1929. 

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929
setUTCDate()método 
AS3 function setUTCDate(day:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece el día del mes, en la hora universal (UTC), y devuelve la nueva hora en milisegundos. La llamada a este método no modifica los demás campos de un objeto Date , aunque los métodos Date.getUTCDay() y Date.getDay() pueden indicar un nuevo valor si cambia el día de la semana como resultado de la llamada a este método.

Parámetros

day:Number — Un número; un entero de 1 a 31.

Valor devuelto
Number — La nueva hora en milisegundos.

Véase también

getUTCDay()
getDay()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Se llama al método getUTCDate() y se devuelve correctamente el día del mes. Después, se llama a setUTCDate() con el parámetro day definido como 1 y una sentencia trace() confirma que la fecha se ha definido correctamente. 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974
setUTCFullYear()método 
AS3 function setUTCFullYear(year:Number, month:Number, day:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece el año, en la hora universal (UTC), y devuelve la nueva hora en milisegundos.

Opcionalmente, este método también puede establecer el mes y el día del mes. La llamada a este método no modifica los demás campos, aunque los métodos Date.getUTCDay() y Date.getDay() pueden indicar un nuevo valor si cambia el día de la semana como resultado de la llamada a este método.

Parámetros

year:Number — Un entero que representa el año especificado como año completo de cuatro dígitos como, por ejemplo, 2000.
 
month:Number — Un entero de 0 (enero) a 11 (diciembre).
 
day:Number — Entero de 1 a 31.

Valor devuelto
Number — Un entero.

Véase también

getUTCDay()
getDay()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). Luego se llama al método getUTCFullYear(), que devuelve correctamente el año con cuatro dígitos. Después, se llama a setUTCFullYear() con el parámetro year definido como 1975 y una sentencia trace() confirma que el año se ha definido correctamente. 

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975
setUTCHours()método 
AS3 function setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece la hora, en la hora universal (UTC), y devuelve la nueva hora en milisegundos. Opcionalmente, pueden especificarse los minutos, segundos y milisegundos.

Parámetros

hour:Number — Entero de 0 (medianoche) a 23 (11 de la noche).
 
minute:Number — Entero de 1 a 59.
 
second:Number — Entero de 1 a 59.
 
millisecond:Number — Entero de 1 a 999.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20). A continuación, se llama a los métodos getHours(), getMinutes(), getUTCHours() y getUTCMinutes(), que recuperan las horas y los minutos. Después, se llama a setUTCHours() con el parámetro hour definido como 12 y se vuelve a llamar a los métodos getHours(), getMinutes(), getUTCHours() y getUTCMinutes(), que muestran la hora actualizada correctamente. 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20
setUTCMilliseconds()método 
AS3 function setUTCMilliseconds(millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece los milisegundos, en la hora universal (UTC), y devuelve la nueva hora en milisegundos.

Parámetros

millisecond:Number — Entero de 1 a 999.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Se llama al método getUTCMilliseconds(), que recupera los milisegundos de la hora UTC en el momento de la creación de now. Posteriormente, se vuelve a llamar a otro nuevo objeto Date before mediante una llamada a setUTCMilliseconds() con el parámetro millisecond definido como 4 y se vuelve a llamar a getUTCMilliseconds(), que recupera los nuevos milisegundos definidos. 


var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());
setUTCMinutes()método 
AS3 function setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece los minutos, en la hora universal (UTC), y devuelve la nueva hora en milisegundos. Opcionalmente, puede especificar los segundos y milisegundos.

Parámetros

minute:Number — Entero de 1 a 59.
 
second:Number — Entero de 1 a 59.
 
millisecond:Number — Entero de 1 a 999.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Se llama al método getUTCMinutes(), que recupera los minutos de la hora UTC en el momento de la creación de now. Posteriormente, se vuelve a llamar a otro nuevo objeto Date before mediante una llamada a setUTCMinutes() con el parámetro minute definido como 0 y se vuelve a llamar a getUTCMinutes(), que recupera los nuevos minutos definidos. 

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());
setUTCMonth()método 
AS3 function setUTCMonth(month:Number, day:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece el mes y, opcionalmente, el día, en la hora universal (UTC) y devuelve la nueva hora en milisegundos. La llamada a este método no modifica los demás campos, aunque los métodos Date.getUTCDay() y Date.getDay() pueden indicar un nuevo valor si cambia el día de la semana como resultado de la llamada a este método.

Parámetros

month:Number — Un entero de 0 (enero) a 11 (diciembre).
 
day:Number — Entero de 1 a 31.

Valor devuelto
Number — La nueva hora en milisegundos.

Véase también

getDay()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Array UTCMonthLabels con elementos de January a December y un nuevo objeto UTCMonth now sin parámetros. Se llama al método getUTCMonth(), que recupera el mes de la hora UTCMonth en que se creó now. Posteriormente, se llama a setUTCMonth() con el parámetro month definido como 0. A continuación, se vuelve a llamar a getUTCMonth(), que recupera el nuevo mes definido. 

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January
setUTCSeconds()método 
AS3 function setUTCSeconds(second:Number, millisecond:Number):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Establece los segundos y, opcionalmente, los milisegundos, en la hora universal (UTC) y devuelve la nueva hora en milisegundos.

Parámetros

second:Number — Entero de 1 a 59.
 
millisecond:Number — Entero de 1 a 999.

Valor devuelto
Number — La nueva hora en milisegundos.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros. Se llama al método getUTCSeconds(), que recupera los segundos en el momento de la creación de now. Posteriormente, se llama a setUTCSeconds() con el parámetro second definido como 0. Después, se vuelve a llamar a getUTCSeconds(), que recupera los nuevos segundos definidos. 

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0
toDateString()método 
AS3 function toDateString():String

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve una representación de cadena del día y la fecha solamente y no incluye la hora ni la zona horaria. Compárelo con los siguientes métodos:

Valor devuelto
String — La representación de cadena del día y la fecha solamente.

Véase también

toString()

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date now sin parámetros y después se llama a los siguientes métodos dentro de una sentencia trace().
  • toString: muestra todos los parámetros de now en el momento en que se creó now.
  • toDateString(): muestra los parámetros day, month y year del momento en que se creó now.

var now:Date = new Date();
trace(now);
trace(now.toDateString());
toLocaleDateString()método 
AS3 function toLocaleDateString():String

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve una representación de cadena del día y la fecha solamente y no incluye la hora ni la zona horaria. Este método devuelve el mismo valor que Date.toDateString. Compárelo con los siguientes métodos:

Valor devuelto
String — La representación de cadena String del día y la fecha solamente.

Véase también

toDateString()
toTimeString()
toString()
toLocaleString()método 
AS3 function toLocaleString():String

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve una representación de cadena del día, la fecha y la hora expresados en la hora local. Compárelo con el método Date.toString(), que devuelve la misma información (más la zona horaria) con el año al final de la cadena.

Valor devuelto
String — Una representación de cadena de un objeto Date en la zona horaria local.
toLocaleTimeString()método 
AS3 function toLocaleTimeString():String

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve una representación de cadena (String) de la hora solamente, sin incluir el día, la fecha o la zona horaria. Compárelo con el método Date.toTimeString(), que devuelve la hora y la zona horaria.

Valor devuelto
String — La representación de cadena de la hora y la zona horaria solamente.

Véase también

toTimeString()
toString()método 
AS3 function toString():String

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve una representación de cadena (String) del día, la fecha, la hora y la zona horaria. El formato de fecha para la salida es: 

     Día Mes Fecha HH:MM:SS TZD AAAA

Por ejemplo:

     Miércoles Abril 12 15:30:17 GMT-0700 2006

Valor devuelto
String — La representación de cadena de un objeto Date.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros y se llama a toString dentro de una sentencia trace(), que muestra todos los parámetros now en el momento en que se creó now. 


var now:Date = new Date();
trace(now);
toTimeString()método 
AS3 function toTimeString():String

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve una representación de cadena de la hora y la zona horaria solamente y no incluye el día ni la fecha. Compárelo con el método Date.toDateString(), que sólo devuelve el día y la fecha.

Valor devuelto
String — La representación de cadena de la hora y la zona horaria solamente.

Véase también

toDateString()
toUTCString()método 
AS3 function toUTCString():String

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve una representación de cadena (String) del día, la fecha y la hora expresados en la hora universal (UTC). Por ejemplo, la fecha de 1 de febrero de 2005 se devuelve como Tue Feb 1 00:00:00 2005 UTC.

Valor devuelto
String — La representación de cadena de un objeto Date en la hora UTC.

Véase también

toString()
UTC()método 
public static function UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el número de milisegundos entre la media noche del 1 de enero de 1970, hora universal, y la hora especificada en los parámetros. Este método utiliza la hora universal, mientras que el constructor Date utiliza la hora local.

Este método es útil si desea pasar una fecha UTC al constructor de la clase Date. Dado que el constructor de la clase Date acepta el desplazamiento de milisegundos como argumento, puede utilizar el método Date.UTC() para convertir la fecha UTC en el desplazamiento de milisegundos correspondiente y enviar dicho desplazamiento como argumento al constructor de la clase Date:

Parámetros

year:Number — Un entero de cuatro dígitos que representa el año (por ejemplo, 2000).
 
month:Number — Un entero de 0 (enero) a 11 (diciembre).
 
date:Number (default = 1) — Entero de 1 a 31.
 
hour:Number (default = 0) — Entero de 0 (medianoche) a 23 (11 de la noche).
 
minute:Number (default = 0) — Entero de 1 a 59.
 
second:Number (default = 0) — Entero de 1 a 59.
 
millisecond:Number (default = 0) — Entero de 1 a 999.

Valor devuelto
Number — El número de milisegundos desde el 1 de enero de 1970 hasta la fecha y la hora especificadas.

Ejemplo

En el ejemplo siguiente, se crea un nuevo objeto Date someBirthday con los parámetros year (1974), month (10 = November), day (30), hour (1) y minute (20) con la hora local. A continuación, mediante una llamada a UTC() dentro del método setTime(), se calculan los mismos parámetros para la hora universal. 

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());
valueOf()método 
AS3 function valueOf():Number

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve el número de milisegundos desde la media noche del 1 de enero de 1970, hora universal, para un objeto Date.

Valor devuelto
Number — El número de milisegundos transcurridos desde el 1 de enero de 1970 que representa un objeto Date.

Ejemplo

El siguiente ejemplo crea un nuevo objeto Date now sin parámetros Se llama al método getTime(), que recupera el número de milisegundos entre la hora en que se creó now y la medianoche del 1 de enero de 1970. Posteriormente, se llama a valueOf(), que recupera lo mismo. 


var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());
Ejemplos Cómo utilizar los ejemplos
DateExample.as

Los ejemplos siguientes ilustran diversos usos del constructor Date() para asignar las siguientes variables: 

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }
    }
}



© 2004-2007 Adobe Systems Incorporated. Todos los derechos reservados.
Fri Oct 12 2007, 2:30 AM GMT-07:00

 

Enviarme un mensaje de correo electrónico cuando se añadan comentarios a esta página | Informe de comentarios

Página actual: http://livedocs.adobe.com/flash/9.0_es/ActionScriptLangRefV3/Date.html