Gibt das Objekt an, bei dem Rückrufmethoden aufgerufen werden sollen. Standardeinstellung ist diese NetConnection-Instanz. Wenn Sie die client-Eigenschaft auf ein anderes Objekt einstellen, werden die Rückrufmethoden bei dem eingestellten Objekt aufgerufen.

Gibt an, ob Flash Player über eine permanente RTMP-Verbindung mit einem Server verbunden ist (true) oder nicht (false). Bei einer Verbindung mit HTTP hat diese Eigenschaft den Wert false, es sei denn, die Verbindung besteht zu Flash Remoting-Diensten auf einem Anwendungsserver, in welchem Fall der Wert true lautet.

Der verwendete Proxytyp für einen erfolgreichen Aufruf von NetConnection.connect() an Flash Media Server: "none", "HTTP", "HTTPS" oder "CONNECT". Der Wert lautet "none", wenn die Verbindung nicht getunnelt wird, "HTTP", wenn die Verbindung über HTTP getunnelt wird, "HTTPS", wenn die Verbindung über HTTPS getunnelt wird, und "CONNECT", wenn die Verbindung mithilfe der Methode HTTP CONNECT getunnelt wird.

Die Standardobjektcodierung für alle in der SWF-Datei erstellten NetConnection-Objekte. Wenn ein Objekt in Binärdaten geschrieben oder aus Binärdaten gelesen wird, gibt die Eigenschaft defaultObjectEncoding an, welche Action Message Format (AMF)-Version für die Serialisierung der Daten verwendet wird: ActionScript 3.0 ( ObjectEncoding.AMF3 ) oder ActionScript 1.0 und ActionScript 2.0 ( ObjectEncoding.AMF0 ).

Der Standardwert ist ObjectEncoding.AMF3. Eine Änderung der Einstellung für NetConnection.defaultObjectEncoding wirkt sich nicht auf bereits vorhandene NetConnection-Instanzen, sondern nur auf nach der Änderung erstellte Instanzen aus.

Um die Objektcodierungen separat einzustellen (anstatt einer Objektcodierung für die gesamte SWF-Datei), verwenden Sie hingegen die Eigenschaft objectEncoding des NetConnection-Objekts.

Nähere Informationen finden Sie in der Beschreibung der Eigenschaft objectEncoding.

Siehe auch

Die Objektcodierung für diese NetConnection-Instanz.

Wenn ein Objekt in Binärdaten geschrieben oder aus Binärdaten gelesen wird, gibt die Eigenschaft defaultObjectEncoding an, welche Action Message Format (AMF)-Version für die Serialisierung der Daten verwendet werden soll: ActionScript 3.0 ( ObjectEncoding.AMF3 ) oder ActionScript 1.0 und ActionScript 2.0 ( ObjectEncoding.AMF0 ). Stellen Sie die objectEncoding-Eigenschaft ein, um eine AMF-Version für eine NetConnection-Instanz festzulegen.

Es ist wichtig, die Funktionsweise dieser Eigenschaft zu kennen, wenn die Kommunikation der ActionScript 3.0-SWF-Datei mit Servern erforderlich ist, die eine ältere Version als Flash Player 9 aufweisen. Die folgenden drei Szenarios sind möglich:

• Verbindung mit einem Server, der AMF3 unterstützt (zum Beispiel Flex Data Services 2 oder Flash Media Server 3). Der Standardwert von defaultObjectEncoding ist ObjectEncoding.AMF3. Für alle in dieser SWF-Datei erstellten NetConnection-Instanzen wird die AMF3-Serialisierung verwendet, d. h., Sie müssen Flash Player nicht anweisen, welche AMF-Codierung zu verwenden ist.
• Verbindung mit einem Server, der AMF nicht unterstützt (zum Beispiel Flash Media Server 2). Setzen Sie in diesem Fall die statische Eigenschaft NetConnection.defaultObjectEncoding auf ObjectEncoding.AMF0. Für alle in dieser SWF-Datei erstellten NetConnection-Instanzen wird die AMF0-Serialisierung verwendet. Die Eigenschaft objectEncoding muss nicht gesetzt werden.
• Herstellung einer Verbindung zu mehreren Servern mit verschiedenen Codierungsversionen. Anstatt defaultObjectEncoding zu verwenden, legen Sie die Objektcodierung pro Verbindung fest, indem Sie die Eigenschaft objectEncoding für jede einzelne Verbindung verwenden. Setzen Sie die Eigenschaft für die Verbindung mit Servern, die AMF0-Codierung verwenden (z. B. Flash Media Server 2), auf ObjectEncoding.AMF0, und für die Verbindung mit Servern, die AMF3-Codierung verwenden (z. B. Flex Data Services 2), auf ObjectEncoding.AMF3.

Sobald die Verbindung für eine NetConnection-Instanz hergestellt ist, kann die Eigenschaft objectEncoding nicht mehr geändert werden.

Wenn Sie die falsche Codierung für die Herstellung einer Serververbindung verwenden, löst Flash Player das Ereignis netStatus aus. Die Eigenschaft NetStatusEvent.info enthält ein Informationsobjekt mit dem code-Eigenschaftswert NetConnection.Connect.Failed und einer Beschreibung, die angibt, dass die Objektcodierung ungültig ist.

Siehe auch

Legt fest, welche Fallback-Methoden ausprobiert werden, wenn ein anfänglicher Verbindungsversuch zum Server fehlschlägt. Sie müssen einen Wert für die Eigenschaft proxyType festlegen, bevor Sie die Methode NetConnection.connect() aufrufen.

Gültige Werte sind "none", "HTTP", "CONNECT" und "best".

In Flash Player 9 ist der Standardwert für diese Eigenschaft none. Wenn Sie diesen Wert nicht ändern, verwendet Flash Player HTTPS-Tunneling für RTMPS. Wenn die Eigenschaft auf "best" gesetzt wird, versucht der Client, die Verbindung über native SSL herzustellen. Kann die Verbindung nicht hergestellt werden, werden andere Verbindungsmethoden probiert. Wenn für die Eigenschaft der Wert "HTTP" eingestellt ist und eine direkte Verbindung fehlschlägt, wird HTTP-Tunneling verwendet. Wenn für die Eigenschaft der Wert "CONNECT" eingestellt ist und eine direkte Verbindung fehlschlägt, wird die Tunneling-Methode CONNECT verwendet. Wenn diese Methode ebenfalls fehlschlägt, erfolgt kein Fallback auf HTTP-Tunneling.

Hinweis: In Flash Player 9 ist diese Eigenschaft nur bei Verwendung von RTMP, RTMPS oder RTMPT anwendbar. Die Methode CONNECT kann nur bei Benutzern angewendet werden, die über einen Proxyserver mit dem Netzwerk verbunden sind.

Der an die NetConnection.connect()-Methode übergebene URI.. Wenn die Methode NetConnection.connect() nicht aufgerufen oder kein URI übergeben wurde, weist diese Eigenschaft den Wert undefined auf.

Gibt an, ob eine sichere Verbindung über TLS (Transport Layer Security) statt HTTPS hergestellt wurde. Diese Eigenschaft ist nur gültig, wenn eine Verbindung mit einem NetConnection-Objekt besteht.

Erstellt ein NetConnection-Objekt. Rufen Sie connect() auf, um eine Verbindung herzustellen.

Wenn die Kommunikation einer SWF-Datei mit älteren Serverversionen als Flash Player 9 erforderlich ist, müssen Sie u. U. die Eigenschaft objectEncoding des NetConnection-Objekts einstellen.

Siehe auch

Fügt der Action Message Format (AMF)-Paketstruktur eine Kontextkopfzeile hinzu. Dieser Header wird mit allen weiteren AMF-Paketen gesendet. Wenn Sie die Methode NetConnection.addHeader() mit demselben Namen aufrufen, wird der vorhandene Header durch den neuen Header ersetzt, der für die Dauer des NetConnection-Objekts erhalten bleibt. Sie können einen Header entfernen, indem Sie die Methode NetConnection.addHeader() mit dem Namen des Headers aufrufen.

Parameter

Ruft auf Flash Media Server oder auf einem Anwendungsserver, auf dem Flash Remoting ausgeführt wird, einen Befehl oder eine Methode auf. Bevor Sie NetConnection.call() aufrufen, müssen Sie NetConnection.connect() aufrufen, um die Verbindung zum Server herzustellen. Sie müssen eine serverseitige Funktion erstellen, die an diese Methode übergeben wird.

Parameter

Schließt die lokal oder zum Server geöffnete Verbindung und löst ein netStatus-Ereignis mit der code-Eigenschaft NetConnection.Connect.Closed aus.

Mit dieser Methode werden alle NetStream-Objekte, die über die Verbindung ausgeführt werden, getrennt. Alle Daten in der Warteschlange, die noch nicht gesendet wurden, werden verworfen. (Um lokale oder serverbasierte Streams zu beenden, ohne die Verbindung zu schließen, verwenden Sie NetStream.close().) Wenn Sie die Verbindung schließen und dann eine neue erstellen möchten, müssen Sie ein neues NetConnection-Objekt erstellen und dann erneut die connect()-Methode aufrufen.

Die close-Methode trennt außerdem alle gemeinsamen Remote-Objekte, die diese Verbindung verwenden. Zur erneuten Verbindungsherstellung müssen Sie das gemeinsame Objekt jedoch nicht neu erstellen. Rufen Sie stattdessen die Methode SharedObject.connect() auf, um die Verbindung mit dem gemeinsamen Objekt wiederherzustellen. Nach der Wiederherstellung der Verbindung mit dem gemeinsamen Objekt werden außerdem alle Daten, die sich beim Aufruf von NetConnection.close() in der Warteschlange befanden, gesendet.

Mit Flash Media Server ist es beim Entwickeln am besten, close() aufzurufen, wenn der Client die Verbindung zum Server nicht mehr benötigt. Das Aufrufen von close() ist die schnellste Möglichkeit, nicht verwendete Verbindungen zu schließen. Sie können die Server als Backup-Maßnahme so konfigurieren, dass nicht verwendete Verbindungen geschlossen werden. Weitere Informationen finden Sie im Flash Media Server Configuration and Administration Guide.

Siehe auch

Erstellt eine bidirektionale Verbindung zwischen Flash Player und einer Flash Media Server-Anwendung. Ein NetConnection-Objekt kann als Verbindung zwischen dem Client und dem Server betrachtet werden. Verwenden Sie NetStream-Objekte, um Streams über diese Verbindung zu senden. Informationen zu den von Flash Media Server unterstützten Codecs und Dateiformaten finden Sie in der Flash Media Server-Dokumentation.

Ohne Flash Media Server rufen Sie NetConnection.connect auf, um Video- und MP3-Dateien aus einem lokalen Dateisystem oder von einem Webserver abzuspielen. Informationen zu den unterstützten Codecs und Dateiformaten finden Sie unter http://www.adobe.com/go/hardware_scaling_de.

Erstellt eine bidirektionale Verbindung zwischen Flash Player und einem Anwendungsserver, auf dem der Dienst Flash Remoting ausgeführt wird. Mit der NetServices-Klasse rufen Sie über ein NetConnection-Objekt Funktionen auf und Ergebnisse von Anwendungsservern auf. Weitere Informationen finden Sie in der Flash Remoting-Dokumentation.

Bedenken Sie beim Einsatz dieser Methode das Sicherheitsmodell von Flash Player und die folgenden Sicherheitsaspekte:

• Standardmäßig lässt Flash Player Sandbox-übergreifende Zugriffe nicht zu. Bei einer Website kann der Zugriff auf eine Ressource durch eine domänenübergreifende Richtliniendatei ermöglicht werden.
• Ihre Anwendung kann den Zugriff auf eine Ressource auf dem Server verhindern. In einer Flash Media Server-Anwendung müssen Sie serverseitigen Programmcode hinzufügen, um den Zugriff zu verweigern. Nähere Informationen finden Sie in der Flash Media Server-Dokumentation.
• Sie können NetConnection.connect() nicht verwenden, wenn sich die aufrufende SWF-Datei in der lokalen Sandbox des Dateisystems befindet.
• Sie können eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie in der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.

Weitere Informationen finden Sie in den folgenden Abschnitten:

• Das Kapitel Sicherheit im Handbuch Programmieren mit ActionScript 3.0 und die neusten Kommentare zu den LiveDocs.
• Das Flash Player 9-Whitepaper zum Thema Sicherheit

Parameter

Siehe auch

Wird ausgelöst, wenn eine Ausnahme asynchron ausgelöst wird – das heißt, aus nativem asynchronem Code.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird beim Auftreten eines Eingabe/Ausgabe-Fehlers ausgelöst, durch den ein Netzwerkvorgang fehlschlägt.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird ausgelöst, wenn der Status oder die Fehlerbedingung eines NetConnection-Objekts protokolliert wird. Das Ereignis netStatus enthält die Eigenschaft info. Dabei handelt es sich um ein Informationsobjekt mit spezifischen Informationen über das Ereignis, z. B., ob ein Verbindungsversuch erfolgreich war oder fehlgeschlagen ist.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird ausgelöst, wenn mit einem Aufruf von NetConnection.call() versucht wird, eine Verbindung mit einem Server außerhalb der Sicherheits-Sandbox des Aufrufers herzustellen.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

In diesem Fall wird der Code zur Erstellung des Video- und NetStream-Objekts und zum Aufrufen der Methoden Video.attachNetStream() und NetStream.play() in eine Prozedur-Funktion eingefügt. Die Prozedur wird nur aufgerufen, wenn die Verbindung mit dem NetConnection-Objekt erfolgreich hergestellt werden kann, d. h. wenn das Ereignis netStatus ein info-Objekt mit einer code-Eigenschaft zurückgibt, die Erfolg angibt. Es wird empfohlen, die erfolgreiche Verbindungsherstellung abzuwarten, bevor Sie NetStream.play() aufrufen.

package {
    import flash.display.Sprite;
    import flash.events.NetStatusEvent;
    import flash.events.SecurityErrorEvent;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.Event;

    public class NetConnectionExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetConnectionExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Stream not found: " + videoURL);
                    break;
            }
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.client = new CustomClient();
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
    }
}

class CustomClient {
    public function onMetaData(info:Object):void {
        trace("metadata: duration=" + info.duration + " width=" + info.width + " height=" + info.height + " framerate=" + info.framerate);
    }
    public function onCuePoint(info:Object):void {
        trace("cuepoint: time=" + info.time + " name=" + info.name + " type=" + info.type);
    }
}