Enthält das Stamm-Anzeigeobjekt der SWF- oder Bilddatei (JPG, PNG oder GIF), die anhand der Methode load() oder loadBytes() geladen worden ist.

Siehe auch

Gibt ein LoaderInfo-Objekt zurück, das dem zu ladenden Objekt entspricht. LoaderInfo-Objekte werden sowohl vom Loader-Objekt als auch von geladenen Inhaltsobjekten genutzt. Das LoaderInfo-Objekt stellt Informationen und Statistiken zum Ladefortschritt der geladenen Datei bereit.

Ereignisse, die sich auf das Laden beziehen, werden durch das LoaderInfo-Objekt ausgelöst, auf das über die contentLoaderInfo-Eigenschaft des Loader-Objekts verwiesen wird. Die contentLoaderInfo-Eigenschaft wird bereits auf ein gültiges LoaderInfo-Objekt gesetzt, bevor der Inhalt geladen wird, damit Sie dem Objekt vor dem Laden Ereignis-Listener hinzufügen können.

Siehe auch

Erstellt ein Loader-Objekt, das Sie zum Laden von Dateien wie SWF-, JPEG-, GIF- oder PNG-Dateien verwenden können. Rufen Sie die load()-Methode auf, um den Bestandsartikel als Child-Objekt der Loader-Instanz zu laden. Anschließend können Sie das Loader-Objekt in die Anzeigeliste aufnehmen (z. B. indem Sie die addChild()-Methode einer DisplayObjectContainer-Instanz verwenden). Der Bestandsartikel erscheint auf der Bühne, noch während er geladen wird.

Sie können eine Loader-Instanz auch außerhalb der Liste verwenden, also ohne sie in einen Anzeigeobjekt-Container in der Anzeigeliste einzufügen. In diesem Modus kann die Loader-Instanz zum Laden einer SWF-Datei verwendet werden, die zusätzliche Module einer Anwendung enthält.

Um festzustellen, wann die SWF-Datei vollständig geladen ist, können Sie die Ereignisse des LoaderInfo-Objekts verwenden, das der contentLoaderInfo-Eigenschaft des Loader-Objekts zugeordnet ist. An diesem Punkt kann der Code in der Modul-SWF-Datei ausgeführt werden, um das Modul zu initialisieren und zu starten. Außerhalb der Liste kann eine Loader-Instanz auch verwendet werden, um eine SWF-Datei zu laden, die Komponenten oder Medienbestände enthält. Sie können wiederum die Ereignisbenachrichtigungen verwenden, um festzustellen, wann die Komponenten vollständig geladen sind. An diesem Punkt kann die Anwendung beginnen, mit den Komponenten und Medienbeständen in der Bibliothek der SWF-Datei zu arbeiten, indem die ActionScript 3.0-Klassen, die diese Komponenten und Medienbestände repräsentieren, instanziiert werden.

Um den Status eines Loader-Objekts zu ermitteln, überwachen Sie die folgenden Ereignisse, die das LoaderInfo-Objekt der contentLoaderInfo-Eigenschaft des Loader-Objekts zugeordnet hat:

• Das open-Ereignis wird ausgelöst, wenn der Ladevorgang beginnt.
• Die Ereignisse ioError bzw. securityError werden ausgelöst, wenn die Datei nicht geladen werden kann oder wenn während des Ladevorgangs ein Fehler aufgetreten ist.
• Das progress-Ereignis wird fortlaufend ausgelöst, während die Datei geladen wird.
• Das complete-Ereignis wird ausgelöst, nachdem eine Datei vollständig heruntergeladen wurde, jedoch noch bevor die Methoden und Eigenschaften des geladenen Movieclips verfügbar sind.
• Das init-Ereignis wird ausgelöst, sobald die Eigenschaften und Methoden der geladenen SWF-Datei verfügbar sind, sodass Sie mit der Bearbeitung der geladenen SWF-Datei beginnen können. Dieses Ereignis wird vor der Prozedur complete ausgelöst. In gestreamten SWF-Dateien kann das init-Ereignis um einiges früher eintreten als das complete-Ereignis. Für die meisten Zwecke ist die init-Prozedur geeignet.

Siehe auch

Bricht einen aktuell für die Loader-Instanz ausgeführten Vorgang der load()-Methode ab.

Siehe auch

Lädt eine SWF-, JPEG-, progressive JPEG-, nicht animierte GIF- oder PNG-Datei in ein Objekt, das dem Loader-Objekt untergeordnet ist. Wenn Sie eine animierte GIF-Datei laden, wird nur das erste Bild angezeigt. Da das Loader-Objekt nur ein einziges untergeordnetes Objekt besitzen darf, beendet eine nachfolgende load()-Anforderung eine ggf. noch aktive vorherige Anforderung und beginnt einen neuen Ladevorgang.

Eine in ein Loader-Objekt geladene SWF- oder Bilddatei übernimmt die Positions-, Drehungs- und Skalierungseigenschaften der dem Loader-Objekt übergeordneten Anzeigeobjekte.

Mit der unload()-Methode können Sie mit dieser Methode geladene Filme oder Bilder entfernen oder einen laufenden Ladevorgang abbrechen.

Beachten Sie bei Verwendung der load()-Methode das folgende Sicherheitsmodell von Flash Player:

• Sie können Inhalte von jeder Quelle laden, zu der Sie Zugang haben.
• Das Laden ist nicht erlaubt, wenn sich die aufrufende SWF-Datei in einer Netzwerk-Sandbox befindet und die zu ladende Datei lokal gespeichert ist.
• Handelt es sich bei dem geladenen Inhalt um eine SWF-Datei, kann eine SWF-Datei in einer anderen Sicherheits-Sandbox nicht darauf verweisen, es sei denn, dieses "Cross-Scripting-Arrangement" wurde durch einen Aufruf der Security.allowDomain()-Methode in der geladenen Inhaltsdatei genehmigt.
• In ActionScript 1.0 oder 2.0 geschriebene SWF-Dateien, die als AVM1Movie-Objekte geladen werden, können nicht auf SWF-Dateien verweisen, die in ActionScript 3.0 geschrieben sind und als Sprite- oder MovieClip-Objekte geladen werden. Um beide Dateien miteinander kommunizieren zu lassen, können Sie jedoch die LocalConnection-Klasse verwenden.
• Handelt es sich bei dem geladenen Inhalt um ein Bild, kann eine SWF-Datei außerhalb der Sicherheits-Sandbox nicht darauf zugreifen, es sein denn, in der Ursprungsdomäne des Bilds wurde die Domäne dieser SWF-Datei in eine domänenübergreifende Richtliniendatei aufgenommen.
• Movieclips in der "local-with-file-system"-Sandbox können in ihren Skripts nicht auf Movieclips in der "local-with-networking"-Sandbox verweisen (auch umgekehrt ist dies nicht möglich).
• Sie können eine SWF-Datei daran hindern, diese Methode aufzurufen, indem Sie in der HTML-Seite, die den SWF-Inhalt enthält, den Parameter allowNetworking der Tags object und embed festlegen.

Weitere Informationen finden Sie in den folgenden Abschnitten:

• Das Kapitel Sicherheit im Handbuch Programmieren mit ActionScript 3.0 und die neusten Kommentare zu den LiveDocs.
• Das Flash Player 9-Whitepaper zum Thema Sicherheit

Parameter

Siehe auch

Lädt in einem ByteArray-Objekt gespeicherte Binärdaten.

Parameter

Siehe auch

Entfernt ein untergeordnetes Objekt dieses Loader-Objekts, das mit der Methode load() geladen wurde. Die property (Eigenschaft) des zugeordneten LoaderInfo-Objekts wird auf null zurückgesetzt. Das untergeordnete Objekt wird nicht unbedingt gelöscht, da andere Objekte möglicherweise Verweise darauf enthalten. Allerdings ist es dem Loader-Objekt nicht mehr untergeordnet.

Es ist ratsam, vor dem Entladen einer untergeordneten SWF-Datei alle Streams in deren Objekten, z. B. LocalConnection-, NetConnection-, NetStream- oder Sound-Objekte, ausdrücklich zu schließen. Andernfalls kann es passieren, dass Audiodaten in der untergeordneten SWF-Datei unaufhörlich abgespielt werden, obwohl die SWF-Datei selbst bereits entladen worden ist. Um Streams in der untergeordneten SWF-Datei zu schließen, fügen Sie dem untergeordneten Objekt, das auf das unload-Ereignis wartet, einen Ereignis-Listener hinzu. Wenn das übergeordnete Objekt die Loader.unload()-Methode aufruft, wird für das untergeordnete Objekt das unload-Ereignis ausgelöst. Im folgenden Code wird gezeigt, wie Sie dies realisieren können:

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Siehe auch

1. Es wird eine url-Eigenschaft erstellt, die den Speicherort und Namen der Grafikdatei angibt.
2. Im Konstruktor LoaderExample wird ein neues Loader-Objekt mit dem Namen loader erstellt, das dann an die configureListeners()-Methode übergeben wird. Dies ist in Schritt 3 beschrieben.
3. Der Konstruktor erstellt eine neue Instanz eines URLRequest-Objekts, request, mit Übergabe von url, damit der Dateiname und -speicherort bekannt sind.
4. Das request-Objekt wird im loader-Objekt an die load()-Methode übergeben, die das Bild in die Anzeigeliste lädt.
5. Im Loader wird ein clickHandler-Ereignis-Listener für das click-Ereignis registriert. Nach einem Klick mit der Maus wird das geladene Bild entfernt.
6. Die configureListeners()-Methode fügt mithilfe der folgenden Methoden sieben Ereignis-Listener hinzu:
   • Die completeHandler()-Methode wird ausgeführt, nachdem das Laden des Bilds beendet ist.
   • Die httpStatusHandler()-Methode wird ausgeführt, wenn das Bild nicht lokal geladen wird und nur wenn die Netzwerkanforderung verfügbar ist und der Flash Player diese erkennen kann.
   • Die initHandler()-Methode wird vor der completeHandler()-Methode und nach der progressHandler()-Methode ausgeführt. Das init-Ereignis ist in der Regel nützlicher, wenn SWF-Dateien geladen werden.
   • Die ioErrorHandler()-Methode wird ausgeführt, wenn die Bilddatei nicht verfügbar oder nicht zugänglich ist.
   • Die openHandler()-Methode wird ausgeführt, nachdem die Bilddatei zum ersten Mal geöffnet wurde.
   • Die progressHandler()-Methode wird ausgeführt, wenn das Laden der Bilddatei beginnt, und wird erneut ausgeführt, wenn das Laden der Bilddatei abgeschlossen ist.
   • Die unLoadHandler()-Methode wird ausgeführt, wenn das Bild entfernt wird, indem die unload()-Methode verwendet wird, wenn Benutzer auf das Bild klicken.

Beachten Sie folgende Bedingungen:

• Zur Ausführung dieses Beispiels müssen Sie eine Datei mit dem Namen "Image.gif" in dem Verzeichnis ablegen, in dem sich auch die kompilierte SWF-Datei befindet. Verwenden Sie ein Bild mit einem Bereich, der in die Abmessungen der SWF-Hauptdatei passt.
• Obwohl in diesem Beispiel alle verfügbaren Ereignisse des LoaderInfo-Objekts verwendet werden, ist in den meisten Situationen nur ein Teil davon erforderlich. Beim einfachen Laden einer Bilddatei reicht z. B. das complete-Ereignis (und ggf. das ioError-Ereignis) aus, sofern ein lokales Bild geladen wird.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}