Ruft ein Objekt ab, das die mit einer Komponenten verknüpften Daten darstellt, oder legt dieses fest. Wenn dieser Wert festgelegt wurde, werden die Komponentendaten gespeichert; die Komponente, die diese enthält, wird entwertet. Die entwertete Komponente wird automatisch neu erstellt.

Die Data-Eigenschaft stellt ein Objekt dar, das das Element im DataProvider enthält, das die Zelle repräsentiert. In der Regel enthält die Data-Eigenschaft Standardwerte, die je nach Komponententyp variieren. Die Daten in der List- oder ComboBox-Komponente von CellRenderer enthalten eine Beschriftung, ein Symbol und Dateneigenschaften; eine TileList: eine Beschriftung oder eine Quelleigenschaft; eine DataGrid-Zelle enthält Werte für jede Spalte. Die Data-Eigenschaft kann auch benutzerspezifische Daten enthalten, die sich auf eine bestimmte Zelle beziehen. Benutzer können CellRenderer um eine Komponente erweitern, um unterschiedliche Dateneigenschaften bei der Wiedergabe der Zelle anzuwenden.

Darüber hinaus können Sie die Elemente labelField, labelFunction, iconField, iconFunction, sourceField und sourceFunction verwenden, um festzulegen, welche Eigenschaften zum Erstellen von Beschriftungen, Symbolen und Quellen verwendet werden sollen.

Ruft die Listeneigenschaften ab, die auf die Zelle angewendet werden, z. B. die Werte index und selected, oder legt diese fest. Diese Listeneigenschaften werden automatisch aktualisiert, nachdem die Zelle entwertet wurde.

Gibt an, ob die Zelle in den vom Eigentümer ausgewählten Indizes inbegriffen ist. Der Wert true gibt an, dass die Zelle in den ausgewählten Indizes inbegriffen ist, der Wert false, dass sie nicht inbegriffen ist.

Beachten Sie, dass dieser Wert in der DataGrid-Komponente nicht geändert werden kann. Die DataGridCellEditor-Klasse implementiert die ICellRenderer-Oberfläche, die angibt, dass dieser Wert definiert werden muss.

Der Standardwert lautet false.

Siehe auch

Erstellt eine neue DataGridCellEditor-Instanz.

Ruft die Standardstilmatrix der aktuellen Komponente ab. Die Stilmatrix enthält den für die Komponente geeigneten Typ und hängt von dem Stil ab, der von der Komponente verwendet wird. Der Stil disabledTextFormat enthält beispielsweise den Wert null oder ein TextFormat-Objekt. Sie können diese Stile verwenden und setStyle() für die aktuelle Komponente aufrufen. Mit folgendem Code wird der Standardstil disabledTextFormat der angegebenen Komponente überschrieben:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Legt für die aktuelle Zelle einen bestimmten Mausstatus fest. Diese Methode ist erforderlich, damit der Mausstatus von DataGrid für eine ganze Zeile festgelegt werden kann, wenn der Benutzer mit einer einzelnen Zelle interagiert.

Parameter

Gehen Sie wie folgt vor, um das Beispiel auszuführen:

1. Fügen Sie die DataGrid-Komponente zur Bibliothek hinzu.
2. Speichern Sie diesen Code unter DataGridCellEditorExample.as im gleichen Verzeichnis wie die FLA-Datei.
3. Legen Sie in der FLA-Datei für die Dokumentklasse den Wert "DataGridCellEditorExample" fest.

package
{
    import fl.controls.DataGrid;
    import fl.controls.dataGridClasses.DataGridCellEditor;
    import fl.data.DataProvider;
    import fl.managers.StyleManager;
    import flash.display.Sprite;
    import flash.text.TextFormat;
    
    public class DataGridCellEditorExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridCellEditorExample() {
            createDataGrid();
            styleDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;            
        }
        private function styleDataGrid():void {
            var georgiaFormat:TextFormat = getCustomFormat();
            georgiaFormat.font = "Georgia";
            var verdanaFormat:TextFormat = getCustomFormat();
            verdanaFormat.font = "Verdana";
            var timesFormat:TextFormat = getCustomFormat();
            timesFormat.font = "Times New Roman";
            
            var firstCellEditor:DataGridCellEditor = getCustomEditor();
            firstCellEditor.setStyle("textFormat",timesFormat);
            var secondCellEditor:DataGridCellEditor = getCustomEditor();
            secondCellEditor.setStyle("textFormat",verdanaFormat);
            var thirdCellEditor:DataGridCellEditor = getCustomEditor();;
            thirdCellEditor.setStyle("textFormat",georgiaFormat);
            
            dg.columns[0].itemEditor = firstCellEditor;
            dg.columns[1].itemEditor = secondCellEditor;
            dg.columns[2].itemEditor = thirdCellEditor;    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
        private function getCustomFormat():TextFormat {
            var tf:TextFormat = new TextFormat();
            tf.bold = true;
            tf.color = 0xFFFFFF;
            return tf;
        }
        private function getCustomEditor():DataGridCellEditor {
            var dgce:DataGridCellEditor = new DataGridCellEditor();
            dgce.textField.background = true;
            dgce.textField.backgroundColor = 0xFF0000;
            dgce.maxChars = 2;
            dgce.restrict = "1234567890";
            return dgce
        }
    }
}