Ein Wert aus der StageAlign-Klasse, der die Ausrichtung der Bühne im Flash Player oder Browser bestimmt. Folgende Werte sind gültig:

Die Eigenschaft align ist nur für ein Objekt verfügbar, das sich in derselben Sicherheits-Sandbox befindet wie der Bühneneigentümer (die Haupt-SWF-Datei). Um dies zu verhindern, kann der Bühneneigentümer der Domäne des aufrufenden Objekts die entsprechende Berechtigung erteilen, indem er die Methode Security.allowDomain() oder Security.alowInsecureDomain() aufruft. Weitere Informationen finden Sie im Kapitel "Sicherheit" des Handbuchs Programmieren mit ActionScript 3.0.

Siehe auch

Ein Wert aus der StageDisplayState-Klasse, der festlegt, welcher Anzeigestatus zu verwenden ist. Folgende Werte sind gültig:

• StageDisplayState.FULL_SCREEN: Weist Flash Player an, die Bühne auf den gesamten Bildschirm des Benutzers zu erweitern.
• StageDisplayState.NORMAL: Setzt den Player auf den Standardanzeigemodus für die Bühne zurück.

Das Skalierverhalten des Films im Vollbildmodus wird durch die scaleMode-Einstellung bestimmt (diese wird mithilfe der Stage.scaleMode-Eigenschaft oder der embed-Tageinstellungen der SWF-Datei in der HTML-Datei eingerichtet). Wenn die scaleMode-Eigenschaft auf noScale gesetzt ist, während Flash Player in den Vollbildmodus wechselt, werden die Eigenschaften width und height der Bühne aktualisiert, und der Flash Player löst das Stage.resize-Ereignis aus.

Die folgenden Einschränkungen gelten für SWF-Dateien, die innerhalb einer HTML-Seite wiedergegeben werden (also nicht für Dateien, die mit einem eigenständigen Flash Player wiedergegeben werden):

• Um den Vollbildmodus zu aktivieren, fügen Sie den Parameter allowFullScreen den Tags object und embed auf der HTML-Seite hinzu, die die SWF-Datei enthält. Dabei muss allowFullScreen wie im folgenden Beispiel auf "true" gesetzt sein:

  <param name="allowFullScreen" value="true" />
           ...
    <embed src="example.swf" allowFullScreen="true" ... >

  Auf einer HTML-Seite kann auch Skript verwendet werden, um Tags zum Einbetten von SWF zu erzeugen. Sie müssen das Skript ändern, damit die richtigen allowFullScreen-Einstellungen eingefügt werden. Von Flash und FlexBuilder erzeugte HTML-Seiten verwenden die AC_FL_RunContent()-Funktion, um Verweise auf SWF-Dateien einzubetten. Sie müssen dann die allowFullScreen-Parametereinstellungen wie folgt hinzufügen:

  AC_FL_RunContent( ... "allowFullScreen", "true", ... )

• Der Vollbildmodus wird als Reaktion auf einen Mausklick oder das Drücken einer Taste durch Benutzer initiiert. Der Film kann Stage.displayState nicht ohne Eingabe von Benutzern ändern. Wenn sich der Flash Player im Vollbildmodus befindet, sind alle Eingaben per Tastatur deaktiviert (mit Ausnahme von Tastaturbefehlen, mit denen Benutzer den Vollbildmodus verlassen können). Im Film wird ein Flash Player-Dialogfeld angezeigt, wenn Benutzer den Vollbildmodus aktivieren, um Benutzer darüber zu informieren und darauf hinzuweisen, dass der Vollbildmodus durch Drücken der Esc-Taste beendet werden kann.
• Ab Flash Player Update 3 und höher funktioniert der Vollbildmodus im fensterlosen Modus genau wie im Fenstermodus. Wenn Sie den Fenstermodus (wmode im HTML-Code) auf "Undurchsichtig ohne Fenster" (opaque) oder "Transparent ohne Fenster" (transparent) einstellen, kann das Vollbild initiiert werden, das Vollbildfenster ist jedoch immer undurchsichtig.

Siehe auch

package {
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.*;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    
    public class FullScreenExample extends Sprite
    {
        private var videoURL:String = "testVideo.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video;        
        
        public function FullScreenExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            
            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
        }        
        
        private function toggleFullScreen(event:MouseEvent):void {
            switch(stage.displayState) {
                case "normal":
                    stage.displayState = "fullScreen";    
                    break;
                case "fullScreen":
                default:
                    stage.displayState = "normal";    
                    break;
            }
        }    
        
        // Video related:
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

            video = new Video(stage.stageWidth,stage.stageHeight);
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }            
    }
}

Das interaktive Objekt mit Tastaturfokus bzw. null, wenn der Fokus nicht gesetzt ist oder wenn das Objekt mit dem Fokus zu einer Sicherheits-Sandbox gehört, zu der das aufrufende Objekt keinen Zugang hat.

Ruft die Bildrate der Bühne ab und setzt sie gegebenenfalls neu. Die Bildrate wird als Bilder pro Sekunde definiert. Standardmäßig wird die Bildrate von der zuerst geladenen SWF-Datei übernommen. Der zulässige Bereich für die Bildrate liegt zwischen 0,01 und 1000 Bildern pro Sekunde.

Hinweis: Möglicherweise ist Flash Player nicht in der Lage, den hohen Einstellungen für die Bildrate zu folgen, entweder weil die Zielplattform nicht schnell genug ist oder weil der Player mit der vertikalen Austastlücke des Anzeigegeräts (in der Regel 60 Hz auf LCD-Geräten) synchronisiert ist. In manchen Fällen ist es auch möglich, dass die Zielplattform die maximale Bildrate herabsetzt, wenn eine hohe CPU-Auslastung erwartet wird.

Setzt die Höhe des Monitors, der verwendet wird, wenn der Vollbildmodus aktiviert wird, zurück, falls dieser Modus sofort aufgerufen wird. Wenn der Benutzer über mehrere Monitore verfügt, wird der Monitor verwendet, auf dem sich zu diesem Zeitpunkt der größte Teil der Bühne befindet.

Hinweis: Falls der Benutzer die Möglichkeit hat, zwischen dem Abrufen des Wertes und dem Wechseln in den Vollbildmodus den Browser von einem Monitor zu einem anderen zu verschieben, könnte der Wert inkorrekt sein. Wenn Sie den Wert in eine Ereignisprozedur abrufen, die Stage.displayState auf StageDisplayState.FULL_SCREEN setzt, ist der Wert korrekt.

Dies ist die Höhe des Monitors in Pixel; dieser Wert ist identisch mit der Höhe der Bühne, wenn Stage.align auf den Wert StageAlign.TOP_LEFT und Stage.scaleMode auf den Wert StageScaleMode.NO_SCALE gesetzt ist.

Player Version: Flash Player 9 Update 3.

Siehe auch

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

Legt fest, dass Flash Player einen bestimmten Bereich der Bühne auf den Vollbildmodus skaliert. Falls verfügbar, verwendet Flash Player die Hardwareskalierung, wobei die Grafik- und Videokarte des Computers genutzt wird und Inhalte im Allgemeinen schneller als bei der Softwareskalierung angezeigt werden.

Wenn diese Eigenschaft auf ein gültiges Rechteck und die Eigenschaft displayState auf den Vollbildmodus gesetzt wird, skaliert Flash Player den angegebenen Bereich. Die tatsächliche Größe der Bühne in Pixel innerhalb von ActionScript wird nicht geändert. Flash Player erzwingt eine Mindestgröße des Rechtecks, damit die standardmäßige Meldung "Vollbildmodus mit Esc beenden" darin Platz findet. Diese Mindestgröße beträgt normalerweise ca. 260 x 30 Pixel, kann jedoch je nach Plattform und Flash Player-Version variieren.

Diese Eigenschaft kann nur festgelegt werden, wenn sich Flash Player nicht im Vollbildmodus befindet. Um diese Eigenschaft richtig zu verwenden, legen Sie sie zuerst fest und setzen Sie dann die Eigenschaft displayState auf den Vollbildmodus, wie in den Codebeispielen dargestellt.

Um die Skalierung zu aktivieren, legen Sie die Eigenschaft fullScreenSourceRect auf ein Rechteckobjekt fest:

  
  // valid, will enable hardware scaling
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240); 
  

Um die Skalierung zu deaktivieren, legen Sie in ActionScript 3.0 fullScreenSourceRect=null und in ActionScript 2.0 undefined fest.

  stage.fullScreenSourceRect = null;
  

Der Endbenutzer kann die Hardwareskalierung, die standardmäßig aktiviert ist, in den Flash Player-Anzeigeeinstellungen auch deaktivieren. Weitere Informationen finden Sie unter www.adobe.com/go/display_settings_de.

Player Version: Flash Player 9 Update 3.

Siehe auch

 
import flash.geom.*; 
{
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);
  stage.displayState = StageDisplayState.FULL_SCREEN;
}

package {
    import flash.display.Sprite;
    import flash.display.StageDisplayState;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.NetStatusEvent;
    import flash.events.AsyncErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class Stage_fullScreenSourceRectExample2 extends Sprite {
        private var videoURL:String = "testVideo1.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var myVideo:Video;        
        private    var savedWidth:uint;
        private    var savedHeight:uint;
 
        public function Stage_fullScreenSourceRectExample2() {
    
            connection = new NetConnection();
             connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);    
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);

            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK, toggleFullScreen);
        }        

        private function toggleFullScreen(event:MouseEvent):void {

            if(stage.displayState == StageDisplayState.NORMAL) {
                myVideo.width = myVideo.videoWidth;
                  myVideo.height = myVideo.videoHeight;

                try {
                    stage.fullScreenSourceRect = new Rectangle(myVideo.x, myVideo.y, 
                                                           myVideo.width, myVideo.height);
                     stage.displayState = StageDisplayState.FULL_SCREEN;

                 } catch (e:SecurityError) {
                     trace ("A security error occurred while switching to full screen: " + event);
                    myVideo.width = savedWidth;
                    myVideo.height = savedHeight;
                 }

            }else {
                myVideo.width = savedWidth;
                myVideo.height = savedHeight;
                stage.displayState = StageDisplayState.NORMAL;
            }
        }    

       private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace ("Unable to locate video: " + videoURL);
                    break;
            }
        }

       private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);     

             myVideo = new Video();
            myVideo.attachNetStream(stream);
            stream.play(videoURL);

            savedWidth = myVideo.width;
            savedHeight = myVideo.height;

            addChild(myVideo);
        }
       
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);    
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            
        }            
    }
}

Setzt die Breite des Monitors, der verwendet wird, wenn der Vollbildmodus aktiviert wird, zurück, falls dieser Modus sofort aufgerufen wird. Wenn der Benutzer über mehrere Monitore verfügt, wird der Monitor verwendet, auf dem sich zu diesem Zeitpunkt der größte Teil der Bühne befindet.

Hinweis: Falls der Benutzer die Möglichkeit hat, zwischen dem Abrufen des Wertes und dem Wechseln in den Vollbildmodus den Browser von einem Monitor zu einem anderen zu verschieben, könnte der Wert inkorrekt sein. Wenn Sie den Wert in eine Ereignisprozedur abrufen, die Stage.displayState auf StageDisplayState.FULL_SCREEN setzt, ist der Wert korrekt.

Dies ist die Breite des Monitors in Pixel; dieser Wert ist identisch mit der Breite der Bühne, wenn Stage.align auf den Wert StageAlign.TOP_LEFT und Stage.scaleMode auf den Wert StageScaleMode.NO_SCALE gesetzt ist.

Player Version: Flash Player 9 Update 3.

Siehe auch

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

Gibt die Höhe des Anzeigeobjekts in Pixel an. Die Höhe wird auf Basis der Begrenzungen des Inhalts des Anzeigeobjekts berechnet. Wenn Sie die Eigenschaft height festsetzen, wird die Eigenschaft scaleY entsprechend angepasst, wie im folgenden Code gezeigt.

 var rect:Shape = new Shape();
 rect.graphics.beginFill(0xFF0000);
 rect.graphics.drawRect(0, 0, 100, 100);
 trace(rect.scaleY) // 1;
 rect.height = 200;
 trace(rect.scaleY) // 2;

Abgesehen von TextField- und Video-Objekten, hat ein Anzeigeobjekt ohne Inhalt (z. B. ein leeres Sprite) eine Höhe von 0, selbst wenn Sie versuchen, height auf einen anderen Wert zu setzen.

Bestimmt, ob die dem Objekt untergeordneten Objekte per Maus aktivierbar sind. Ist ein Objekt per Maus aktivierbar, kann ein Benutzer damit in Interaktion treten, indem er eine Maus verwendet. Der Standardwert lautet true.

Diese Eigenschaft ist praktisch, wenn Sie eine Schaltfläche mit einer Instanz der Sprite-Klasse (anstelle der SimpleButton-Klasse) erstellen. Wenn Sie zum Erstellen einer Schaltfläche eine Sprite-Instanz verwenden, können Sie die Schaltfläche ausrüsten und mithilfe der addChild()-Methode zusätzliche Sprite-Instanzen hinzufügen. Dieser Vorgang kann zu unerwarteten Verhaltensweisen bei Mausereignissen führen, da die untergeordneten Sprite-Instanzen zum Zielobjekt eines Mausereignisses werden können, wenn eigentlich die übergeordnete Instanz des Zielobjekts erwartet wird. Um sicherzustellen, dass die übergeordnete Instanz als Zielobjekt für Mausereignisse dient, können Sie die mouseChildren-Eigenschaft der übergeordneten Instanz auf false setzen.

Durch das Festlegen dieser Eigenschaft wird kein Ereignis ausgelöst. Um interaktive Funktionalität zu erzielen, müssen Sie die addEventListener()-Methode verwenden.

Liefert die Anzahl der Objekte, die diesem Objekt untergeordnet sind.

Ein Wert aus der StageQuality-Klasse, der angibt, welche Wiedergabequalität Flash Player verwendet. Folgende Werte sind gültig:

• StageQuality.LOW: Niedrige Wiedergabequalität. Bei Grafiken erfolgt kein Anti-Aliasing, und Bitmaps werden nicht geglättet.
• StageQuality.MEDIUM: Mittlere Wiedergabequalität. Bei Grafiken erfolgt ein Anti-Aliasing mithilfe eines 2 x 2 Pixel großen Rasters, Bitmaps werden hingegen nicht geglättet. Diese Einstellung ist für Filme geeignet, die keinen Text enthalten.
• StageQuality.HIGH: Hohe Wiedergabequalität. Bei Grafiken erfolgt ein Anti-Aliasing mithilfe eines 4 x 4 Pixel großen Rasters, und Bitmaps werden bei statischen Filmen geglättet. Dies ist die von Flash Player verwendete Standardeinstellung für die Wiedergabequalität.
• StageQuality.BEST: Maximale Wiedergabequalität. Bei Grafiken erfolgt ein Anti-Aliasing mithilfe eines 4 x 4 Pixel großen Rasters, und Bitmaps werden immer geglättet.

Siehe auch

Ein Wert aus der StageScaleMode-Klasse, mit dem angegeben wird, welcher Skalierungsmodus verwendet werden soll. Folgende Werte sind gültig:

• StageScaleMode.EXACT_FIT: Die gesamte Flash-Anwendung wird im angegebenen Bereich verzerrungsfrei angezeigt. Dabei bleibt das ursprüngliche Seitenverhältnis der Anwendung erhalten. Unter Umständen werden an zwei Seiten der Anwendung Ränder angezeigt.
• StageScaleMode.SHOW_ALL: Die gesamte Flash-Anwendung wird im angegebenen Bereich angezeigt. Das ursprüngliche Seitenverhältnis des Films wird nicht beibehalten. Dadurch kann es zu Verzerrungen kommen.
• StageScaleMode.NO_BORDER: Die gesamte Flash-Anwendung füllt den angegebenen Bereich so, dass er ohne Verzerrung in den angegebenen Bereich passt. Bei Bedarf wird der Film jedoch zugeschnitten. Das ursprüngliche Seitenverhältnis der Anwendung bleibt erhalten.
• StageScaleMode.NO_SCALE: Die gesamte Flash-Anwendung wird festgelegt und bleibt auch dann unverändert, wenn sich die Größe des Player-Fensters ändert. Ist das Player-Fenster kleiner als der Flash-Inhalt, wird der Inhalt zugeschnitten.

Siehe auch

Gibt an, ob die Standardelemente im Kontextmenü des Flash Players ein- oder ausgeblendet werden.

Wenn die showDefaultContextMenu-Eigenschaft auf true gesetzt ist (die Standardeinstellung), werden alle Elemente des Kontextmenüs eingeblendet. Wenn die showDefaultContextMenu-Eigenschaft auf false gesetzt ist, werden nur die Befehle "Einstellungen" und "Über Adobe Flash Player" angezeigt.

Bestimmt, ob Objekte mit leuchtendem Rahmen angezeigt werden, wenn sie den Fokus besitzen.

Die aktuelle Höhe der Bühne in Pixel.

Wenn der Wert der Stage.scaleMode-Eigenschaft auf StageScaleMode.NO_SCALE gesetzt ist, gibt die stageHeight-Eigenschaft die Höhe des Flash Player-Fensters an. Wenn der Wert von Stage.scaleMode nicht auf StageScaleMode.NO_SCALE gesetzt ist, gibt "stageHeight" die Höhe der SWF-Datei an. Diese Eigenschaft kann nicht festgelegt werden.

Siehe auch

Bestimmt die aktuelle Breite der Bühne in Pixel.

Wenn der Wert der scaleMode-Eigenschaft auf StageScaleMode.NO_SCALE gesetzt ist, gibt die stageWidth-Eigenschaft die Breite von Flash Player an. Dies bedeutet, dass sich auch die stageWidth-Eigenschaft ändert, wenn die Größe des Flash Player-Fensters geändert wird. Wenn der Wert der scaleMode-Eigenschaft nicht auf StageScaleMode.NO_SCALE, gesetzt ist, gibt die stageWidth-Eigenschaft die Breite der SWF-Datei an, die beim Authoring im Dialogfeld "Dokumenteigenschaften" festgelegt wurde. Dies bedeutet, dass der Wert der stageWidth-Eigenschaft beim Ändern der Größe des Flash Player-Fensters nicht geändert wird. Diese Eigenschaft kann nicht festgelegt werden.

Siehe auch

Bestimmt, ob die dem Objekt untergeordneten Objekte per Tabulatortaste aktivierbar sind. Aktiviert oder deaktiviert die Möglichkeit zur Auswahl von untergeordneten Objekten mithilfe der Tabulatortaste. Der Standardwert lautet true.

Liefert ein TextSnapshot-Objekt für diese DisplayObjectContainer-Instanz.

Gibt die Breite des Anzeigeobjekts in Pixel an. Die Breite wird auf Basis der Begrenzungen des Inhalts des Anzeigeobjekts berechnet. Wenn Sie die Eigenschaft width festsetzen, wird die Eigenschaft scaleX entsprechend angepasst, wie im folgenden Code gezeigt.

 var rect:Shape = new Shape();
 rect.graphics.beginFill(0xFF0000);
 rect.graphics.drawRect(0, 0, 100, 100);
 trace(rect.scaleX) // 1;
 rect.width = 200;
 trace(rect.scaleX) // 2;

Abgesehen von TextField- und Video-Objekten, hat ein Anzeigeobjekt ohne Inhalt (z. B. ein leeres Sprite) eine Breite von 0, selbst wenn Sie versuchen, width auf einen anderen Wert zu setzen.

Wenn Sie ein Child-Objekt hinzufügen, das bereits einem anderen Anzeigeobjekt-Container untergeordnet worden ist, wird es aus dessen Child-Liste entfernt.

Parameter

Siehe auch

Das folgende Beispiel enthält z. B. drei Anzeigeobjekte mit der Bezeichnung a, b und c jeweils an den Indexpositionen 0, 1 und 2:

Wenn Sie ein Child-Objekt hinzufügen, das bereits einem anderen Anzeigeobjekt-Container untergeordnet worden ist, wird es aus dessen Child-Liste entfernt.

Parameter

Siehe auch

Nachdem Sie einen Ereignis-Listener erfolgreich registriert haben, können Sie seine Priorität nicht durch weitere Aufrufe von addEventListener() ändern. Um die Priorität eines Listeners zu ändern, müssen Sie zunächst removeListener() aufrufen. Anschließend können Sie den Listener mit der neuen Prioritätsstufe erneut aufrufen.

Nach der Registrierung des Listeners haben nachfolgende Aufrufe von addEventListener() mit einem anderen type- oder useCapture-Wert eine separate Listener-Registrierung zur Folge. Wenn Sie beispielsweise zuerst einen Listener registrieren, für den useCapture auf true gesetzt ist, wird dieser nur während der Aufnahmephase aktiv sein. Wenn Sie addEventListener() für dasselbe Listener-Objekt erneut aufrufen, diesmal aber useCapture auf false gesetzt ist, werden zwei separate Listener angelegt: einer, der während der Aufnahmephase aktiv ist und ein zweiter, der während der Ziel- und Bubbling-Phase aktiv ist.

Sie können einen Ereignis-Listener nicht nur für die Ziel- oder Bubbling-Phase registrieren. Die beiden Phasen hängen während der Registrierung immer zusammen, da Bubbling nur für vorangegangenen Elemente des Zielknotens gilt.

Wenn Sie einen Ereignis-Listener nicht mehr brauchen, entfernen sie ihn, indem Sie removeEventListener() aufrufen. Andernfalls könnte es zu Speicherproblemen kommen. Objekte mit registrierten Ereignis-Listenern werden nicht automatisch aus dem Speicher entfernt, da der Garbage Collector (Speichermanagement) keine Objekte entfernt, die noch Verweise enthalten.

Beim Kopieren einer EventDispatcher-Instanz werden zugewiesene Ereignis-Listener nicht kopiert. (Wenn ein neu angelegter Knoten einen Ereignis-Listener benötigt, müssen Sie den Listener nach dem Erstellen des Knoten zuweisen). Wenn Sie jedoch eine EventDispatcher-Instanz verschieben, werden zugewiesene Ereignis-Listener ebenfalls verschoben.

Wenn der Ereignis-Listener bei einem Knoten registriert wird, während mit diesem Knoten ein Ereignis durchgeführt wird, so wird der Ereignis-Listener während der aktuellen Phase nicht ausgelöst, kann aber während einer späteren Phase im Ereignisablauf ausgelöst werden, etwa während der Bubbling-Phase.

Wird ein Ereignis-Listener von einem Knoten entfernt, während mit dem Knoten ein Ereignis durchgeführt wird, so wird er von den aktuellen Aktionen immer noch ausgelöst. Nachdem er entfernt worden ist, wird der Ereignis-Listener nicht wieder aufgerufen (es sei denn er wird für spätere Verarbeitungsvorgänge erneut aufgerufen).

Parameter

Siehe auch

Parameter

Der Unterschied zwischen hasEventListener() und willTrigger() besteht darin, dass hasEventListener() nur das Objekt untersucht, zu dem es gehört, während willTrigger() den gesamten Ereignisablauf auf das im Parameter type angegebene Ereignis untersucht.

Wird hasEventListener() von einem LoaderInfo-Objekt aus aufgerufen, werden nur die Listener berücksichtigt, die dem Aufrufer zugänglich sind.

Parameter

Durch Aufrufen der invalidate()-Methode wird Flash Player signalisiert, dass bei nächster Gelegenheit die Anzeigeliste neu gezeichnet werden muss (z. B., wenn der Abspielkopf in ein neues Bild tritt). Nachdem Sie die invalidate()-Methode aufgerufen haben und die Anzeigeliste neu gezeichnet worden ist, sendet Flash Player ein render-Ereignis an jedes Anzeigeobjekt, das gemäß seiner Registrierung auf das render-Ereignis wartet. Sie müssen die invalidate()-Methode immer dann aufrufen, wenn Flash Player render-Ereignisse senden soll.

Das render-Ereignis gibt Ihnen die Gelegenheit, Änderungen an der Anzeigeliste vorzunehmen, und zwar unmittelbar bevor sie neu gezeichnet wird. Dadurch haben Sie die Möglichkeit, Aktualisierungen an der Anzeigeliste bis zur letzten Gelegenheit zurückzustellen. Auf diese Weise wird die Performance verbessert, da unnötige Bildschirmaktualisierungen vermieden werden.

Das render-Ereignis wird nur ausgelöst, um Objekte anzuzeigen, die sich in derselben Sicherheitsdomäne befinden wie der Code, der die stage.invalidate()-Methode aufruft, oder um Anzeigeobjekte aus einer Sicherheitsdomäne anzuzeigen, der die Berechtigung über die Security.allowDomain()-Methode erteilt wurde.

Siehe auch

Legt fest, ob die Stage.focus-Eigenschaft aus Sicherheitsgründen den Wert null zurückgibt. Anders ausgedrückt: isFocusInaccessible gibt den Wert true zurück, wenn das Objekt mit dem Fokus zu einer Sicherheits-Sandbox gehört, auf die die SWF-Datei keinen Zugriff hat.

Der Garbage Collector ist der Vorgang, durch den Flash Player nicht genutzten Arbeitsspeicher wieder freigibt. Wenn auf Variablen oder Objekte nicht mehr aktiv verwiesen wird und diese auch nirgends mehr gespeichert sind, werden sie vom Garbage Collector entfernt, und der belegte Arbeitsspeicher wird bereinigt.

Parameter

Wenn Sie die setChildIndex()-Methode verwenden und eine Indexposition angeben, die bereits belegt ist, werden das untergeordnete Objekt an dieser Position sowie alle darüber liegenden Positionen innerhalb der Child-Liste um eine Position nach oben verschoben. Wenn der Anzeigeobjekt-Container im vorigen Beispiel z. B. den Namen container hat, können Sie die Position der Anzeigeobjekte mit den Bezeichnungen a und b austauschen, indem Sie den folgenden Code aufrufen:

container.setChildIndex(container.getChildAt(1), 0);

Dieser Code führt zur folgenden Objektanordnung:

Parameter

Parameter

Der Unterschied zwischen der hasEventListener()- und der willTrigger()-Methode besteht darin, dass die Methode hasEventListener() nur das Objekt untersucht, zu dem sie gehört, während die willTrigger()-Methode den gesamten Ereignisablauf auf das im Parameter type angegebene Ereignis untersucht.

Wird willTrigger() von einem LoaderInfo-Objekt aus aufgerufen, werden nur die Listener berücksichtigt, die dem Aufrufer zugänglich sind.

Parameter

Wird vom Flash Player ausgelöst, wenn das Stage-Objekt den Vollbildmodus aktiviert bzw. verlässt. Ein Änderung des Vollbildmodus kann initiiert werden, indem ActionScript verwendet wird, indem Benutzer einen Tastaturbefehl drücken oder indem das Vollbildfenster den Fokus abgibt.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird vom Stage-Objekt ausgelöst, wenn der Mauszeiger aus dem Flash Player-Fenster herausbewegt wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Wird ausgelöst, wenn die scaleMode-Eigenschaft des Stage-Objekts auf StageScaleMode.NO_SCALE gesetzt und die Größe der SWF-Datei verändert wird.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

1. Der Klassenkonstruktor richtet zuerst die Flash-Anwendung ein, die unabhängig von der Größe des Flash Player-Fensters fixiert werden soll, und fügt unter Verwendung der Methoden activateHandler() und resizeHandler() dann zwei Ereignis-Listener hinzu.
2. Die activateHandler()-Methode wird ausgeführt, sobald die linke Maustaste gedrückt wird.
3. Die resizeHandler()-Methode wird ausgeführt, wenn die Größe der Bühne geändert wird.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;

    public class StageExample extends Sprite {

        public function StageExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            stage.addEventListener(Event.ACTIVATE, activateHandler);
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function activateHandler(event:Event):void {
            trace("activateHandler: " + event);
        }

        private function resizeHandler(event:Event):void {
            trace("resizeHandler: " + event);
            trace("stageWidth: " + stage.stageWidth + " stageHeight: " + stage.stageHeight);
        }
    }
}