Der Grad der horizontalen Weichzeichnung. Die zulässigen Werte liegen zwischen 0 und 255,0 (Gleitkommazahl). Der Standardwert ist 4. Zweierpotenzen (z. B. 2, 4, 8, 16 und 32) sind optimiert und ergeben eine schnellere Anzeige als andere Werte.

Der Grad der vertikalen Weichzeichnung. Die zulässigen Werte liegen zwischen 0 und 255,0 (Gleitkommazahl). Der Standardwert ist 4. Zweierpotenzen (z. B. 2, 4, 8, 16 und 32) sind optimiert und ergeben eine schnellere Anzeige als andere Werte.

Gibt an, wie oft die Weichzeichnung durchgeführt werden soll. Der Standardwert lautet BitmapFilterQuality.LOW, was einer einmaligen Anwendung des Filters entspricht. Mit dem Wert BitmapFilterQuality.MEDIUM wird der Filter zweimal angewendet und mit dem Wert BitmapFilterQuality.HIGH dreimal. Bei Letzterem entspricht der Effekt einer Gauss-Weichzeichnung. Filter mit niedrigen Werten werden schneller dargestellt.

Bei den meisten Anwendungen genügt die Angabe der niedrigen, mittleren oder hohen Qualität für quality. Sie können zwar Zahlenwerte bis 15 angeben, um die Anzahl der Filteranwendung zu erhöhen, höhere Werte führen jedoch auch zu einer langsameren Wiedergabe. Anstatt also den Wert von quality zu erhöhen, können Sie einen ähnlichen Effekt mit gleichzeitig schnellerer Darstellung erzielen, indem Sie einfach die Eigenschaftswerte von blurX und blurY erhöhen.

Mithilfe der folgenden BitmapFilterQuality-Konstanten können Sie die Werte für die quality-Eigenschaft festlegen:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Initialisiert den Filter mit den angegebenen Parametern. Mit den Standardwerten wird ein weiches unscharfes Bild erstellt.

Gibt eine Kopie dieses Filterobjekts zurück.

1. Importieren Sie die erforderlichen Klassen.
2. Deklarieren Sie drei Eigenschaften für die draw()-Funktion, mit der das Objekt, auf das der Weichzeichnungsfilter angewendet wird, gezeichnet wird.
3. Erstellen Sie die BlurFilterExample()-Konstruktorfunktion, die Folgendes bewirkt:
   • Ruft die draw()-Funktion auf, die später deklariert wird.
   • Deklariert eine Variable filter als BitmapFilter-Objekt und weist es dem Wert zu, der sich aus dem Aufruf von getBitmapFilter() ergibt.
   • Erstellt ein neues Array-Objekt myFilters und fügt filter zum Array hinzu. Anschließend wird myFilters der filters-Eigenschaft des BlurFilterExample-Objekts zugewiesen. Dadurch werden alle in myFilters vorgefundenen Filter angewendet; in diesem Fall nur filter.
4. Erstellen Sie die getBitmapFilter()-Funktion, mit der Eigenschaften für den Filter erstellt und festgelegt werden.
5. Erstellen Sie die draw()-Funktion. Diese Funktion verwendet Methoden der Graphics-Klasse, auf die über die Eigenschaft graphics der Sprite-Klasse zugegriffen wird, um das Quadrat zu zeichnen.

package {
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BlurFilter;

    public class BlurFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BlurFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var blurX:Number = 30;
            var blurY:Number = 30;
            return new BlurFilter(blurX, blurY, BitmapFilterQuality.HIGH);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}