Gibt die Anzahl der Byte an, die bereits geladen wurden.

Gibt die Gesamtanzahl der Byte der heruntergeladenen Daten an. Diese Eigenschaft weist während des Ladevorgangs den Wert 0 auf und wird nach Abschluss des Vorgangs mit dem entsprechenden Wert gefüllt. Ein fehlender Content-Length-Header führt dazu, dass bytesTotal unbestimmt ist.

Die bei dem Ladevorgang empfangenen Daten. Dieser Eigenschaft werden nur dann Werte zugewiesen, wenn der Ladevorgang abgeschlossen wurde. Das Format der Daten hängt von der Einstellung der Eigenschaft dataFormat ab:

Wenn die Eigenschaft dataFormat auf URLLoaderDataFormat.TEXT gesetzt ist, wird ein String empfangen, der den Text aus der geladenen Datei enthält.

Wenn die Eigenschaft dataFormat auf URLLoaderDataFormat.BINARY gesetzt ist, werden die Daten als ByteArray-Objekt empfangen, das unformatierte Binärdaten enthält.

Wenn die Eigenschaft dataFormat auf URLLoaderDataFormat.VARIABLES gesetzt ist, werden die Daten als URLVariables-Objekt empfangen, das URL-codierte Variablen enthält.

Siehe auch

Steuert, ob die heruntergeladenen Daten als Text (URLLoaderDataFormat.TEXT), unformatierte Binärdaten (URLLoaderDataFormat.BINARY) oder URL-codierte Variablen (URLLoaderDataFormat.VARIABLES) empfangen werden.

Wenn die Eigenschaft dataFormat den Wert URLLoaderDataFormat.TEXT aufweist, wird ein String empfangen, der den Text aus der geladenen Datei enthält.

Wenn die Eigenschaft dataFormat den Wert URLLoaderDataFormat.BINARY aufweist, werden die Daten als ByteArray-Objekt empfangen, das unformatierte Binärdaten enthält.

Wenn die Eigenschaft dataFormat den Wert URLLoaderDataFormat.VARIABLES aufweist, werden die Daten als URLVariables-Objekt empfangen, das URL-codierte Variablen enthält.

Der Standardwert lautet URLLoaderDataFormat.TEXT.

Siehe auch

Erstellt ein URLLoader-Objekt.

Siehe auch

Schließt den laufenden Ladevorgang. Alle laufenden Ladevorgänge werden sofort beendet. Wenn kein URL-Stream ausgeführt wird, wird ein Fehler ausgegeben.

Sendet und lädt Daten von der angegebenen URL. Die Daten können als Text, unformatierte Binärdaten oder URL-codierte Variablen empfangen werden, je nachdem, welchen Wert Sie für die Eigenschaft dataFormat festlegen. Beachten Sie, dass "Text" der Standardwert der Eigenschaft dataFormat ist. Wenn Sie Daten an die angegebene URL senden möchten, können Sie die Eigenschaft data im URLRequest-Objekt festlegen.

Hinweis: Enthält eine geladene Datei Nicht-ASCII-Zeichen (wie z. B. in vielen Sprachen außerhalb des englischen Sprachraums), wird empfohlen, dass Sie die Datei im Format UTF-8 oder UTF-16 und nicht in einem Unicode-fremden Format (z. B. ASCII) speichern.

Beachten Sie bei Verwendung dieser Methode das folgende Sicherheitsmodell von Flash Player:

Ab der Version Flash Player 9 können Sie eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie in der HTML-Seite, die den SWF-Inhalt beinhaltet, den Parameter allowNetworking der Tags object und embed festlegen.

Für Flash Player 8 und neuere Versionen:

• Befindet sich die aufrufende SWF-Datei in der lokalen Sandbox des Dateisystems und die Zieldatei in einer Netzwerk-Sandbox, so ist das Laden von Daten nicht zulässig.
• Das Laden von Daten ist auch dann nicht zulässig, wenn die aufrufende SWF-Datei von einer Netzwerk-Sandbox und die Zielressource aus einer lokalen Quelle stammt.

In Flash Player 7 und höher kann auf Websites der domänenübergreifende Zugriff auf eine Ressource mit einer domänenübergreifenden Richtliniendatei gestattet werden. Bei SWF-Dateien einer beliebigen Version, die in Flash Player ab Version 7 ausgeführt werden, muss sich url in exakt derselben Domäne befinden. Eine SWF-Datei unter www.adobe.com kann beispielsweise nur Daten laden, die sich ebenfalls unter www.adobe.com befinden.

Weitere Informationen finden Sie in den folgenden Abschnitten:

• Das Kapitel Sicherheit im Handbuch Programmieren mit ActionScript 3.0 und die neusten Kommentare zu den LiveDocs.
• Das Flash Player 9-Whitepaper zum Thema Sicherheit

Bei SWF-Dateien, die in einer älteren Version als Flash Player 7 ausgeführt werden, muss sich url in derselben Superdomäne wie die aufrufende SWF-Datei befinden. Eine Superdomäne wird durch Entfernen der äußeren linken Komponente der URL einer Datei abgeleitet. Eine SWF-Datei unter www.adobe.com kann beispielsweise Daten von Quellen unter store.adobe.com laden, da sich beide Dateien in derselben Superdomäne adobe.com befinden.

Parameter

Siehe auch

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Wird ausgelöst, nachdem alle empfangenen Daten decodiert und in der Eigenschaft data des URLLoader-Objekts abgelegt wurden. Nach der Auslösung dieses Ereignisses können Sie auf die empfangenen Daten zugreifen.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird ausgelöst, wenn ein URLLoader.load()-Aufruf versucht, über HTTP auf Daten zuzugreifen, und die aktuelle Flash Player-Umgebung den Statuscode für die Anforderung erkennen und zurückgeben kann. (Diese Informationen können in einigen Browser-Umgebungen möglicherweise nicht bereitgestellt werden.) Beachten Sie, dass das Ereignis httpStatus (falls vorhanden) vor (und zusätzlich zu) jedem complete- oder error-Ereignis gesendet wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird ausgelöst, wenn bei einem URLLoader.load()-Aufruf ein schwerwiegender Fehler auftritt und der Download abgebrochen wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird ausgelöst, wenn der Download-Vorgang nach dem Aufruf der Methode URLLoader.load() gestartet wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird ausgelöst, wenn während des Download-Vorgangs Daten empfangen werden.

Beachten Sie, dass Sie bei Verwendung eines URLLoader-Objekts erst dann auf die Daten zugreifen können, wenn der Ladevorgang abgeschlossen ist. In diesem Fall dient das progress-Ereignis lediglich zur Benachrichtigung über den Fortschritt des Download-Vorgangs. Verwenden Sie ein URLStream-Objekt, um vor Abschluss des Ladevorgangs auf die Daten zuzugreifen.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird ausgelöst, wenn ein URLLoader.load()-Aufruf versucht, Daten von einem Server außerhalb der Sicherheits-Sandbox zu laden.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Hinweis: Legen Sie zur Ausführung des Beispiels eine Datei mit dem Namen "urlLoaderExample.txt" in dem Verzeichnis ab, in dem sich die SWF-Datei befindet. Diese Datei darf nur die folgende Textzeile enthalten: answer=42&question=unknown

Der Beispielcode führt folgende Schritte aus:

1. Die Konstruktorfunktion erstellt eine URLLoader-Instanz mit dem Namen loader und eine URLRequest-Instanz mit dem Namen request, wobei es sich um den Standort und den Namen der zu ladenden Datei handelt.
2. Das Objekt loader wird an die Methode configureListeners() übergeben, die für jedes unterstützte URLLoader-Ereignis Listener hinzufügt.
3. Dann wird das Objekt request an die Methode loader.load() übergeben, die die Textdatei lädt.
4. Nach Abschluss des Ladevorgangs wird das Ereignis Event.COMPLETE event ausgelöst, das wiederum die Methode completeHandler() auslöst. Die Methode completeHandler() erstellt ein URLVariables-Objekt aus dem aus der Datei geladenen Text. Das URLVariables-Objekt konvertiert URL-codierte Name/Wert-Paare in ActionScript-Eigenschaften, um die Bearbeitung der geladenen Daten zu vereinfachen.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        public function URLLoaderExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}