Das BitmapData-Objekt, auf das verwiesen wird.

Steuert, ob das Bitmap-Objekt am nächsten Pixel ausgerichtet wird. Die PixelSnapping-Klasse umfasst die folgenden zulässigen Werte:

• PixelSnapping.NEVER: Keine Ausrichtung an Pixeln.
• PixelSnapping.ALWAYS: Die Grafik wird immer am nächsten Pixel ausgerichtet, und zwar unabhängig von einer etwaigen Transformation.
• PixelSnapping.AUTO: Das Bild wird am nächsten Pixel ausgerichtet, wenn es ohne Drehung oder Neigung gezeichnet wird, und mit einem Skalierungsfaktor von 99,9 % bis 100,1 % gezeichnet. Sind diese Bedingungen erfüllt, wird die Bitmap bei einhundertprozentiger Skalierung gezeichnet und am nächstgelegenen Pixel ausgerichtet. Intern ermöglicht es dieser Wert, dass die Grafik so schnell wie möglich gezeichnet wird, indem der Vektorrenderer verwendet wird.

Steuert, ob die Bitmap beim Skalieren geglättet wird. Wenn true angegeben ist, wird die Bitmap beim Skalieren geglättet. Wenn false angegeben ist, wird die Bitmap beim Skalieren nicht geglättet.

Initialisiert ein Bitmap-Objekt, das auf das angegebene BitmapData-Objekt verweisen soll.

	bitmapData:BitmapData (default = null) — Das BitmapData-Objekt, auf das verwiesen wird.
	pixelSnapping:String (default = "auto") — Gibt an, ob das Bitmap-Objekt am nächsten Pixel ausgerichtet wird.
	smoothing:Boolean (default = false) — Gibt an, ob die Bitmap beim Skalieren geglättet wird. Im folgenden Beispiel wird dieselbe Bitmap um den Faktor 3 skaliert angezeigt, wobei smoothing auf false (links) und true (rechts) gesetzt ist:

1. Es wird eine url-Eigenschaft erstellt, die den Speicherort und Namen der Bilddatei angibt.
2. Der Klassenkonstruktor ruft die configureAssets()-Methode auf, die wiederum die completeHandler()-Methode aufruft.
3. configureAssets() erstellt ein Loader-Objekt, das dann einen Ereignis-Listener instanziiert. Der Ereignis-Listener wird ausgelöst, wenn die completeHandler()-Methode die Bildbearbeitung abgeschlossen hat.
4. Als Nächstes erstellt die buildChild()-Methode eine neue Instanz eines URLRequest-Objekts, request, mit Übergabe von url, damit der Dateiname und -speicherort bekannt sind.
5. Das request-Objekt wird an die loader.load()-Methode übergeben, die das Bild über ein Anzeigeobjekt in den Speicher lädt.
6. Das Bild wird in die Anzeigeliste eingefügt, die das Bild sofort auf dem Bildschirm bei den Koordinaten x = 0, y = 0 anzeigt.
7. Die completeHandler()-Methode führt dann Folgendes aus:
   1. Sie erstellt ein zweites Loader-Objekt und ein Bitmap-Objekt, das über das Loader-Objekt initialisiert wird.
   2. Sie erstellt ein zweites Bitmap-Objekt, duplicate, das wiederum die duplicateImage()-Methode aufruft, die ein Duplikat des Originalbilds erzeugt.
   3. Sie erstellt ein BitmapData-Objekt, das dem BitmapData-Objekt des duplicate-Objekts zugeordnet ist.
   4. Sie erstellt ein neues Rechteckobjekt, das mit denselben Werten für Koordinaten, Breite und Höhe wie das Originalbild initialisiert wird.
   5. Sie erstellt ein neues Point-Objekt mit der Standardeinstellung x = 0, y = 0.
   6. Sie erstellt die folgenden Variablen:
      • operation: Wendet die neue Farbe an, wenn der Schwellenwert größer oder gleich dem Original ist.
      • threshold: Der Wert, mit dem jedes Pixel verglichen wird, wird auf Hellgrau mit einem Alphawert von 0xCC gesetzt.
      • color: Die Farbe, auf die die Pixel eingestellt werden, die den Schwellentest bestehen. In diesem Fall ist dies reines Gelb.
      • mask: Die genau entgegengesetzte Farbe (durchsichtiges Blau).
      • copySource: Auf "false" gesetzt. Dies zeigt an, dass die Pixelwerte nicht kopiert werden, wenn der Schwellenwert den Test nicht besteht. Dieser Wert hat keine Bedeutung, da das Bild dupliziert wird und nur Pixel geändert werden, die den Schwellenwerttest bestehen.
   7. Ruft mithilfe der vorherigen Variablen die threshold()-Methode auf. Es ergibt sich die folgende Schwellenwertgleichung: if (current pixel Value & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) then set pixel to 0xFFFFFF00.

Hinweise:

• Für die Kompilierung der SWF-Datei müssen Sie die Option "Sicherheit bei lokaler Wiedergabe" auf "Nur auf lokale Dateien zugreifen" einstellen.
• Zur Ausführung dieses Beispiels müssen Sie eine Datei mit dem Namen "Image.gif" in dem Verzeichnis ablegen, in dem sich die SWF-Datei befindet.
• Es wird empfohlen, ein Bild mit einer Breite von bis zu 80 Pixel zu verwenden.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}