fl.controls.RadioButtonGroup (ActionScript 3.0)

	Eigenschaft	Definiert von
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		name : String [read-only] Ruft den Namen des Optionsfelds ab.	RadioButtonGroup
		numRadioButtons : int [read-only] Ruft die Anzahl von Optionsfeldern in dieser Optionsfeldgruppe ab.	RadioButtonGroup
		prototype : Object [static] Ein Verweis auf das Prototypobjekt einer Klasse oder eines Funktionsobjekts.	Object
		selectedData : Object Ruft die Eigenschaft "value" des ausgewählten Optionsfelds ab oder legt diese fest.	RadioButtonGroup
		selection : RadioButton Ruft einen Verweis auf das aktuell in der Optionsfeldgruppe ausgewählte Optionsfeld ab oder legt diesen fest.	RadioButtonGroup

	Methode	Definiert von
		RadioButtonGroup(name:String) Erstellt eine neue RadioButtonGroup-Instanz.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registriert ein Ereignis-Listener-Objekt bei einem EventDispatcher-Objekt, sodass der Listener über ein Ereignis benachrichtigt wird.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Fügt ein Optionsfeld zum internen Optionsfeld-Array hinzu, mit dem die Indizierung der Optionsfeldgruppe vorgenommen wird, damit in einer Gruppe nur ein Optionsfeld ausgewählt werden kann.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Sendet ein Ereignis in den Ereignisablauf.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [static] Ruft einen Verweis auf die aktuelle Optionsfeldgruppe ab.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Ruft die RadioButton-Komponente an der angegebenen Indexposition ab.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Gibt die Indexposition der angegebenen RadioButton-Instanz zurück.	RadioButtonGroup
		hasEventListener(type:String):Boolean Überprüft, ob das EventDispatcher-Objekt Listener für einen bestimmten Ereignistyp registriert hat.	EventDispatcher
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Entfernt einen Listener aus dem EventDispatcher-Objekt.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Entfernt die RadioButton-Instanz aus der internen Optionsfeldliste.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object
		willTrigger(type:String):Boolean Überprüft, ob bei diesem EventDispatcher-Objekt oder bei einem seiner vorangegangenen Elementen ein Ereignis-Listener für einen bestimmten Ereignistyp registriert ist.	EventDispatcher

Übersicht	Definiert von
activate	Wird ausgelöst, wenn Flash Player den Betriebssystemfokus erhält und aktiv wird.	EventDispatcher
change	Wird ausgelöst, wenn sich die in einer Gruppe ausgewählte RadioButton-Instanz ändert.	RadioButtonGroup
click	Wird ausgelöst, wenn auf eine RadioButton-Instanz geklickt wird.	RadioButtonGroup
deactivate	Wird ausgelöst, wenn Flash Player den Betriebssystemfokus verliert und inaktiv wird.	EventDispatcher

Eigenschaftsdetail

name	Eigenschaft

name:String [read-only]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Ruft den Namen des Optionsfelds ab.

Der Standardwert lautet "RadioButtonGroup".

Implementierung
public function get name():String

numRadioButtons

Eigenschaft

numRadioButtons:int [read-only]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Ruft die Anzahl von Optionsfeldern in dieser Optionsfeldgruppe ab.

Der Standardwert lautet 0.

Implementierung
public function get numRadioButtons():int

selectedData

Eigenschaft

selectedData:Object [read-write]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Ruft die Eigenschaft value des ausgewählten Optionsfelds ab oder legt diese fest. Falls kein Optionsfeld ausgewählt ist, gilt für diese Eigenschaft der Wert null.

Implementierung
public function get selectedData():Object
public function set selectedData(value:Object):void

Beispiel

Im folgenden Beispiel wird eine neue RadioButtonGroup-Instanz erstellt und deren change-Ereignisse überwacht:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

Eigenschaft

selection:RadioButton [read-write]

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Ruft einen Verweis auf das aktuell in der Optionsfeldgruppe ausgewählte Optionsfeld ab oder legt diesen fest.

Implementierung
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Beispiel

Im folgenden Beispiel wird eine neue Optionsfeldgruppe mit zwei Optionsfeldern erstellt. Bei einer Änderung am aktuell ausgewählten Optionsfeld werden Bezeichnung und Wert des Optionsfelds nachverfolgt:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Konstruktordetail

RadioButtonGroup

()

Konstruktor

public function RadioButtonGroup(name:String)

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Erstellt eine neue RadioButtonGroup-Instanz. Dies geschieht in der Regel automatisch, wenn ein Optionsfeld instanziiert wird.

Parameter

name:String — Der Name der Optionsfeldgruppe.

Methodendetail

addRadioButton

()

Methode

public function addRadioButton(radioButton:RadioButton):void

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Fügt ein Optionsfeld zum internen Optionsfeld-Array hinzu, mit dem die Indizierung der Optionsfeldgruppe vorgenommen wird, damit in einer Gruppe nur ein Optionsfeld ausgewählt werden kann. Diese Methode wird automatisch von Optionsfeldern verwendet, kann aber auch manuell verwendet werden, um ein bestimmtes Optionsfeld explizit zu einer Gruppe hinzuzufügen.

Parameter

radioButton:RadioButton — Die RadioButton-Instanz, die zur aktuellen Optionsfeldgruppe hinzugefügt werden soll.

getGroup

()

Methode

public static function getGroup(name:String):RadioButtonGroup

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Ruft einen Verweis auf die aktuelle Optionsfeldgruppe ab.

Parameter

name:String — Der Name der Gruppe, für die eine Referenz abgerufen werden soll.

Rückgabewerte

RadioButtonGroup — Eine Referenz auf die angegebene RadioButtonGroup-Instanz.

Beispiel

Im folgenden Beispiel wird gezeigt, wie Sie bestimmen, welches Optionsfeld in einer Gruppe ausgewählt ist:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

Methode

public function getRadioButtonAt(index:int):RadioButton

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Ruft die RadioButton-Komponente an der angegebenen Indexposition ab.

Parameter

index:int — Die Indexposition der RadioButton-Komponente in der RadioButtonGroup-Komponente, wobei die Indexposition der ersten Komponente 0 ist.

Rückgabewerte

RadioButton — Die angegebene RadioButton-Komponente.

Auslöser

RangeError — Der angegebene Index ist kleiner als 0 oder größer gleich der Länge des Datenproviders.

getRadioButtonIndex

()

Methode

public function getRadioButtonIndex(radioButton:RadioButton):int

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Gibt die Indexposition der angegebenen RadioButton-Instanz zurück.

Parameter

radioButton:RadioButton — Die in der RadioButton-Gruppe zu suchende RadioButton-Instanz.

Rückgabewerte

int — Die Indexposition der angegebenen RadioButton-Komponente oder -1, wenn die angegebene RadioButton-Komponente nicht gefunden wurde.

removeRadioButton

()

Methode

public function removeRadioButton(radioButton:RadioButton):void

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Entfernt die RadioButton-Instanz aus der internen Optionsfeldliste.

Parameter

radioButton:RadioButton — Zu entfernende RadioButton-Instanz.

Ereignisdetail

change

Ereignis

Ereignisobjekttyp: flash.events.Event
Event.type property = flash.events.Event.CHANGE

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Wird ausgelöst, wenn sich die in einer Gruppe ausgewählte RadioButton-Instanz ändert.

Definiert den Wert der Eigenschaft type eines change-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`true`
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`target`	Das Objekt, dessen Wert geändert wurde. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Beispiel

Im folgenden Beispiel werden drei Optionsfelder erstellt und ein Ereignis-Listener für change-Ereignisse der Optionsfeldgruppen hinzugefügt:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Ereignis

Ereignisobjekttyp: flash.events.MouseEvent
MouseEvent.type property = flash.events.MouseEvent.CLICK

Sprachversion :

ActionScript 3.0

Player-Version :

Flash Player 9.0.28.0

Wird ausgelöst, wenn auf eine RadioButton-Instanz geklickt wird.

Definiert den Wert der Eigenschaft type eines click-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Eigenschaft	Wert
`bubbles`	`true`
`buttonDown`	`true`, wenn die primäre Maustaste gedrückt wird; andernfalls `false`.
`cancelable`	`false`. Es gibt kein Standardverhalten, das abgebrochen werden kann.
`ctrlKey`	`true`, wenn die Strg-Taste aktiv ist; `false`, wenn sie nicht aktiv ist.
`currentTarget`	Das Objekt, welches das Ereignisobjekt aktiv mit einem Ereignis-Listener verarbeitet.
`localX`	Die horizontale Koordinate, an der das Ereignis aufgetreten ist, das in Relation zum umgebenden Sprite-Objekt steht.
`localY`	Die vertikale Koordinate, an der das Ereignis aufgetreten ist, das in Relation zum umgebenden Sprite-Objekt steht.
`shiftKey`	`true`, wenn die Umschalttaste aktiv ist; `false`, wenn sie nicht aktiv ist.
`stageX`	Die horizontale Koordinate, an der das Ereignis aufgetreten ist, in globalen Bühnenkoordinaten.
`stageY`	Die vertikale Koordinate, an der das Ereignis aufgetreten ist, in globalen Bühnenkoordinaten.
`target`	Die InteractiveObject-Instanz unter dem Zeigegerät. Das unter `target` angegebene Ziel ist nicht immer das Objekt in der Anzeigeliste, in der der Ereignis-Listener registriert wurde. Mit der Eigenschaft `currentTarget` können Sie auf das Objekt in der Anzeigeliste zugreifen, das das Ereignis derzeit verarbeitet.

Beispiele Verwendung von Beispielen

RadioButtonGroupExample.as

In diesem Beispiel wird gezeigt, wie Sie viele RadioButton-Instanzen in mehreren Gruppen verwalten können.

Gehen Sie wie folgt vor, um das Beispiel auszuführen:

Fügen Sie die RadioButton- und Label-Komponenten zur Bibliothek hinzu.
Speichern Sie diesen Code unter "RadioButtonGroupExample.as" im gleichen Verzeichnis wie die FLA-Datei.
Geben Sie "RadioButtonGroupExample" als Dokumentklasse in der FLA-Datei an.

package
{
    import fl.controls.Label;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.text.TextFieldAutoSize;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Aktuelle Seite: http://livedocs.adobe.com/flash/9.0_de/ActionScriptLangRefV3/fl/controls/RadioButtonGroup.html

Komponenten-Referenzhandbuch für ActionScript 3.0		Alle Pakete \| Alle Klassen \| Sprachelemente \| Stichwortverzeichnis \| Anhänge \| Konventionen \| Frames Keine Frames
RadioButtonGroup	Eigenschaften \| Methoden \| Ereignisse \| Beispiele

Paket	fl.controls
Klasse	public class RadioButtonGroup
Vererbung	RadioButtonGroup EventDispatcher Object