Das Erstellungsdatum der Datei auf der lokalen Festplatte. Falls das FileReference-Objekt noch keine Daten enthält, gibt der Aufruf dieser Eigenschaft null zurück.

Siehe auch

Der Erstellertyp für die Datei (auf Macintosh-Systemen). In Windows weist diese Eigenschaft den Wert null auf. Falls das FileReference-Objekt noch keine Daten enthält, gibt der Aufruf dieser Eigenschaft null zurück.

Siehe auch

Das Datum, an dem die Datei auf der lokalen Festplatte zuletzt geändert wurde. Falls das FileReference-Objekt noch keine Daten enthält, gibt der Aufruf dieser Eigenschaft null zurück.

Siehe auch

Der Name der Datei auf der lokalen Festplatte. Falls das FileReference-Objekt noch keine Daten enthält, gibt der Aufruf dieser Eigenschaft null zurück.

Den Eigenschaften eines FileReference-Objekts werden durch einen Aufruf der Methode browse() Werte zugewiesen. Im Unterschied zu anderen FileReference-Eigenschaften wird beim Aufruf der Methode download() die Eigenschaft name erst bei Auslösung des Ereignisses select mit Daten aktualisiert.

Siehe auch

Die Größe der Datei auf der lokalen Festplatte in Byte. Wenn size den Wert 0 aufweist, wird eine Ausnahme ausgelöst.

Siehe auch

Der Dateityp. Auf Windows-Systemen ist diese Eigenschaft die Dateinamenerweiterung. Auf Macintosh-Systemen ist diese Eigenschaft ein aus vier Zeichen bestehender Dateityp. Falls das FileReference-Objekt noch keine Daten enthält, gibt der Aufruf dieser Eigenschaft null zurück.

Erstellt ein neues FileReference-Objekt. Sobald dieses Objekt mit Daten versehen ist, wird ein FileReference-Objekt zu einer Datei auf der lokalen Festplatte eines Benutzers.

Siehe auch

Zeigt ein Dialogfeld für die Dateisuche an, in dem der Benutzer eine Datei für einen Upload-Vorgang auswählen kann. Das Dialogfeld stammt aus dem Betriebssystem des Benutzers. Der Benutzer kann eine Datei aus dem lokalen System oder aus anderen Systemen auswählen, z. B. über einen UNC-Pfad (Windows).

Wenn diese Methode aufgerufen wird und der Benutzer erfolgreich eine Datei auswählt, werden die Eigenschaften dieses FileReference-Objekts mit den Eigenschaftendaten der Datei aktualisiert. Bei jedem nachfolgenden Aufruf der Methode FileReference.browse() werden die Eigenschaften des FileReference-Objekts auf die vom Benutzer im Dialogfeld ausgewählte Datei zurückgesetzt. Es kann immer nur eine browse()- oder download()-Sitzung durchgeführt werden (da immer nur ein Dialogfeld aufgerufen werden kann).

Mit dem Parameter typeFilter können Sie festlegen, welche Dateien im Dialogfeld angezeigt werden.

Parameter

Siehe auch

Bricht alle laufenden Updoad- bzw. Download-Vorgänge dieses FileReference-Objekts ab. Durch Aufruf dieser Methode wird nicht das Ereignis cancel ausgelöst. Dieses Ereignis wird nur ausgelöst, wenn der Benutzer den Vorgang abbricht, indem er das Dialogfeld für den Upload- bzw. Download-Vorgang schließt.

Öffnet ein Dialogfeld, mit dem der Benutzer eine Datei von einem Remote-Server herunterladen kann. In Flash Player ist kein Grenzwert für die Größe der Dateien für Upload- und Download-Vorgänge festgelegt. Offiziell unterstützt der Player Dateigrößen von bis zu 100 MB.

Mit der Methode download() wird zunächst ein Dialogfeld des Betriebssystems geöffnet, in dem der Benutzer aufgefordert wird, einen Dateinamen einzugeben und einen Ordner zum Speichern der Datei auf dem lokalen Computer auszuwählen. Wenn der Benutzer den Speicherort auswählt und den Download-Vorgang bestätigt (z. B. durch Klicken auf "Speichern"), wird der Download vom Remote-Server gestartet. Listener erhalten Ereignisdaten und zeigen den Fortschritt, den Erfolg oder den Fehlschlag des Downloads an. Um den Status des Dialogfelds und des Download-Vorgangs nach dem download-Aufruf ermitteln zu können, muss der ActionScript-Code Listener für Ereignisse wie cancel, open, progress und complete enthalten.

Die Funktionen FileReference.upload() und FileReference.download() sind ungeblockt. Die Funktionsrückgaben erfolgen nach dem Aufruf vor Abschluss der Dateiübertragung. Wenn bei einem FileReference-Objekt der Gültigkeitsbereich verlassen wird, werden alle zu dem Zeitpunkt noch nicht abgeschlossenen Upload- bzw. Download-Vorgänge für dieses Objekt abgebrochen. Stellen Sie sicher, dass das FileReference-Objekt während der gesamten Dauer des Upload- bzw. Download-Vorgangs den Gültigkeitsbereich nicht verlässt.

Nach erfolgreich abgeschlossenem Download-Vorgang werden die Eigenschaften des FileReference-Objekts mit den Eigenschaften der lokalen Datei aktualisiert. Bei erfolgreichem Abschluss des Download-Vorgangs wird das Ereignis complete ausgelöst.

Es kann immer nur eine browse()- oder download()-Sitzung durchgeführt werden (da immer nur ein Dialogfeld aufgerufen werden kann).

Diese Methode unterstützt den Download jedes Dateityps mit HTTP oder HTTPS.

Hinweis: Wenn der Server eine Benutzerauthentifizierung erfordert, kann der Benutzer nur bei SWF-Dateien, die in einem Browser — also mit einem Browser-Plug-In oder einer ActiveX-Steuerung — ausgeführt werden, in einem Dialogfeld zur Eingabe eines Benutzernamens und eines Kennworts zur Authentifizierung aufgefordert werden. Dies gilt darüber hinaus nur für Download-Vorgänge. Upload-Vorgänge mit Plug-Ins oder ActiveX-Steuerelementen bzw. Upload- und Download-Vorgänge mit dem Standalone- oder externen Player schlagen fehl.

Beachten Sie bei Verwendung dieser Methode das folgende Sicherheitsmodell von Flash Player:

• Ladevorgänge sind nicht zulässig, wenn die aufrufende SWF-Datei sich in einer nicht vertrauenswürdigen lokalen Sandbox befindet.
• Standardmäßig werden Sandbox-übergreifende Zugriffe nicht zugelassen. Bei einer Website kann der Zugriff auf eine Ressource durch eine domänenübergreifende Richtliniendatei ermöglicht werden.
• Sie können eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie in der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.

Weitere Informationen finden Sie in den folgenden Abschnitten:

• Das Kapitel Sicherheit im Handbuch Programmieren mit ActionScript 3.0 und die neusten Kommentare zu den LiveDocs.
• Das Flash Player 9-Whitepaper zum Thema Sicherheit

Parameter

Siehe auch

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Startet den Upload-Vorgang für eine vom Benutzer auf einem Remote-Server ausgewählte Datei. In Flash Player ist kein Grenzwert für die Größe der Dateien für Upload- und Download-Vorgänge festgelegt. Offiziell unterstützt der Player Dateigrößen von bis zu 100 MB. Vor dem Aufruf dieser Methode müssen Sie die Methode FileReference.browse() oder FileReferenceList.browse() aufrufen.

Listener erhalten Ereignisdaten und zeigen den Fortschritt, den Erfolg oder den Fehlschlag des Uploads an. Sie können Benutzern mit dem Objekt "FileReferenceList" zwar die Auswahl mehrerer Dateien zum Upload ermöglichen, die Dateien müssen jedoch einzeln hochgeladen werden. Verwenden Sie hierzu das Array FileReferenceList.fileList der FileReferenceList-Objekte.

Die Funktionen FileReference.upload() und FileReference.download() sind ungeblockt. Die Funktionsrückgaben erfolgen nach dem Aufruf vor Abschluss der Dateiübertragung. Wenn bei einem FileReference-Objekt der Gültigkeitsbereich verlassen wird, werden alle zu dem Zeitpunkt noch nicht abgeschlossenen Upload- bzw. Download-Vorgänge für dieses Objekt abgebrochen. Stellen Sie sicher, dass das FileReference-Objekt während der gesamten Dauer des Upload- bzw. Download-Vorgangs den Gültigkeitsbereich nicht verlässt.

Die betreffenden Dateien werden zu der im Parameter url angegebenen jeweiligen URL hochgeladen. Bei der URL sollte es sich um ein Serverskript handeln, das für Uploads konfiguriert ist. In Flash Player werden Dateien mit der HTTP POST-Methode hochgeladen. Das den Upload verwaltende Serverskript sollte eine POST-Anforderung mit den folgenden Elementen erwarten:

• Content-Type mit dem Wert multipart/form-data
• Content-Disposition mit einem standardmäßig auf "Filedata" gesetzten name-Attribut und einem filename-Attribut, das auf den Namen der ursprünglichen Datei gesetzt ist.
• Die Binärdaten der Datei

Ein Beispiel für eine POST-Anforderung finden Sie in der Beschreibung zum Parameter uploadDataFieldName. Sie können POST- oder GET-Parameter mit der Methode upload() an den Server senden. Nähere Informationen finden Sie in der Beschreibung zum Parameter request.

Wenn der Parameter testUpload den Wert true aufweist und die hochzuladende Datei größer ist als etwa 10 KB, sendet Flash Player unter Windows vor dem Hochladen der tatsächlichen Datei zunächst einen Test-Upload ohne Inhalt mit der POST-Methode, um sicherzustellen, dass die Übertragung erfolgreich durchgeführt werden kann. Anschließend wird ein zweiter POST-Vorgang mit dem tatsächlichen Dateiinhalt gesendet. Bei Dateien, die kleiner sind als 10 KB, führt Flash Player nur einen POST-Vorgang mit dem tatsächlichen Inhalt der hochzuladenden Datei durch. Auf Macintosh-Plattformen werden keine POST-Vorgänge für Test-Uploads durchgeführt.

Hinweis: Wenn der Server eine Benutzerauthentifizierung erfordert, kann der Benutzer nur bei SWF-Dateien, die in einem Browser — also mit einem Browser-Plug-In oder einer ActiveX-Steuerung — ausgeführt werden, in einem Dialogfeld zur Eingabe eines Benutzernamens und eines Kennworts zur Authentifizierung aufgefordert werden. Dies gilt darüber hinaus nur für Download-Vorgänge. Upload-Vorgänge mit Plug-Ins oder ActiveX-Steuerelementen bzw. Upload- und Download-Vorgänge mit dem Standalone- oder externen Player schlagen fehl.

Beachten Sie bei Verwendung dieser Methode die folgenden Einschränkungen des Sicherheitsmodells von Flash Player:

• Ladevorgänge sind nicht zulässig, wenn die aufrufende SWF-Datei sich in einer nicht vertrauenswürdigen lokalen Sandbox befindet.
• Standardmäßig werden Sandbox-übergreifende Zugriffe nicht zugelassen. Bei einer Website kann der Zugriff auf eine Ressource durch eine domänenübergreifende Richtliniendatei ermöglicht werden.
• Sie können eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie in der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.

Weitere Informationen finden Sie in den folgenden Abschnitten:

• Das Kapitel Sicherheit im Handbuch Programmieren mit ActionScript 3.0 und die neusten Kommentare zu den LiveDocs.
• Das Flash Player 9-Whitepaper zum Thema Sicherheit

Parameter

 Content-Type: multipart/form-data; boundary=AaB03x --AaB03x Content-Disposition: form-data; name="Filedata"; filename="example.jpg" Content-Type: application/octet-stream ... contents of example.jpg ... --AaB03x-- 
 

Siehe auch

Wird ausgelöst, wenn der Benutzer eine Upload- oder Download-Vorgang über das Dialogfeld zum Suchen von Dateien abbricht. Flash Player löst dieses Ereignis nicht aus, wenn der Benutzer einen Upload bzw. Download auf andere Weise abbricht (durch Schließen des Browsers oder anhalten der aktuellen Anwendung).

Dieses Ereignis verfügt über die folgenden Eigenschaften:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Wird ausgelöst, wenn der Download-Vorgang abgeschlossen ist oder wenn beim Upload-Vorgang der HTTP-Statuscode 200 generiert wird. Bei Download-Vorgängen wird dieses Ereignis ausgelöst, wenn Flash Player den Download der gesamten Datei auf die Festplatte abgeschlossen hat. Bei Upload-Vorgängen wird dieses Ereignis ausgelöst, nachdem Flash Player vom empfangenden Server den HTTP-Statuscode 200 empfangen hat.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Siehe auch

Wird ausgelöst, wenn ein Upload-Vorgang fehlschlägt und HTTP-Statuscode zur Beschreibung des Fehlers verfügbar ist. Das Ereignis httpStatus wird gefolgt von einem ioError-Ereignis ausgelöst.

Das Ereignis httpStatus wird nur bei Upload-Fehlern ausgelöst. Aufgrund der Art und Weise, in der Flash Player während eines Download-Vorgangs den Browser nutzt, steht dieses Ereignis nicht für Download-Fehler zur Verfügung. Wenn ein Download mit einem HTTP-Fehler abbricht, wird dieser Fehler als E/A-Fehler gemeldet.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird ausgelöst, wenn der Upload- bzw. Download-Vorgang fehlschlägt. Das Fehlschlagen einer Dateiübertragung kann folgende Ursachen haben:

• Während des Lese-, Schreib- oder Übertragungsvorgangs der Datei ist ein Eingabe/Ausgabe-Fehler aufgetreten.
• Mit der SWF-Datei wird versucht, eine Datei auf einen Server hochzuladen, der eine Authentifizierung (z. B. anhand eines Benutzernamens und eines Kennworts) erfordert. Während des Uploads stellt Flash Player keine Möglichkeit für die Eingabe von Kennwörtern durch die Benutzer bereit. Wenn eine SWF-Datei versucht, eine Datei auf einen Server hochzuladen, der eine Authentifizierung erfordert, schlägt dieser Upload fehl.
• Mit der SWF-Datei wird versucht, im Standalone- oder externen Player eine Datei von einem Server herunterzuladen, der eine Authentifizierung erfordert. Während des Downloads stellt der Standalone- bzw. externe Player keine Möglichkeit für die Eingabe von Kennwörtern durch die Benutzer bereit. Wenn mit einer SWF-Datei versucht wird, innerhalb dieser Player eine Datei von einem Server herunterzuladen, der eine Authentifizierung erfordert, schlägt dieser Download fehl. Der Download von Dateien funktioniert grundsätzlich nur bei einer ActiveX-Steuerung oder bei Plug-In-Playern von Browsern.
• Der an den Parameter url in der Methode upload() übergebene Wert enthält ein ungültiges Protokoll. Die zulässigen Protokolle sind HTTP und HTTPS.

Wichtig: Nur bei Flash-Anwendungen, die in einem Browser — also mithilfe eines Browser-Plug-Ins oder einer ActiveX-Steuerung — ausgeführt werden, kann der Benutzer in einem Dialogfeld zur Eingabe eines Benutzernamens und eines Kennworts zur Authentifizierung aufgefordert werden. Dies gilt darüber hinaus nur für Download-Vorgänge. Upload-Vorgänge mit Plug-Ins oder ActiveX-Steuerelementen bzw. Upload- und Download-Vorgänge mit dem Standalone- oder externen Player schlagen fehl.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird beim Start eines Upload- bzw. Download-Vorgangs ausgelöst.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Siehe auch

Wird regelmäßig während des Upload- bzw. Download-Vorgangs ausgelöst. Das Ereignis progress wird ausgelöst, während Flash Player Byte an einen Server sendet. Im Verlauf der Übertragung wird das Ereignis in regelmäßigen Abständen auch dann aufgerufen, wenn die Übertragung am Ende nicht erfolgreich abgeschlossen werden kann. Wenn Sie feststellen möchten, ob und zu welchem Zeitpunkt die Dateiübertragung erfolgreich abgeschlossen wird, verwenden Sie einen Listener für das complete-Ereignis.

In einigen Fällen werden keine progress-Ereignisse empfangen. Wenn die übertragene Datei beispielsweise sehr klein ist oder der Upload- bzw. Download-Vorgang in sehr kurzer Zeit erfolgt, wird möglicherweise kein progress-Ereignis ausgelöst.

Bei Macintosh-Plattformen vor Version OS X 10.3 kann der Fortschritt von Upload-Vorgängen nicht festgestellt werden. Das progress-Ereignis wird zwar während des Upload-Vorgangs aufgerufen, die Eigenschaft bytesLoaded weist jedoch stets den Wert -1 auf, was bedeutet, dass der Fortschritt nicht festgestellt werden kann.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Siehe auch

Wird ausgelöst, wenn mit einem Aufruf der Methode FileReference.upload() oder FileReference.download() versucht wird, eine Datei auf einen Server zu laden oder von einem Server herunterzuladen, der sich außerhalb der Sicherheits-Sandbox des Aufrufers befindet. Der Wert der Texteigenschaft zur Beschreibung des aufgetretenen Fehlers ist in der Regel "securitySandboxError". Mit der aufrufenden SWF-Datei wurde unter Umständen versucht, ohne entsprechende Berechtigung auf eine SWF-Datei außerhalb ihrer Domäne zuzugreifen. Sie können versuchen, diesen Fehler mithilfe einer domänenübergreifenden Richtliniendatei zu umgehen.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Siehe auch

Wird ausgelöst, wenn der Benutzer im Dialogfeld zum Suchen von Dateien eine Datei für einen Upload- oder Download-Vorgang auswählt. (Dieses Dialogfeld wird beim Aufruf der Methode FileReferenceList.browse(), FileReference.browse() oder FileReference.download() geöffnet.) Sobald ein Benutzer eine Datei auswählt und den Vorgang bestätigt (z. B. durch Klicken auf OK), werden die Eigenschaftenfelder des FileReference-Objekts mit Daten gefüllt.

Das select-Ereignis kann je nach aufrufender Methode etwas variieren. Wenn das Ereignis select nach einem browse()-Aufruf ausgelöst wird, können sämtliche Eigenschaften des FileReference-Objekts von Flash Player gelesen werden, da sich die vom Benutzer ausgewählte Datei im lokalen Dateisystem befindet. Wenn das Ereignis select nach einem download()-Aufruf ausgelöst wird, kann Flash Player lediglich die Eigenschaft name lesen, da die Datei zu dem Zeitpunkt der Auslösung des select-Ereignisses noch nicht in das lokale Dateisystem heruntergeladen wurde. Nachdem die Datei heruntergeladen und das Ereignis complete ausgelöst wurde, können alle anderen Eigenschaften des FileReference-Objekts in Flash Player gelesen werden.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Wird ausgelöst, nachdem die Daten vom Server nach einem erfolgreichen Upload empfangen wurden. Das Ereignis wird nur ausgelöst, wenn Daten vom Server zurückgegeben werden.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Hinweis: Ändern Sie zur Ausführung dieses Beispiels die Eigenschaft "uploadURL.url" so, dass sie auf eine tatsächliche URL verweist. Die URL muss auf eine Datei mit dem Namen yourUploadHandlerScript.cfm im Stammverzeichnis des Webservers der angegebenen URL verweisen. Abhängig von der Konfiguration müssen Sie außerdem ggf. die SWF-Datei unter Verwendung der Einstellung "Nur auf Netzwerk zugreifen" für die Option "Sicherheit bei lokaler Wiedergabe" kompilieren oder die Flash Player-Sicherheitseinstellungen ändern, um den Netzwerkzugriff für diese Datei zuzulassen.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:Event):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}