Der MIME-Inhaltstyp der POST-Daten.

Hinweis: Der Parameter URLRequest.contentType wird von den Methoden FileReference.upload() und FileReference.download() nicht unterstützt.

Ein Objekt, das mit der URL-Anforderung zu übertragende Daten enthält.

Diese Eigenschaft wird mit der Eigenschaft method verwendet. Wenn URLRequest.method den Wert POST aufweist, werden die Daten mit dem URLRequest-Objekt und der HTTP-Methode POST übertragen.

Wenn URLRequest.method den Wert GET aufweist, definieren die Daten Variablen, die mit dem URLRequest-Objekt und der HTTP-Methode GET gesendet werden.

Die API für "URLRequest" unterstützt binäre POST-Daten sowie URL-codierte Variablen und Strings. Das Datenobjekt kann den Typ "ByteArray", "URLVariables" oder "String" aufweisen.

Die Verwendung der Daten hängt vom Objekttyp ab:

• Wenn es sich um ein ByteArray-Objekt handelt, werden die Binärdaten des Objekts als POST-Daten verwendet. Der Objekttyp "ByteArray" wird für GET-Daten nicht unterstützt. Dasselbe gilt für FileReference.upload() und FileReference.download().
• Wenn es sich um ein URLVariables-Objekt handelt und die Methode POST verwendet wird, werden die Variablen im Format x-www-form-urlencoded codiert, und der Ergebnisstring wird als POST-Daten verwendet. Eine Ausnahme bildet hier der Aufruf von FileReference.upload(), bei dem die Variablen als separate Felder in einem multipart/form-data-Post gesendet werden.
• Wenn es sich um ein URLVariables-Objekt handelt und die Methode GET verwendet wird, definiert das URLVariables-Objekt die Variablen, die mit dem URLRequest-Objekt gesendet werden.
• Andernfalls wird das Objekt in einen String konvertiert, der als POST- oder GET-Daten verwendet wird.

Die Daten werden erst gesendet, wenn eine Methode (z. B. navigateToURL() oder FileReference.upload()) das URLRequest-Objekt verwendet.

Siehe auch

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Steuert, ob als HTTP-Übertragungsmethode ein GET- oder ein POST-Vorgang verwendet wird. Gültige Werte sind URLRequestMethod.GET und URLRequestMethod.POST.

Der Standardwert lautet URLRequestMethod.GET.

Siehe auch

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

Das Array der an die HTTP-Anforderung anzuhängenden HTTP-Anforderungsheader. Das Array besteht aus URLRequestHeader-Objekten. Jedes Objekt im Array muss ein URLRequestHeader-Objekt sein und einen Namens- und einen Wert-String enthalten:

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
  

In Flash Player gelten bestimmte Einschränkungen für Anforderungsheader. Weitere Informationen hierzu finden Sie in der Beschreibung der URLRequestHeader-Klasse.

Die Methoden FileReference.upload() und FileReference.download() unterstützen den Parameter URLRequest.requestHeaders nicht.

Siehe auch

Die anzufordernde URL. In der Standardeinstellung muss sich die URL in derselben Domäne befinden wie die aufrufende SWF-Datei, einschließlich Subdomänen. Bei www.adobe.com und store.adobe.com handelt es sich beispielsweise um unterschiedliche Domänen. Legen Sie eine domänenübergreifende Richtliniendatei auf dem Server ab, auf dem sich die Daten befinden, um Daten von einer anderen Domäne zu laden. Weitere Informationen finden Sie in den Sicherheitsinformationen in der Beschreibung der URLRequest-Klasse.

Hinweis: Flash Player Update 3 und höher unterstützt IPv6 (Internet Protocol Version 6). IPv6 ist eine Internet Protocol-Version, die 128-Bit-Adressen unterstützt (eine Verbesserung gegenüber der älteren Version IPv4, die 32-Bit-Adressen unterstützt). Möglicherweise müssen Sie IPv6 für Ihre Netzwerkschnittstellen aktivieren. Weitere Informationen finden Sie in der Hilfe des Betriebssystems, unter dem die Daten gehostet werden. Wenn IPv6 vom Hostingsystem unterstützt wird, können Sie in URLs numerische IPv6-Literaladressen in eckigen Klammern angeben, wie im folgenden Beispiel:

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

Erstellt ein URLRequest-Objekt. Wenn System.useCodePage auf true gesetzt ist, wird die Anforderung mit der Codepage des Systems codiert. Wenn System.useCodePage auf false gesetzt ist, wird die Anforderung mit Unicode codiert.

Siehe auch

Legen Sie zur Ausführung dieses Beispiels eine Datei mit dem Namen "XMLFile.xml" in dem Verzeichnis ab, in dem sich die SWF-Datei befindet.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}