Die Oberlänge des Texts ist die Länge von der Grundlinie bis zur Oberkante der Zeile in Pixel. Siehe "Oberlänge" im Übersichtsdiagramm für diese Klasse.

Siehe auch

Die Unterlänge des Texts ist die Länge von der Grundlinie bis zur Unterkante der Zeile in Pixel. Siehe "Unterlänge" im Übersichtsdiagramm für diese Klasse.

Siehe auch

Die Höhe des Texts in den ausgewählten Zeilen (nicht unbedingt des gesamten Texts) in Pixel. Die Höhe der Textzeile umfasst nicht die Höhe des Zwischenraums. Siehe "Zeilenhöhe" im Übersichtsdiagramm für diese Klasse.

Siehe auch

[Der Zeilenabstand ist der vertikale Abstand zwischen den Textzeilen. Siehe "Zeilenabstand" im Übersichtsdiagramm für diese Klasse.

Siehe auch

Der Wert für die Breite ist die Textbreite in den ausgewählten Zeilen (nicht unbedingt des gesamten Texts) in Pixel. Die Breite der Textzeile ist nicht identisch mit der Breite des Textfelds. Die Breite der Textzeile muss relativ zur Textfeldbreite gesehen werden (abzüglich des Zwischenraums von 4 Pixel, d. h. 2 Pixel auf jeder Seite). Siehe "Breite der Textzeile" im Übersichtsdiagramm für diese Klasse.

Siehe auch

Der x-Wert ist die linke Position des ersten Zeichens in Pixel. Dieser Wert umfasst den Rand, eventuelle Einzüge und den Zwischenraum. Siehe "x-Position der Textzeile" im Übersichtsdiagramm für diese Klasse.

Siehe auch

Erstellt ein TextLineMetrics-Objekt. Das TextLineMetrics-Objekt enthält Informationen zu den Maßen einer Textzeile innerhalb eines Textfelds. Objekte dieser Klasse werden von der Methode flash.text.TextField.getLineMetrics() zurückgegeben.

Kontextinformationen zu den verschiedenen Eigenschaften finden Sie im Übersichtsdiagramm für diese Klasse.

Siehe auch

1. Erstellen Sie die Eigenschaft label vom Typ "TextField".
2. Der Konstruktor ruft die Methode configureAssets() auf, die Folgendes durchführt:
   • Die Bühne wird oben links ausgerichtet und ohne Skalierung angezeigt.
   • Es wird das neue TextField-Objekt label erstellt.
   • Der Hintergrund von label wird aktiviert, und die Farbe wird auf weiß eingestellt.
   • Es wird festgelegt, dass sich der Text von label über mehrere Zeilen mit automatischem Zeilenumbruch erstrecken kann.
   • Das Ergebnis eines Aufrufs an getLabelText() wird der text-Eigenschaft von label zugewiesen. Mit der Methode getLabelText() wird eine Variable vom Typ XML erstellt und dem XML-Knoten body zugewiesen, der einen langen Satz enthält.
   • label wird der Anzeigeliste mithilfe von addChild() hinzugefügt.
3. Anschließend wird die Methode resizeHandler() hinzugefügt, die als Listener für resize-Ereignisse auf der Bühne fungiert. Bei jeder Größenänderung des Flash Player-Fensters wird ein RESIZE-Ereignis ausgelöst. Dies hat die folgenden Auswirkungen:
   • draw() wird aufgerufen, damit label in der Mitte der Bühne, umgeben von einem 10-Pixel-Puffer, angezeigt wird.
   • setTimeout() führt showMetrics() anschließend nach einer kurzen Verzögerung aus. Die Verzögerung wird dadurch verursacht, dass die Textzeilenmaße erst nach Abschluss des RESIZE-Ereignisses und nach der vollständigen Neuzeichnung der Bühne aktualisiert werden.
   • Mit showMetrics() wird die TextLineMetrics-Variable metrics dem Ergebnis eines Aufrufs von getLineMetrics() zugewiesen. Diese Variable wird anschließend an eine neue Instanz der LineMetricsReader-Instanz reader übergeben. Die beiden Variablen werden anschließend in Aufrufen von trace() zum Drucken der ersten (und einzigen) Zeile von label und Informationen aus der LineMetricsReader-Instanz (über die Methode toString()) verwendet.
4. Der Konstruktor erzwingt eine einmalige Auslösung resize-Ereignisses, damit label beim ersten Laden der SWF-Datei richtig gezeichnet wird.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.text.TextField;
    import flash.text.TextLineMetrics;
    import flash.utils.setTimeout;

    public class TextLineMetricsExample extends Sprite {
        private var gutter:int = 10;
        private var label:TextField;

        public function TextLineMetricsExample() {
            configureAssets();
            configureListeners();
            resizeHandler(new Event(Event.RESIZE));
        }

        private function showMetrics():void {
            var metrics:TextLineMetrics = label.getLineMetrics(0);
            var reader:LineMetricsReader = new LineMetricsReader(metrics);
            trace("lineText: " + label.getLineText(0));
            trace("metrics: " + reader);
        }

        private function configureAssets():void {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            label = new TextField();
            label.background = true;
            label.backgroundColor = 0xFFFFFF;
            label.multiline = true;
            label.wordWrap = true;
            label.text = getLabelText();
            addChild(label);
        }

        private function configureListeners():void {
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function resizeHandler(event:Event):void {
            draw();
            setTimeout(showMetrics, 100);
        }

        private function draw():void {
            label.x = gutter;
            label.y = gutter;
            label.width = stage.stageWidth - (gutter * 2);
            label.height = stage.stageHeight - (gutter * 2);
        }

        private function getLabelText():String {
            var text:XML = <body>The Flex product line enables developers to build rich Internet applications that blend the responsiveness of desktop software, the cross-platform reach of the web, and the expressiveness of the Flash Platform.</body>
            return text.toString();
        }
    }
}

import flash.text.TextLineMetrics;

class LineMetricsReader {
    private var metrics:TextLineMetrics;

    public function LineMetricsReader(metrics:TextLineMetrics) {
        this.metrics = metrics;
    }

    public function toString():String {
        return "[TextLineMetrics ascent:" + metrics.ascent
            + ", descent:" + metrics.descent
            + ", leading:" + metrics.leading
            + ", width:" + metrics.width
            + ", height:" + metrics.height
            + ", x:" + metrics.x
            + "]";
    }
}