Füllt einen Zeichenbereich mit einer Bitmap. Um den Bereich zu füllen, kann das Bild wiederholt oder mehrfach neben- und untereinander angeordnet werden. Die Füllung bleibt wirksam, bis Sie eine der Methoden beginFill(), beginBitmapFill() oder beginGradientFill() aufrufen. Durch das Aufrufen der clear()-Methode wird die Füllung gelöscht.

Flash Player rendert die Füllung erst, wenn die endFill()-Methode aufgerufen wird.

Parameter

  matrix = new flash.geom.Matrix(); 
  matrix.rotate(Math.PI/4);
  

Siehe auch

package {
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.geom.Matrix;

    public class Graphics_beginBitmapFillExample extends Sprite {
 
        private var url:String = "image1.jpg";
        private var loader:Loader = new Loader();

        public function Graphics_beginBitmapFillExample() {

            var request:URLRequest = new URLRequest(url);
            
            loader.load(request);
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, drawImage);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function drawImage(event:Event):void {

            var mySprite:Sprite = new Sprite();
            var myBitmap:BitmapData = new BitmapData(loader.width, loader.height, false);
  
            myBitmap.draw(loader, new Matrix());
            
            var matrix:Matrix = new Matrix();
            matrix.rotate(Math.PI/4);
            
            mySprite.graphics.beginBitmapFill(myBitmap, matrix, true);
            mySprite.graphics.drawRect(100, 50, 200, 90);
            mySprite.graphics.endFill();
            
            addChild(mySprite);
        }
 
         private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }   
}

Legt eine einfache einfarbige Füllung fest, die Flash Player für nachfolgende Aufrufe von anderen Graphics-Methoden für das Objekt verwendet (z. B. lineTo() oder drawCircle()). Die Füllung bleibt wirksam, bis Sie eine der Methoden beginFill(), beginBitmapFill() oder beginGradientFill() aufrufen. Durch das Aufrufen der clear()-Methode wird die Füllung gelöscht.

Flash Player rendert die Füllung erst, wenn die endFill()-Methode aufgerufen wird.

Parameter

Siehe auch

Legt eine Farbverlaufsfüllung fest, die Flash Player für nachfolgende Aufrufe von anderen Graphics-Methoden für das Objekt verwendet (z. B. lineTo() oder drawCircle()). Die Füllung bleibt wirksam, bis Sie eine der Methoden beginFill(), beginBitmapFill() oder beginGradientFill() aufrufen. Durch das Aufrufen der clear()-Methode wird die Füllung gelöscht.

Flash Player rendert die Füllung erst, wenn die endFill()-Methode aufgerufen wird.

Parameter

	type:String — Ein Wert aus der GradientType-Klasse, mit dem angegeben wird, welcher Farbverlaufstyp verwendet werden soll: GradientType.LINEAR oder GradientType.RADIAL.
	colors:Array — Ein Array mit hexadezimalen RGB-Farbwerten, die im Farbverlauf verwendet werden sollen (beispielsweise 0xFF0000 für Rot, 0x0000FF für Blau usw.). Sie können bis zu 15 Farben angeben. Definieren Sie auf jeden Fall für jede Farbe einen entsprechenden Wert in den Parametern "alphas" und "ratios".
	alphas:Array — Ein Array mit Alphawerten für die entsprechenden Farben im Array "colors". Gültig sind Werte von 0 bis 1. Ist der Wert kleiner als 0, ist der Standardwert 0. Ist der Wert größer als 1, ist der Standardwert 1.
	ratios:Array — Ein Array mit Farbverteilungsverhältnissen. Die zulässigen Werte liegen zwischen 0 und 255. Dieser Wert gibt den Breitenanteil an, in dem die Farbe mit 100 % gesampelt wird. Der Wert 0 repräsentiert die linke Position im Farbverlaufsfeld, und 255 repräsentiert die rechte Position im Farbverlaufsfeld. Hinweis: Dieser Wert repräsentiert Positionen im Farbverlaufsfeld, nicht im Koordinatenraum des endgültigen Farbverlaufs, der breiter oder schmaler als das Farbverlaufsfeld sein kann. Geben Sie für jeden Wert im Parameter colors einen Wert an. Die folgende Abbildung zeigt für einen linearen Verlauf mit den beiden Farben Blau und Grün die Farbplatzierung im Verlauf basierend auf den verschiedenen Werten im ratios-Array an: ratios Farbverlauf [0, 127] [0, 255] [127, 255] Die Werte im Array müssen sich sequenziell erhöhen. Beispiel: [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — Eine Transformationsmatrix, wie sie von der flash.geom.Matrix-Klasse definiert wird. Die flash.geom.Matrix-Klasse umfasst eine createGradientBox()-Methode, mit der Sie die Matrix zur Verwendung mit der beginGradientFill()-Methode auf einfache Weise festlegen können.
	spreadMethod:String (default = "pad") — Ein Wert aus der SpreadMethod-Klasse, der festlegt, welche Auftragstärke zu verwenden ist: SpreadMethod.PAD, SpreadMethod.REFLECT oder SpreadMethod.REPEAT. Angenommen, Sie haben einen einfachen linearen Farbverlauf zwischen zwei Farben: import flash.geom.* import flash.display.* var fillType:String = GradientType.LINEAR; var colors:Array = [0xFF0000, 0x0000FF]; var alphas:Array = [1, 1]; var ratios:Array = [0x00, 0xFF]; var matr:Matrix = new Matrix(); matr.createGradientBox(20, 20, 0, 0, 0); var spreadMethod:String = SpreadMethod.PAD; this.graphics.beginGradientFill(fillType, colors, alphas, ratios, matr, spreadMethod); this.graphics.drawRect(0,0,100,100); Dieses Beispiel verwendet SpreadMethod.PAD als Methode für die Auftragstärke, und der Farbverlauf sieht folgendermaßen aus: Mit der Auftragstärke SpreadMethod.REFLECT sieht die Farbverlaufsfüllung folgendermaßen aus: Mit der Auftragstärke SpreadMethod.REPEAT sieht die Farbverlaufsfüllung folgendermaßen aus:
	interpolationMethod:String (default = "rgb") — Ein Wert aus der InterpolationMethod-Klasse, der festlegt, welcher Wert zu verwenden ist: InterpolationMethod.linearRGB oder InterpolationMethod.RGB. Angenommen, Sie haben einen einfachen linearen Farbverlauf zwischen zwei Farben (wobei der Parameter spreadMethod auf SpreadMethod.REFLECT gesetzt ist). Die verschiedenen Interpolationsmethoden haben folgende Auswirkung auf die Darstellung des Farbverlaufs: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Eine Zahl, die die Position des Farbverlaufsbrennpunkts steuert. Der Wert 0 bedeutet, dass der Brennpunkt in der Mitte liegt. Der Wert 1 bedeutet, dass der Brennpunkt an einem Rand des Farbverlaufskreises liegt. Der Wert -1 bedeutet, dass der Brennpunkt am anderen Rand des Farbverlaufskreises liegt. Werte, die kleiner als -1 oder größer als 1 sind, werden auf -1 bzw. 1 gerundet. Im folgenden Beispiel ist focalPointRatio z. B. auf 0,75 gesetzt:

Siehe auch

Löscht die Grafiken, die für dieses Graphics-Objekt gezeichnet worden sind, und setzt die Einstellungen für den Füll- und Linienstil zurück.

Zeichnet eine Kurve im aktuellen Linienstil von der aktuellen Zeichnungsposition zu (anchorX, anchorY) unter Verwendung des durch (controlX, controlY) angegebenen Steuerpunkts. Die aktuelle Zeichnungsposition wird dann auf (anchorX, anchorY) gesetzt. Wenn der Movieclip, in dem Sie zeichnen, einen mit den Flash-Zeichenwerkzeugen erstellten Inhalt enthält, werden die Ergebnisse von Aufrufen der curveTo()-Methode unterhalb dieses Inhalts gezeichnet. Wenn Sie die curveTo()-Methode vor der moveTo()-Methode aufrufen, ist der Standardwert der aktuellen Zeichnungsposition (0, 0). Wenn ein Parameter fehlt, schlägt die Ausführung dieser Methode fehl, und die aktuelle Zeichnungsposition wird beibehalten.

Die gezeichnete Kurve ist eine quadratische Bézierkurve. Quadratische Bézierkurven bestehen aus zwei Ankerpunkten und einem Steuerpunkt. Die Kurve interpoliert die zwei Ankerpunkte und neigt sich zum Steuerpunkt hin.

Parameter

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    
    public class Graphics_curveToExample1 extends Sprite
    {
        public function Graphics_curveToExample1():void
        {
            var roundObject:Shape = new Shape();

            roundObject.graphics.beginFill(0x00FF00);
            roundObject.graphics.moveTo(250, 0);
            roundObject.graphics.curveTo(300, 0, 300, 50);
            roundObject.graphics.curveTo(300, 100, 250, 100);
            roundObject.graphics.curveTo(200, 100, 200, 50);
            roundObject.graphics.curveTo(200, 0, 250, 0);
            roundObject.graphics.endFill();
            
            this.addChild(roundObject);
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_curveToExample2 extends Sprite
    {
        public function Graphics_curveToExample2() {
            var newMoon:Shape = new Shape();
            
            newMoon.graphics.lineStyle(1, 0);
            newMoon.graphics.beginFill(0xFFFFFF);
            newMoon.graphics.moveTo(100, 100); 
            newMoon.graphics.curveTo(30, 150, 100, 200);    
            newMoon.graphics.curveTo(50, 150, 100, 100);
            graphics.endFill();
            
            this.addChild(newMoon);
        }
    }
}

Zeichnet einen Kreis. Sie müssen den Linienstil oder die Füllung oder beides setzen, bevor Sie die drawCircle()-Methode aufrufen. Dazu rufen Sie die Methode linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() oder beginBitmapFill() auf.

Parameter

Siehe auch

Zeichnet eine Ellipse. Sie müssen den Linienstil oder die Füllung oder beides setzen, bevor Sie die drawEllipse()-Methode aufrufen. Dazu rufen Sie die Methode linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() oder beginBitmapFill() auf.

Parameter

Siehe auch

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_drawEllipseExample extends Sprite
    {
        public static const SMALL:uint = 0;
        public static const MEDIUM:uint = 1;
        public static const LARGE:uint = 2;

        public function Graphics_drawEllipseExample()
        {
            drawEgg(SMALL, 0, 100);
            drawEgg(MEDIUM, 100, 60);
            drawEgg(LARGE, 250, 35);    
        }

        public function drawEgg(eggSize:uint, x:Number, y:Number):void  {
            
            var myEgg:Shape = new Shape();
            
            myEgg.graphics.beginFill(0xFFFFFF);
            myEgg.graphics.lineStyle(1);

            switch(eggSize) {
                case SMALL:
                    myEgg.graphics.drawEllipse(x, y, 60, 70);
                    break;
                case MEDIUM:
                    myEgg.graphics.drawEllipse(x, y, 120, 150);    
                    break;
                case LARGE:
                    myEgg.graphics.drawEllipse(x, y, 150, 200);
                    break;
                default:
                    trace ("Wrong size! There is no egg.");
                break;            
            }
            
            myEgg.graphics.endFill();
    
            this.addChild(myEgg);
        }
    }
}

Zeichnet ein Rechteck. Sie müssen den Linienstil oder die Füllung oder beides setzen, bevor Sie die drawRect()-Methode aufrufen. Dazu rufen Sie die Methode linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() oder beginBitmapFill() auf.

Parameter

Siehe auch

Zeichnet ein abgerundetes Rechteck. Sie müssen den Linienstil oder die Füllung oder beides setzen, bevor Sie die drawRoundRect()-Methode aufrufen. Dazu rufen Sie die Methode linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() oder beginBitmapFill() auf.

Parameter

Siehe auch

Versieht die Linien und Kurven, die seit dem letzten Aufruf der Methode beginFill(), beginGradientFill() oder beginBitmapFill() hinzugefügt wurden, mit einer Füllung. Flash verwendet die im vorherigen Aufruf der Methode beginFill(), beginGradientFill() oder beginBitmapFill() angegebene Füllung. Wenn die aktuelle Zeichnungsposition nicht der in einer moveTo()-Methode angegebenen vorherigen Position entspricht und eine Füllung definiert ist, wird der Pfad mit einer Linie geschlossen und dann gefüllt.

Siehe auch

Legt einen Farbverlauf für den Linienstil fest, den Flash Player für nachfolgende Aufrufe von anderen Graphics-Methoden für das Objekt verwendet (z. B. lineTo() oder drawCircle()). Der Linienstil bleibt wirksam, bis Sie die lineStyle()-Methode oder die lineGradientStyle()-Methode mit verschiedenen Parametern aufrufen. Sie können lineGradientStyle() beim Zeichnen eines Pfads aufrufen, um für unterschiedliche Liniensegmente in einem Pfad unterschiedliche Linientypen zu verwenden.

Rufen Sie lineStyle() vor lineGradientStyle() auf, um einen Strich zu ermöglichen. Andernfalls bleibt der Wert des Linienstils undefined.

Wenn Sie clear() aufrufen, setzen Sie den Linienstil wieder auf undefined zurück.

Parameter

	type:String — Ein Wert aus der GradientType-Klasse, mit dem angegeben wird, welcher Farbverlaufstyp verwendet werden soll, entweder "GradientType.LINEAR" oder "GradientType.RADIAL".
	colors:Array — Ein Array mit hexadezimalen RGB-Farbwerten, die im Farbverlauf verwendet werden sollen (beispielsweise 0xFF0000 für Rot, 0x0000FF für Blau usw.).
	alphas:Array — Ein Array mit Alphawerten für die entsprechenden Farben im Array colors. Gültig sind Werte von 0 bis 100. Ist der Wert kleiner als 0, verwendet Flash Player den Wert 0. Ist der Wert größer als 100, verwendet Flash Player den Wert 100.
	ratios:Array — Ein Array mit Farbverteilungsverhältnissen. Die zulässigen Werte liegen zwischen 0 und 255. Dieser Wert gibt den Breitenanteil an, in dem die Farbe mit 100 % gesampelt wird. Der Wert 0 repräsentiert die linke Position im Farbverlaufsfeld, und 255 repräsentiert die rechte Position im Farbverlaufsfeld. Dieser Wert repräsentiert Positionen im Farbverlaufsfeld, nicht im Koordinatenraum des endgültigen Farbverlaufs, der breiter oder schmaler als das Farbverlaufsfeld sein kann. Geben Sie für jeden Wert im Parameter colors einen Wert an. Die folgende Abbildung zeigt für einen linearen Verlauf mit den beiden Farben Rot und Blau die Farbplatzierung im Verlauf basierend auf den verschiedenen Werten im ratios-Array: ratios Farbverlauf [0, 127] [0, 255] [127, 255] Die Werte im Array müssen sich sequenziell erhöhen. Beispiel: [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — Eine Transformationsmatrix, wie sie von der flash.geom.Matrix-Klasse definiert wird. Die flash.geom.Matrix-Klasse umfasst eine createGradientBox()-Methode, mit der Sie die Matrix zur Verwendung mit der lineGradientStyle()-Methode auf einfache Weise festlegen können.
	spreadMethod:String (default = "pad") — Ein Wert aus der SpreadMethod-Klasse, der festlegt, welche Auftragstärke zu verwenden ist: SpreadMethod.PAD SpreadMethod.REFLECT SpreadMethod.REPEAT
	interpolationMethod:String (default = "rgb") — Ein Wert aus der InterpolationMethod-Klasse, der festlegt, welcher Wert zu verwenden ist. Angenommen, Sie haben einen einfachen linearen Farbverlauf zwischen zwei Farben (wobei der Parameter spreadMethod auf SpreadMethod.REFLECT gesetzt ist). Die verschiedenen Interpolationsmethoden haben folgende Auswirkung auf die Darstellung des Farbverlaufs: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Eine Zahl, die die Position des Farbverlaufsbrennpunkts steuert. Der Wert 0 bedeutet, dass der Brennpunkt in der Mitte liegt. Der Wert 1 bedeutet, dass der Brennpunkt an einem Rand des Farbverlaufskreises liegt. Der Wert -1 bedeutet, dass der Brennpunkt am anderen Rand des Farbverlaufskreises liegt. Werte, die kleiner als -1 oder größer als 1 sind, werden auf -1 bzw. 1 gerundet. Das folgende Bild zeigt einen Farbverlauf mit einem focalPointRatio von -0,75:

Siehe auch

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.geom.Matrix; 
    import flash.display.GradientType;
    
    public class Graphics_lineGradientStyleExample extends Sprite
    {
        public function Graphics_lineGradientStyleExample()
        {
            var myShape:Shape = new Shape();
            var gradientBoxMatrix:Matrix = new Matrix();
  
            gradientBoxMatrix.createGradientBox(200, 40, 0, 0, 0);  
            
            myShape.graphics.lineStyle(5);
  
            myShape.graphics.lineGradientStyle(GradientType.LINEAR, [0xFF0000,
            0x00FF00, 0x0000FF], [1, 1, 1], [0, 128, 255], gradientBoxMatrix);
            
            myShape.graphics.drawRect(0, 0, 200, 40);
            myShape.graphics.drawCircle(100, 120, 50);  
             
            this.addChild(myShape);
    
        }
    }
}

Legt einen Linienstil fest, den Flash für nachfolgende Aufrufe von anderen Graphics-Methoden für das Objekt verwendet (z. B. lineTo() oder drawCircle()). Der Linienstil bleibt wirksam, bis Sie die lineGradientStyle()-Methode oder die lineStyle()-Methode mit verschiedenen Parametern aufrufen. Sie können lineStyle() beim Zeichnen eines Pfads aufrufen, um für unterschiedliche Liniensegmente innerhalb des Pfads unterschiedliche Linienstile zu verwenden.

Hinweis: Wenn Sie die clear()-Methode aufrufen, wird der Linienstil wieder auf undefined gesetzt.

Parameter

Siehe auch

Zeichnet eine Linie im aktuellen Linienstil von der aktuellen Zeichnungsposition zu (x, y). Die aktuelle Zeichnungsposition wird dann auf (x, y) gesetzt. Wenn das Anzeigeobjekt, in dem Sie zeichnen, mit den Flash-Zeichenwerkzeugen erstellte Objekte enthält, werden die Ergebnisse von Aufrufen der lineTo()-Methode unter diesen Objekten gezeichnet. Wenn Sie lineTo() vor der moveTo()-Methode aufrufen, wird die aktuelle Zeichnungsposition standardmäßig auf (0, 0) gesetzt. Wenn ein Parameter fehlt, schlägt die Ausführung dieser Methode fehl, und die aktuelle Zeichnungsposition wird beibehalten.

Parameter

package {
    import flash.display.Sprite;
    import flash.display.LineScaleMode;
    import flash.display.CapsStyle;
    import flash.display.JointStyle;
    import flash.display.Shape;


    public class Graphics_lineToExample extends Sprite {

        public function Graphics_lineToExample() {

            var trapezoid:Shape = new Shape();    

            trapezoid.graphics.lineStyle(10, 0xFFD700, 1, false, LineScaleMode.VERTICAL,
                               CapsStyle.NONE, JointStyle.MITER, 10);

            trapezoid.graphics.moveTo(100, 100);
 
            trapezoid.graphics.lineTo(120, 50);
            trapezoid.graphics.lineTo(200, 50);
            trapezoid.graphics.lineTo(220, 100);
            trapezoid.graphics.lineTo(100, 100); 

            this.addChild(trapezoid);
        }
    }
}

Verschiebt die aktuelle Zeichnungsposition auf (x, y). Wenn ein Parameter fehlt, schlägt die Ausführung dieser Methode fehl, und die aktuelle Zeichnungsposition wird beibehalten.

Parameter

package {
    import flash.display.Sprite;
    import flash.display.CapsStyle;
    import flash.display.LineScaleMode;

    public class Graphics_moveToExample extends Sprite
    {
        public function Graphics_moveToExample() {
            
            graphics.lineStyle(3, 0x990000, 0.25, false, 
                            LineScaleMode.NONE, CapsStyle.SQUARE);

            graphics.moveTo(10, 20);
            graphics.lineTo(20, 20);
            graphics.moveTo(30, 20);
            graphics.lineTo(50, 20);
            graphics.moveTo(60, 20);
            graphics.lineTo(80, 20);
            graphics.moveTo(90, 20);
            graphics.lineTo(110, 20);            
            graphics.moveTo(120, 20);
            graphics.lineTo(130, 20);           
        }
    }
}

1. Deklarieren Sie eine size-Eigenschaft zur späteren Verwendung beim Bestimmen der Größe der einzelnen Formen.
2. Deklarieren Sie Eigenschaften, die die Hintergrundfarbe auf Orange, die Rahmenfarbe auf Dunkelgrau, die Rahmenbreite auf 0 Pixel und den Eckradius auf 9 Pixel setzen, und setzen Sie den Abstand zwischen Bühnenrand und anderen Objekten auf 5 Pixel.
3. Verwenden Sie die in den vorherigen Schritten deklarierten Eigenschaften zusammen mit den vorhandenen Methoden der Graphics-Klasse, um an den Koordinaten x = 0, y = 0 einen Kreis, ein abgerundetes Rechteck und ein Quadrat zu zeichnen.
4. Zeichnen Sie die einzelnen Formen am oberen Rand der Bühne neu, indem Sie an der Position x = 5, y = 5 beginnen und zwischen den Formen einen Abstand von jeweils 5 Pixel einhalten.

package {
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class GraphicsExample extends Sprite {
        private var size:uint         = 80;
        private var bgColor:uint      = 0xFFCC00;
        private var borderColor:uint  = 0x666666;
        private var borderSize:uint   = 0;
        private var cornerRadius:uint = 9;
        private var gutter:uint       = 5;

        public function GraphicsExample() {
            doDrawCircle();
            doDrawRoundRect();
            doDrawRect();
            refreshLayout();
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = gutter;
            lastChild.y = gutter;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = gutter;
                lastChild = child;
            }
        }

        private function doDrawCircle():void {
            var child:Shape = new Shape();
            var halfSize:uint = Math.round(size / 2);
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawCircle(halfSize, halfSize, halfSize);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRoundRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRoundRect(0, 0, size, size, cornerRadius);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRect(0, 0, size, size);
            child.graphics.endFill();
            addChild(child);
        }
    }
}