Sucht nach einer Klasse, für die mit dem Aufruf der Methode registerClassAlias() ein Alias registriert wurde.

Es erfolgt keine Interaktion zwischen dieser Methode und der Methode flash.utils.getDefinitionByName().

Parameter

Siehe auch

Öffnet oder ersetzt ein Fenster in der Anwendung mit dem Flash Player-Container (in der Regel ein Browser).

Hinweis: Für lokalen in einem Browser ausgeführten Inhalt sind Aufrufe der Funktion navigateToURL(), die ein "javascript:"- Pseudo-Protokoll (z. B. navigateToURL("javascript:someFunction()") angeben, nur dann zulässig, wenn sich die SWF-Datei und die Webseite, in die sie eingebettet ist, (falls vorhanden) in der lokalen vertrauenswürdigen Sicherheits-Sandbox befinden. Weitere Informationen finden Sie in den folgenden Abschnitten:

• Das Kapitel Sicherheit im Handbuch Programmieren mit ActionScript 3.0 und die neusten Kommentare zu den LiveDocs.
• Das Flash Player 9-Whitepaper zum Thema Sicherheit

Parameter

Siehe auch

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class NavigateToURLExample extends Sprite {

        public function NavigateToURLExample() {
            var url:String = "http://www.adobe.com";
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "Your Name";
            var request:URLRequest = new URLRequest(url);
            request.data = variables;
            try {            
                navigateToURL(request);
            }
            catch (e:Error) {
                // handle error here
            }
        }
    }
}

Behält die Klasse (den Typ) eines Objekts bei, wenn dieses in Action Message Format (AMF) codiert wird. Bei der Codierung eines Objekts in AMF speichert diese Funktion einen Alias für die Klasse des Objekts, sodass Sie die Klasse wiederherstellen können, wenn Sie das Objekt decodieren. Wenn im Kontext der Codierung kein Alias für eine Objektklasse registriert wird, erfolgt die Codierung des Objekts als anonymes Objekt. Wenn im Kontext der Decodierung nicht derselbe Alias registriert ist, wird für die decodierten Daten ein anonymes Objekt erstellt.

LocalConnection, ByteArray, SharedObject, NetConnection und NetStream sind Beispiele für Klassen, die Objekte in AMF codieren.

Für den Codierungs- und Decodierungs-Kontext muss nicht dieselbe Klasse für einen Alias verwendet werden. Die Klassen können geändert werden, vorausgesetzt, dass die Zielklasse alle Mitglieder enthält, die von der Quellklasse serialisiert werden.

Parameter

Siehe auch

package {
    import flash.display.Sprite;
    import flash.net.registerClassAlias;
    import flash.utils.ByteArray;

    public class RegisterClassAliasExample extends Sprite {
        public function RegisterClassAliasExample() {
            registerClassAlias("com.example.eg", ExampleClass);
            var eg1:ExampleClass = new ExampleClass();
            var ba:ByteArray = new ByteArray();
            ba.writeObject(eg1);
            ba.position = 0;
            var eg2:* = ba.readObject();
            trace(eg2 is ExampleClass); // true
        }
    }
}

class ExampleClass {}

Sendet eine URL-Anforderung an einen Server, Antworten werden jedoch ignoriert.

Verwenden Sie die MethodeURLLoader.load(), wenn die Serverantwort überprüft werden soll.

Ab der Version Flash Player 9 können Sie eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie in der HTML-Seite, die den SWF-Inhalt beinhaltet, den Parameter allowNetworking der Tags object und embed festlegen.

Weitere Informationen finden Sie im Flash Player 9-Whitepaper zum Thema Sicherheit unter http://www.adobe.com/go/fp9_0_security_de.

Parameter

Siehe auch

 package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.net.URLVariables;
    import flash.net.sendToURL;

    public class SendToURLExample extends Sprite {

        public function SendToURLExample() {
            var url:String = "http://www.yourDomain.com/application.jsp";
            var variables:URLVariables = new URLVariables();
            variables.sessionId = new Date().getTime();
            variables.userLabel = "Your Name";

            var request:URLRequest = new URLRequest(url);
            request.data = variables;
            trace("sendToURL: " + request.url + "?" + request.data);
            try {
                sendToURL(request);
            }
            catch (e:Error) {
                // handle error here
            }
        }
    }
}