Legt ein Anzeigeobjekt fest, das als visuelles Objekt für den Schaltflächenzustand "down" verwendet wird. Dies ist der Zustand der Schaltfläche, wenn Benutzer auf das hitTestState-Objekt klicken.

Siehe auch

Ein boolescher Wert, der angibt, ob eine Schaltfläche aktiviert ist. Wenn eine Schaltfläche deaktiviert ist (ihre enabled-Eigenschaft also auf false gesetzt wurde), dann ist diese Schaltfläche zwar sichtbar, aber das Klicken darauf hat keine Auswirkung. Der Standardwert ist true. Diese Eigenschaft ist nützlich, wenn Sie einen Teil der Navigation deaktivieren möchten, z. B. wenn Sie eine Schaltfläche auf der gerade angezeigten Seite deaktivieren möchten, damit nicht darauf geklickt werden und die Seite nicht erneut geladen werden kann.

Legt ein Anzeigeobjekt fest, das als Kollisionserkennungsobjekt für die Schaltfläche verwendet wird. Für eine normale Schaltfläche setzen Sie die hitTestState-Eigenschaft auf dasselbe Anzeigeobjekt wie die overState-Eigenschaft. Wenn Sie die hitTestState-Eigenschaft nicht setzen, ist die SimpleButton-Schaltfläche nicht aktiv. Sie reagiert also nicht auf Maus- und Tastaturereignisse.

Siehe auch

Legt ein Anzeigeobjekt fest, das als visuelles Objekt für den Schaltflächenstatus "over" verwendet wird. Dies ist der Status, den die Schaltfläche aufweist, wenn sich der Mauszeiger über der Schaltfläche befindet.

Siehe auch

Das SoundTransform-Objekt, das dieser Schaltfläche zugewiesen wurde. Ein SoundTransform-Objekt enthält Eigenschaften zum Festlegen von Lautstärke, Schwenkung sowie Zuordnung von linkem und rechtem Lautsprecher. Dieses SoundTransform-Objekt wird auf alle Statuszustände der Schaltfläche angewendet. Dieses SoundTransform-Objekt wirkt sich nur auf eingebettete Sounds aus.

Siehe auch

Zeigt an, ob andere Anzeigeobjekte, die SimpleButton- oder MovieClip-Objekte sind, durch das Loslassen der Maustaste erzeugte Ereignisse empfangen können. Die trackAsMenu-Eigenschaft dient zum Erstellen von Menüs. Sie können die trackAsMenu-Eigenschaft für jedes SimpleButton- oder MovieClip-Objekt setzen. Wenn die trackAsMenu-Eigenschaft nicht vorhanden ist, lautet das Standardverhalten false.

Sie können die trackAsMenu-Eigenschaft jederzeit ändern. Die geänderte Schaltfläche übernimmt sofort das neue Verhalten.

Legt ein Anzeigeobjekt fest, das als visuelles Objekt für den Schaltflächenstatus "up" verwendet wird. Dies ist der Status, den die Schaltfläche aufweist, wenn sich der Mauszeiger nicht über der Schaltfläche befindet.

Siehe auch

Ein boolescher Wert, der bei true angibt, ob im Flash Player der Handcursor angezeigt wird, wenn Benutzer mit der Maus auf eine Schaltfläche zeigen. Wenn diese Eigenschaft auf false gesetzt ist, wird stattdessen der Pfeilcursor angezeigt. Der Standardwert lautet true.

Sie können die Eigenschaft useHandCursor jederzeit ändern. Die geänderte Schaltfläche übernimmt sofort das neue Cursorverhalten.

Erstellt eine neue SimpleButton-Instanz. Ein oder alle Anzeigeobjekte, die die verschiedenen Schaltflächenzustände repräsentieren, können als Parameter im Konstruktor gesetzt werden.

1. Im Konstruktor SimpleButtonExample() wird ein neues CustomSimpleButton-Objekt vom Typ "SimpleButton" mit dem Namen button erstellt. Dieses Objekt ruft die CustomSimpleButton-Konstruktormethode auf. Das button-Objekt wird der Anzeigeliste hinzugefügt. Farbe und Größe der Schaltfläche werden in den darauf folgenden Schritten festgelegt.
2. In der CustomSimpleButton-Klasse werden Instanzeigenschaften deklariert, die später verwendet werden, um die Größe und Hintergrundfarbe von button zu steuern. Dies erfolgt basierend auf dem jeweiligen Status (orange im normalen Status, dunkelgelb im Mouseover-Status und hellblau im Mousedown-Status). Für jeden Status von button ist die Größe des Quadrats auf 80 Pixel festgelegt, indem die size-Eigenschaft verwendet wird.
3. Die Konstruktorfunktion für die CustomSimpleButton-Klasse setzt die Eigenschaften downState, overState, upState, hitTestState und useHandCursor mit vier Instanzen der ButtonDisplayState-Klasse.
4. In der ButtonDisplayState-Klasse setzt der Konstruktor den Wert des Quadrats für Größe und Hintergrundfarbe und ruft die draw()-Methode auf.
5. Die draw()-Methode zeichnet das Quadrat unter Verwendung der im Konstruktor angegebenen Größe und Hintergrundfarbe basierend auf dem Status der Schaltfläche neu.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}