flash.events.Event (ActionScript 3.0)

	Eigenschaft	Definiert von
		bubbles : Boolean [read-only] Gibt an, ob es sich bei dem Ereignis um ein Bubbling-Ereignis handelt.	Event
		cancelable : Boolean [read-only] Gibt an, ob das mit dem Ereignis verknüpfte Verhalten verhindert werden kann.	Event
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		currentTarget : Object [read-only] Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.	Event
		eventPhase : uint [read-only] Die aktuelle Phase im Ereignisablauf.	Event
		prototype : Object [static] Ein Verweis auf das Prototypobjekt einer Klasse oder eines Funktionsobjekts.	Object
		target : Object [read-only] Das Ereignis-Ziel.	Event
		type : String [read-only] Der Typ des Ereignisses.	Event

	Methode	Definiert von
		Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false) Erstellt ein Ereignisobjekt, das als ein Parameter an Ereignis-Listener übergeben wird.	Event
		clone():Event Dupliziert eine Instanz einer Event-Unterklasse.	Event
		formatToString(className:String, ... arguments):String Eine Dienstprogrammfunktion, mit der die toString()-Methode in Ihrer benutzerdefinierten Event-Klasse implementiert wird.	Event
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isDefaultPrevented():Boolean Überprüft, ob "preventDefault()" im Ereignis aufgerufen wurde.	Event
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		preventDefault():void Bricht das Standardverhalten eines Ereignisses ab, wenn dieses Verhalten abgebrochen werden kann.	Event
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		stopImmediatePropagation():void Verhindert die Verarbeitung von Ereignis-Listenern im aktuellen Knoten und in Knoten, die dem aktuellen Knoten im Ereignisablauf nachfolgen.	Event
		stopPropagation():void Verhindert die Verarbeitung von Ereignis-Listenern in Knoten, die dem aktuellen Knoten im Ereignisablauf nachfolgen.	Event
		toString():String Gibt eine Zeichenfolge zurück, die alle Eigenschaften des Ereignisobjekts enthält.	Event
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object

	Konstante	Definiert von
		ACTIVATE : String = "activate" [static] Definiert den Wert der Eigenschaft "type" eines activate-Ereignisobjekts.	Event
		ADDED : String = "added" [static] Definiert den Wert der Eigenschaft "type" eines added-Ereignisobjekts.	Event
		ADDED_TO_STAGE : String = "addedToStage" [static] Definiert den Wert der Eigenschaft "type" eines addedToStage-Ereignisobjekts.	Event
		CANCEL : String = "cancel" [static] Definiert den Wert der Eigenschaft type eines cancel-Ereignisobjekts.	Event
		CHANGE : String = "change" [static] Definiert den Wert der Eigenschaft "type" eines change-Ereignisobjekts.	Event
		CLOSE : String = "close" [static] Definiert den Wert der Eigenschaft "type" eines close-Ereignisobjekts.	Event
		COMPLETE : String = "complete" [static] Definiert den Wert der Eigenschaft "type" eines complete-Ereignisobjekts.	Event
		CONNECT : String = "connect" [static] Definiert den Wert der Eigenschaft "type" eines connect-Ereignisobjekts.	Event
		DEACTIVATE : String = "deactivate" [static] Definiert den Wert der Eigenschaft "type" eines deactivate-Ereignisobjekts.	Event
		ENTER_FRAME : String = "enterFrame" [static] Definiert den Wert der Eigenschaft "type" eines enterFrame-Ereignisobjekts.	Event
		FULLSCREEN : String = "fullScreen" [static] Definiert den Wert der Eigenschaft "type" eines fullScreen-Ereignisobjekts.	Event
		ID3 : String = "id3" [static] Definiert den Wert der Eigenschaft "type" eines id3-Ereignisobjekts.	Event
		INIT : String = "init" [static] Definiert den Wert der Eigenschaft "type" eines init-Ereignisobjekts.	Event
		MOUSE_LEAVE : String = "mouseLeave" [static] Definiert den Wert der Eigenschaft "type" eines mouseLeave-Ereignisobjekts.	Event
		OPEN : String = "open" [static] Definiert den Wert der Eigenschaft "type" eines open-Ereignisobjekts.	Event
		REMOVED : String = "removed" [static] Definiert den Wert der Eigenschaft type eines removed-Ereignisobjekts.	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [static] Definiert den Wert der Eigenschaft "type" eines removedFromStage-Ereignisobjekts.	Event
		RENDER : String = "render" [static] Definiert den Wert der Eigenschaft "type" eines render-Ereignisobjekts.	Event
		RESIZE : String = "resize" [static] Definiert den Wert der Eigenschaft type eines resize-Ereignisobjekts.	Event
		SCROLL : String = "scroll" [static] Definiert den Wert der Eigenschaft type eines scroll-Ereignisobjekts.	Event
		SELECT : String = "select" [static] Definiert den Wert der Eigenschaft type eines select-Ereignisobjekts.	Event
		SOUND_COMPLETE : String = "soundComplete" [static] Definiert den Wert der Eigenschaft "type" eines soundComplete-Ereignisobjekts.	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] Definiert den Wert der Eigenschaft "type" eines tabChildrenChange-Ereignisobjekts.	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] Definiert den Wert der Eigenschaft type eines tabEnabledChange-Ereignisobjekts.	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] Definiert den Wert der Eigenschaft "type" eines tabIndexChange-Ereignisobjekts.	Event
		UNLOAD : String = "unload" [static] Definiert den Wert der Eigenschaft "type" eines unload-Ereignisobjekts.	Event

Eigenschaftsdetail

bubbles

Eigenschaft

bubbles:Boolean [read-only]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Gibt an, ob es sich bei dem Ereignis um ein Bubbling-Ereignis handelt. Wenn das Ereignis eine Bubbling-Phase ausführen kann, lautet der Wert true, andernfalls false.

Wenn ein Ereignis auftritt, durchläuft es die drei Phasen des Ereignisablaufs: die Aufnahmephase, die vom Anfang der Anzeigelistenhierarchie bis zum Knoten direkt vor dem Zielknoten verläuft; die Zielphase, die den Zielknoten umfasst; und die Bubbling-Phase, die von dem Zielknoten nachfolgenden Knoten bis zur Anzeigelistenhierarchie verläuft.

Einige Ereignisse, wie zum Beispiel activate und unload, haben keine Bubbling-Phase. Die Eigenschaft bubbles weist für Ereignisse ohne Bubbling-Phase den Wert false auf.

Implementierung
public function get bubbles():Boolean

Siehe auch

Ereignisobjekte

cancelable

Eigenschaft

cancelable:Boolean [read-only]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Gibt an, ob das mit dem Ereignis verknüpfte Verhalten verhindert werden kann. Wenn das Verhalten abgebrochen werden kann, lautet der Wert true, andernfalls false.

Implementierung
public function get cancelable():Boolean

Siehe auch

Event.preventDefault()
Ereignisobjekte

currentTarget

Eigenschaft

currentTarget:Object [read-only]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet. Wenn ein Benutzer auf eine OK-Schaltfläche klickt, kann es sich bei dem Zielknoten um den Knoten handeln, in dem die Schaltfläche enthalten ist, oder um eines der vorangegangenen Elemente, die einen Ereignis-Listener für dieses Ereignis registriert hatten.

Implementierung
public function get currentTarget():Object

Siehe auch

Ereignisobjekte

eventPhase

Eigenschaft

eventPhase:uint [read-only]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Die aktuelle Phase im Ereignisablauf. Diese Eigenschaft kann die folgenden numerischen Werte enthalten:

1 Die Aufnahmephase (EventPhase.CAPTURING_PHASE).
2 Die Zielphase (EventPhase.AT_TARGET).
3 Die Bubbling-Phase (EventPhase.BUBBLING_PHASE).

Implementierung
public function get eventPhase():uint

Siehe auch

Ereignisobjekte

target

Eigenschaft

target:Object [read-only]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Das Ereignis-Ziel. Diese Eigenschaft enthält den Zielknoten. Wenn ein Benutzer beispielsweise auf eine OK-Schaltfläche klickt, ist der Zielknoten der Anzeigelistenknoten, der diese Schaltfläche enthält.

Implementierung
public function get target():Object

Siehe auch

Ereignisobjekte

type

Eigenschaft

type:String [read-only]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Der Typ des Ereignisses. Der Typ ist abhängig von der Groß- und Kleinschreibung.

Implementierung
public function get type():String

Siehe auch

Ereignisobjekte

Konstruktordetail

Event

()

Konstruktor

public function Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false)

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Erstellt ein Ereignisobjekt, das als ein Parameter an Ereignis-Listener übergeben wird.

Parameter

	`type:String` — Der Typ des Ereignisses, auf den als `Event.type` zugegriffen werden kann.

	`bubbles:Boolean` (default = `false`) — Legt fest, ob das Ereignisobjekt an der Bubbling-Phase des Ereignisablaufs teilnimmt. Der Standardwert lautet `false`.

	`cancelable:Boolean` (default = `false`) — Legt fest, ob das Ereignisobjekt abgebrochen werden kann. Der Standardwert lautet `false`.

Methodendetail

clone

()

Methode

public function clone():Event

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Dupliziert eine Instanz einer Event-Unterklasse.

Gibt ein neues Ereignisobjekt zurück, das eine Kopie der ursprünglichen Instanz des Ereignisobjekts ist. Normalerweise rufen Sie clone() nicht auf; es wird automatisch von der EventDispatcher-Klasse aufgerufen, wenn Sie ein Ereignis neu auslösen, das heißt, wenn Sie dispatchEvent(event) von einer Prozedur aus aufrufen, die event verarbeitet.

Das neue Ereignisobjekt übernimmt alle Eigenschaften des Originals.

Wenn Sie Ihre eigene benutzerdefinierte Event-Klasse erstellen, müssen Sie die übernommene Event.clone()-Methode außer Kraft setzen, um die Eigenschaften Ihrer benutzerdefinierten Klasse zu duplizieren. Wenn Sie nicht alle der Ereignis-Unterklasse hinzugefügten Eigenschaften eingestellt haben, weisen sie nicht die korrekten Werte auf, wenn Listener das neu ausgelöste Ereignis verarbeiten.

In dem folgenden Beispiel ist PingEvent eine Unterklasse von Event und implementiert aus diesem Grund eine eigene Version von clone().

  PingEvent-Klasse erweitert "Event" { var URL:String; public override function clone():Event { return new PingEvent(type, bubbles, cancelable, URL); } }

Rückgabewerte

Event — Ein mit dem Original identisches neues Ereignisobjekt.

Siehe auch

Ereignisobjekte

formatToString

()

Methode

public function formatToString(className:String, ... arguments):String

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Eine Dienstprogrammfunktion, mit der die toString()-Methode in Ihrer benutzerdefinierten Event-Klasse implementiert wird. Das Außerkraftsetzen der toString()-Methode wird empfohlen, ist jedoch nicht erforderlich.

  PingEvent-Klasse erweitert "Event" { var URL:String; public override function toString():String { return formatToString("PingEvent", "type", "bubbles", "cancelable", "eventPhase", "URL"); } }

Parameter

	`className:String` — Der Name Ihrer benutzerdefinierten Event-Klasse. Im obigen Beispiel lautet der `className`-Parameter `PingEvent`.

	`... arguments` — Die Eigenschaften der Event-Klasse und die Eigenschaften, die Sie Ihrer benutzerdefinierten Event-Klasse hinzufügen. Im vorigen Beispiel umfasst der `...arguments`-Parameter `type`, `bubbles`, `cancelable`, `eventPhase` und `URL`.

Rückgabewerte

String — Der Name Ihrer benutzerdefinierten Event-Klasse und der String-Wert Ihres ...arguments-Parameters.

isDefaultPrevented

()

Methode

public function isDefaultPrevented():Boolean

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Überprüft, ob preventDefault() im Ereignis aufgerufen wurde. Wenn preventDefault() aufgerufen wurde, wird true zurückgegeben, andernfalls wird false zurückgegeben.

Rückgabewerte

Boolean — Wenn preventDefault() aufgerufen wurde, wird true zurückgegeben, andernfalls wird false zurückgegeben.

Siehe auch

flash.events.Event.preventDefault()
Ereignisobjekte

preventDefault

()

Methode

public function preventDefault():void

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Bricht das Standardverhalten eines Ereignisses ab, wenn dieses Verhalten abgebrochen werden kann.

Vielen Ereignissen ist ein Standardverhalten zugewiesen, das Flash Player standardmäßig ausführt. Wenn ein Benutzer beispielsweise Text in ein Textfeld eingibt, so besteht das Standardverhalten darin, dass die Zeichen in dem Textfeld angezeigt werden. Da das Standardverhalten des TextEvent.TEXT_INPUT-Ereignisses abgebrochen werden kann, können Sie die Anzeige der Zeichen mithilfe der Methode preventDefault() verhindern.

Ein Beispiel für ein Verhalten, das nicht abgebrochen werden kann, ist das Standardverhalten, das dem Event.REMOVED-Ereignis zugewiesen ist. Dieses Verhalten wird immer dann erzeugt, wenn Flash Player ein Anzeigeobjekt aus der Anzeigeliste entfernt. Dieses Standardverhalten (das Entfernen des Elements) kann nicht abgebrochen werden, daher hat die Methode preventDefault() keine Auswirkung auf dieses Standardverhalten.

Mit der Eigenschaft Event.cancelable können Sie überprüfen, ob Sie das einem bestimmten Ereignis zugewiesene Standardverhalten abbrechen können. Wenn der Wert von Event.cancelable auf true lautet, kann preventDefault() zum Abbruch des Ereignisses verwendet werden. Ansonsten hat preventDefault() keine Auswirkungen.

Siehe auch

flash.events.Event.isDefaultPrevented()
Event.cancelable
Ereignisobjekte

stopImmediatePropagation

()

Methode

public function stopImmediatePropagation():void

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Verhindert die Verarbeitung von Ereignis-Listenern im aktuellen Knoten und in Knoten, die dem aktuellen Knoten im Ereignisablauf nachfolgen. Diese Methode wirkt sich sofort und auf die Ereignis-Listener im aktuellen Knoten aus. Im Gegensatz dazu wirkt sich die Methode stopPropagation() nicht aus, bis alle Ereignis-Listener im aktuellen Knoten vollständig verarbeitet wurden.

Hinweis: Diese Methode bricht nicht das diesem Ereignis zugewiesene Standardverhalten ab. Weitere Informationen zu dieser Funktionalität finden Sie unter preventDefault().

Siehe auch

flash.events.Event.stopPropagation()
flash.events.Event.preventDefault()
Ereignisobjekte

stopPropagation

()

Methode

public function stopPropagation():void

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Verhindert die Verarbeitung von Ereignis-Listenern in Knoten, die dem aktuellen Knoten im Ereignisablauf nachfolgen. Diese Methode wirkt sich nicht auf Ereignis-Listener im aktuellen Knoten (currentTarget) aus. Im Gegensatz dazu verhindert die Methode stopImmediatePropagation() die Verarbeitung von Ereignis-Listenern im aktuellen und in den nachfolgenden Knoten. Weitere Aufrufe dieser Methode haben keine Auswirkungen. Diese Methode kann in jeder Phase des Ereignisablaufs aufgerufen werden.

Hinweis: Diese Methode bricht nicht das diesem Ereignis zugewiesene Standardverhalten ab. Weitere Informationen zu dieser Funktionalität finden Sie unter preventDefault().

Siehe auch

flash.events.Event.stopImmediatePropagation()
flash.events.Event.preventDefault()

toString

()

Methode

public function toString():String

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Gibt eine Zeichenfolge zurück, die alle Eigenschaften des Ereignisobjekts enthält. Der String liegt im folgenden Format vor:

[Event type=Wert bubbles=Wert cancelable=Wert]

Rückgabewerte

String — Eine Zeichenfolge, die alle Eigenschaften des Ereignisobjekts enthält.

Siehe auch

Ereignisobjekte

Konstantendetail

ACTIVATE

Konstante

public static const ACTIVATE:String = "activate"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines activate-Ereignisobjekts.

Hinweis: Dieses Ereignis durchläuft keine "Aufnahmephase" und wird direkt an das Ziel gesendet – unabhängig davon, ob sich dieses auf der Anzeigeliste befindet.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Jede DisplayObject-Instanz, die einen Listener besitzt, der für das ACTIVATE-Ereignis registriert worden ist.

Siehe auch

flash.events.EventDispatcher.activate
DEACTIVATE

ADDED

Konstante

public static const ADDED:String = "added"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines added-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`true`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Die DisplayObject-Instanz, die in die Anzeigeliste aufgenommen wird. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.display.DisplayObject.added
ADDED_TO_STAGE
REMOVED
REMOVED_FROM_STAGE

ADDED_TO_STAGE

Konstante

public static const ADDED_TO_STAGE:String = "addedToStage"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Definiert den Wert der Eigenschaft type eines addedToStage-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Die DisplayObject-Instanz, die der Anzeigeliste für die Bühne hinzugefügt wird. Dies erfolgt entweder direkt oder über das Hinzufügen einer Unterstruktur, die die DisplayObject-Instanz enthält. Wenn die DisplayObject-Instanz direkt hinzugefügt wird, findet das `added`-Ereignis vor diesem Ereignis statt.

Siehe auch

flash.display.DisplayObject.addedToStage
ADDED
REMOVED
REMOVED_FROM_STAGE

CANCEL

Konstante

public static const CANCEL:String = "cancel"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines cancel-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Ein Verweis auf das Objekt, dessen Operation abgebrochen wurde.

Siehe auch

flash.net.FileReference.cancel

CHANGE

Konstante

public static const CHANGE:String = "change"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines change-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`true`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Objekt, dessen Wert geändert wurde. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.text.TextField.change
flash.events.TextEvent.TEXT_INPUT

Konstante

public static const CLOSE:String = "close"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines close-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Objekt, dessen Verbindung geschlossen wurde.

Siehe auch

flash.net.Socket.close
flash.net.XMLSocket.close

COMPLETE

Konstante

public static const COMPLETE:String = "complete"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines complete-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Netzwerkobjekt, dessen Ladevorgang beendet ist.

Siehe auch

flash.display.LoaderInfo.complete
flash.media.Sound.complete
flash.net.FileReference.complete
flash.net.URLLoader.complete
flash.net.URLStream.complete
Verwenden von externen Daten

CONNECT

Konstante

public static const CONNECT:String = "connect"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines connect-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Socket- oder XMLSocket-Objekt, das eine Netzwerkverbindung hergestellt hat.

Siehe auch

flash.net.Socket.connect
flash.net.XMLSocket.connect

DEACTIVATE

Konstante

public static const DEACTIVATE:String = "deactivate"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines deactivate-Ereignisobjekts.

Hinweis: Dieses Ereignis durchläuft keine "Aufnahmephase" und wird direkt an das Ziel gesendet – unabhängig davon, ob sich dieses auf der Anzeigeliste befindet.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Jede DisplayObject-Instanz, die einen Listener besitzt, der für das DEACTIVATE-Ereignis registriert worden ist.

Siehe auch

flash.events.EventDispatcher.deactivate
ACTIVATE

ENTER_FRAME

Konstante

public static const ENTER_FRAME:String = "enterFrame"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines enterFrame-Ereignisobjekts.

Hinweis: Dieses Ereignis durchläuft keine "Aufnahmephase" und wird direkt an das Ziel gesendet – unabhängig davon, ob sich dieses auf der Anzeigeliste befindet.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Jede DisplayObject-Instanz, die einen Listener besitzt, der für das ENTER_FRAME-Ereignis registriert worden ist.

Siehe auch

flash.display.DisplayObject.enterFrame

FULLSCREEN

Konstante

public static const FULLSCREEN:String = "fullScreen"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines fullScreen-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Stage-Objekt.

Siehe auch

flash.display.Stage.fullScreen

ID3

Konstante

public static const ID3:String = "id3"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines id3-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Sound-Objekt, über das die MP3-Datei geladen wird, für die nun ID3-Daten verfügbar sind. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.media.Sound.id3

INIT

Konstante

public static const INIT:String = "init"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines init-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das LoaderInfo-Objekt, das mit der zu ladenden SWF-Datei verknüpft ist.

Siehe auch

flash.display.LoaderInfo.init

MOUSE_LEAVE

Konstante

public static const MOUSE_LEAVE:String = "mouseLeave"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines mouseLeave-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Stage-Objekt. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.display.Stage.mouseLeave
flash.events.MouseEvent

OPEN

Konstante

public static const OPEN:String = "open"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines open-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Netzwerkobjekt, über das eine Verbindung geöffnet wurde.

Siehe auch

flash.display.LoaderInfo.open
flash.media.Sound.open
flash.net.FileReference.open
flash.net.URLLoader.open
flash.net.URLStream.open

REMOVED

Konstante

public static const REMOVED:String = "removed"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines removed-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`true`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Die DisplayObject-Instanz, die aus der Anzeigeliste entfernt werden soll. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.display.DisplayObject.removed
ADDED
ADDED_TO_STAGE
REMOVED_FROM_STAGE

REMOVED_FROM_STAGE

Konstante

public static const REMOVED_FROM_STAGE:String = "removedFromStage"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Definiert den Wert der Eigenschaft type eines removedFromStage-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Die DisplayObject-Instanz, die aus der Anzeigeliste für die Bühne entfernt wird. Dies erfolgt entweder direkt oder über das Entfernen einer Unterstruktur, die die DisplayObject-Instanz enthält. Wenn die DisplayObject-Instanz direkt entfernt wird, findet das `removed`-Ereignis vor diesem Ereignis statt.

Siehe auch

flash.display.DisplayObject.removedFromStage
ADDED
REMOVED
ADDED_TO_STAGE

RENDER

Konstante

public static const RENDER:String = "render"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines render-Ereignisobjekts.

Hinweis: Dieses Ereignis durchläuft keine "Aufnahmephase" und wird direkt an das Ziel gesendet – unabhängig davon, ob sich dieses auf der Anzeigeliste befindet.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Das Standardverhalten kann nicht abgebrochen werden.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Jede DisplayObject-Instanz, die einen Listener besitzt, der für das RENDER-Ereignis registriert worden ist.

Siehe auch

flash.display.DisplayObject.render
flash.display.Stage.invalidate()

RESIZE

Konstante

public static const RESIZE:String = "resize"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines resize-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Stage-Objekt.

Siehe auch

flash.display.Stage.resize

SCROLL

Konstante

public static const SCROLL:String = "scroll"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines scroll-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das TextField-Objekt, für das ein Bildlauf durchgeführt wurde. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.text.TextField.scroll

SELECT

Konstante

public static const SELECT:String = "select"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines select-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das FileReference-Objekt, auf dem ein Objekt ausgewählt wurde.

Siehe auch

flash.net.FileReference.select

SOUND_COMPLETE

Konstante

public static const SOUND_COMPLETE:String = "soundComplete"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines soundComplete-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Sound-Objekt, bei dem die Wiedergabe eines Sounds beendet wird.

Siehe auch

flash.media.SoundChannel.soundComplete

TAB_CHILDREN_CHANGE

Konstante

public static const TAB_CHILDREN_CHANGE:String = "tabChildrenChange"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines tabChildrenChange-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`true`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Objekt, dessen tabChildren-Flag sich geändert hat. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.display.InteractiveObject.tabChildrenChange

TAB_ENABLED_CHANGE

Konstante

public static const TAB_ENABLED_CHANGE:String = "tabEnabledChange"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines tabEnabledChange-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`true`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das interaktive Objekt (InteractiveObject), dessen tabEnabled-Flag sich geändert hat. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.display.InteractiveObject.tabEnabledChange

TAB_INDEX_CHANGE

Konstante

public static const TAB_INDEX_CHANGE:String = "tabIndexChange"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines tabIndexChange-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`true`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Objekt dessen Tabulatorindex (tabIndex) sich geändert hat. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Siehe auch

flash.display.InteractiveObject.tabIndexChange

UNLOAD

Konstante

public static const UNLOAD:String = "unload"

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9

Definiert den Wert der Eigenschaft type eines unload-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`false`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das LoaderInfo-Objekt, das mit der zu entfernenden oder zu ersetzenden SWF-Datei verknüpft ist.

Siehe auch

flash.display.LoaderInfo.unload

Beispiele Verwendung von Beispielen

EventExample.as

Im folgenden Beispiel wird anhand der EventExample-Klasse und der benutzerdefinierten Klasse Square die Verwaltung von Ereignis-Bubbling demonstriert.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    public class EventExample extends Sprite {
        
        public function EventExample() {
            var square_0:Square = new Square(300, 0x336633);
            addChild(square_0);
            
            var square_1:Square = new Square(250, 0x669966);
            square_0.addChild(square_1);

            var square_2:Square = new Square(200, 0x66CC66);
            square_1.addChild(square_2);

            var square_3:Square = new Square(150, 0xAA0000);
            square_3.shouldBubble = false;
            square_2.addChild(square_3);

            var square_4:Square = new Square(100, 0x66FF66);
            square_3.addChild(square_4);

            var square_5:Square = new Square(50, 0xCC0000);
            square_5.shouldBubble = false;
            square_4.addChild(square_5);

            this.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(e:Event):void {
            trace(">> stage: " + e.type + " event from " + e.target.name + " called on " + this.name);
            trace(">> --------------------------------------------");
        }
    }
}

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

class Square extends Sprite {
    private var sideLen:int;
    private var color:Number;
    public var shouldBubble:Boolean = true;

    public function Square(sideLen:int, color:Number) {
        this.sideLen = sideLen;
        this.color = color;
        init();
        draw();
    }
        
    private function init():void {
        buttonMode = true;
        this.addEventListener(MouseEvent.CLICK, firstClickHandler);
        this.addEventListener(MouseEvent.CLICK, secondClickHandler);
        this.addEventListener(MouseEvent.CLICK, thirdClickHandler);
    }
        
    private function draw():void {
        this.graphics.beginFill(color);
        this.graphics.drawRect(0, 0, sideLen, sideLen);
    }
        
    private function firstClickHandler(e:Event):void {
        trace(">> 1e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopPropagation();
        }
    }

    private function secondClickHandler(e:Event):void {
        trace(">> 2e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopImmediatePropagation();
            trace(">> --------------------------------------------");
        }
    }

    private function thirdClickHandler(e:Event):void {
        trace(">> 3e: " + e.type + " event from " + e.target.name + " called on " + this.name);
    }
}

EventExample2.as

Im folgenden Beispiel wird der Unterschied zwischen den Ereignissen ADDED und ADDED_TO_STAGE sowie den Ereignissen REMOVED und REMOVED_FROM_STAGE interaktiv gezeigt. Durch Klicken auf ein Sprite wird es mit seinem gesamten geschachtelten Inhalt von der Bühne entfernt. Durch Klicken auf das größte Sprite werden ein REMOVED-Ereignis sowie drei REMOVED_FROM_STAGE-Ereignisse ausgelöst.

 package {
    import flash.display.Sprite;
    import flash.events.*;

    public class EventExample2 extends Sprite {
        public function EventExample2():void {
            var parentSprite:Sprite = createSprite("parentSprite",200);
            var childSprite:Sprite = createSprite("childSprite",100);
            var childOfChildSprite:Sprite = createSprite("childOfChildSprite",50);
            
            trace(":: Adding to Stage ::");
            this.addChild(parentSprite);
            trace(":: Adding to Stage ::");
            parentSprite.addChild(childSprite);
            trace(":: Adding to Stage ::");
            childSprite.addChild(childOfChildSprite);
        }
        private function createSprite(name:String,size:uint):Sprite {
            trace(":: Creating Sprite ::");
            var newSprite:Sprite = new Sprite();
            newSprite.name = name;
            newSprite.graphics.beginFill(0xFFFFFF * Math.random(),1);
            newSprite.graphics.drawRect(0,0,size,size);
            newSprite.graphics.endFill();
            newSprite.addEventListener(Event.ADDED, spriteAdded);
            newSprite.addEventListener(Event.ADDED_TO_STAGE, spriteAddedToStage);
            newSprite.addEventListener(Event.REMOVED, spriteRemoved);
            newSprite.addEventListener(Event.REMOVED_FROM_STAGE, spriteRemovedFromStage);
            newSprite.addEventListener(MouseEvent.CLICK, remove);
            return newSprite;
        }
        private function remove(event:Event) {
            if(event.target == event.currentTarget) {
                trace(":: Removing Clicked Sprite ::");
                var target:Sprite = Sprite(event.target);
                target.parent.removeChild(target);
            }
        }
        private function spriteRemovedFromStage(event:Event):void {
            trace("REMOVED_FROM_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteRemoved(event:Event):void {
            trace("REMOVED: " + event.target.name + " from " + event.currentTarget.name);
        }
        private function spriteAddedToStage(event:Event):void {
            trace("ADDED_TO_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteAdded(event:Event):void {
            trace("ADDED: " + event.target.name + " within " + event.currentTarget.name);
        }
    }
}

Aktuelle Seite: http://livedocs.adobe.com/flash/9.0_de/ActionScriptLangRefV3/flash/events/Event.html

Komponenten-Referenzhandbuch für ActionScript 3.0		Alle Pakete \| Alle Klassen \| Sprachelemente \| Stichwortverzeichnis \| Anhänge \| Konventionen \| Frames Keine Frames
Event	Eigenschaften \| Methoden \| Konstanten \| Beispiele

Paket	flash.events
Klasse	public class Event
Vererbung	Event Object
Unterklassen	ActivityEvent, CaptionChangeEvent, CaptionTargetEvent, ColorPickerEvent, ComponentEvent, ContextMenuEvent, DataChangeEvent, FocusEvent, HTTPStatusEvent, KeyboardEvent, LayoutEvent, ListEvent, MetadataEvent, MotionEvent, MouseEvent, NetStatusEvent, ProgressEvent, ScrollEvent, SliderEvent, SoundEvent, StatusEvent, SyncEvent, TextEvent, TimerEvent, TweenEvent, VideoEvent