ignoreComments:Boolean [read-write]
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Legt fest, ob XML-Kommentare ignoriert werden, wenn XML-Objekte die XML-Quelldaten analysieren. Standardmäßig werden Kommentare ignoriert (true). Um XML-Kommentare einzubeziehen, rufen Sie false auf. Die Eigenschaft ignoreComments wird nur während der XML-Analyse verwendet, nicht etwa beim Aufruf von Methoden, wie myXMLObject.child(*).toXMLString(). Enthält das XML-Quelldokument Kommentarknoten, werden sie während der XML-Analyse durch den Parser beibehalten oder verworfen.
Implementierung
public static function get ignoreComments():Boolean
public function set ignoreComments(value:Boolean):void
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, welche Wirkung es hat, wenn Sie
XML.ignoreComments auf
false und
true setzen:
XML.ignoreComments = false;
var xml1:XML =
<foo>
<!-- comment -->
</foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>
XML.ignoreComments = true;
var xml2:XML =
<foo>
<!-- example -->
</foo>;
trace(xml2.toXMLString()); // <foo/>
ignoreProcessingInstructions:Boolean [read-write]
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Legt fest, ob XML-Verarbeitungsanweisungen ignoriert werden, wenn XML-Objekte die XML-Quelldaten analysieren. Standardmäßig werden Verarbeitungsanweisungen ignoriert (true). Um XML-Verarbeitungsanweisungen einzubeziehen, rufen Sie false auf. Die Eigenschaft ignoreProcessingInstructions wird nur während der XML-Analyse verwendet, nicht etwa beim Aufruf von Methoden wie myXMLObject.child(*).toXMLString(). Enthält das XML-Quelldokument Verarbeitungsanweisungen, werden sie während der XML-Analyse durch den Parser beibehalten oder verworfen.
Implementierung
public static function get ignoreProcessingInstructions():Boolean
public function set ignoreProcessingInstructions(value:Boolean):void
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, welche Wirkung es hat, wenn Sie
XML.ignoreProcessingInstructions auf
false und
true setzen:
XML.ignoreProcessingInstructions = false;
var xml1:XML =
<foo>
<?exampleInstruction ?>
</foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>
XML.ignoreProcessingInstructions = true;
var xml2:XML =
<foo>
<?exampleInstruction ?>
</foo>;
trace(xml2.toXMLString()); // <foo/>
ignoreWhitespace:Boolean [read-write]
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Legt fest, ob während der Analyse durch den Parser Leerraumzeichen am Anfang und Ende von Textknoten ignoriert werden. Standardmäßig wird Leerraum ignoriert (true). Besteht ein Textknoten zu 100 % aus Leerraum und die Eigenschaft ignoreWhitespace ist auf true gesetzt, wird der Knoten nicht erstellt. Um Leerraum in einem Textknoten anzuzeigen, setzen Sie die Eigenschaft ignoreWhitespace auf false.
Implementierung
public static function get ignoreWhitespace():Boolean
public function set ignoreWhitespace(value:Boolean):void
Beispiel
Im folgenden Beispiel wird veranschaulicht, welche Wirkung es hat, wenn Sie
XML.ignoreWhitespace auf
false und
true setzen:
XML.ignoreWhitespace = false;
var xml1:XML = <foo> </foo>;
trace(xml1.children().length()); // 1
XML.ignoreWhitespace = true;
var xml2:XML = <foo> </foo>;
trace(xml2.children().length()); // 0
prettyIndent:int [read-write]
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Legt die Breite der Einrückung fest, die von den Methoden toString() und toXMLString() angewendet wird, wenn die Eigenschaft XML.prettyPrinting auf true gesetzt ist. Die Einrückung wird mit dem Leerzeichen angewendet und nicht etwa mit dem Tabulatorzeichen. Der Standardwert ist 2.
Implementierung
public static function get prettyIndent():int
public function set prettyIndent(value:int):void
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, welche Wirkung es hat, wenn Sie die statische Eigenschaft
XML.prettyIndent festlegen:
var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());
XML.prettyIndent = 1;
trace(xml.toXMLString());
XML.prettyIndent = 2;
trace(xml.toXMLString());
prettyPrinting:Boolean [read-write]
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Legt fest, ob die Methoden toString() und toXMLString() Leerraumzeichen zwischen einigen Tags normalisieren. Der Standardwert ist true.
Implementierung
public static function get prettyPrinting():Boolean
public function set prettyPrinting(value:Boolean):void
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, welche Wirkung es hat, wenn Sie die statische Eigenschaft
XML.prettyPrinting festlegen:
var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());
XML.prettyPrinting = true;
trace(xml.toXMLString());
public function XML(value:Object)
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Erstellt ein neues XML-Objekt. Vor dem Aufruf einer Methode der XML-Klasse muss der Konstruktor zum Erstellen eines XML-Objekts verwendet werden.
Verwenden Sie die Methode toXMLString(), um das XML-Objekt als String zurückzugeben, und zwar unabhängig davon, ob das XML-Objekt einen einfachen oder komplexen Inhalt besitzt.
Parameter
| value:Object — Jedes Objekt, das sich mithilfe von XML(), einer Funktion oberster Ebene, in ein XMLList-Objekt konvertieren lässt.
|
Siehe auch
AS3 function addNamespace(ns:Object):XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Erweitert den Satz an gültigen Namespaces für das XML-Objekt um einen Namespace. Existiert der Namespace bereits im Namespace-Gültigkeitsbereich für das XML-Objekt (mit dem Präfix aus dem angegebenen Parameter), so wird das Präfix des bereits vorhandenen Namespaces auf undefined gesetzt. Handelt es sich beim Eingabeparameter um ein Namespace-Objekt, wird es direkt verwendet. Handelt es sich um ein QName-Objekt, wird der URI des Eingabeparameters verwendet, um einen neuen Namespace zu erstellen; andernfalls wird es in einen String konvertiert und der Namespace wird aus diesem String erstellt.
Parameter
| ns:Object — Der Namespace, der zum XML-Objekt hinzufügt werden soll.
|
Rückgabewerte
| XML — Das neue XML-Objekt mit dem zusätzlichen Namespace.
|
Siehe auch
Beispiel
In diesem Beispiel wird ein Namespace, der in einem XML-Objekt definiert wurde auf ein anderes XML-Objekt angewendet:
var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();
var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>
AS3 function appendChild(child:Object):XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Hängt das angegebene untergeordnete Objekt ans Ende der Eigenschaften des XML-Objekts an. Die Methode appendChild() akzeptiert ein XML-Objekt, ein XMLList-Objekt oder einen anderen Datentyp, der dann in einen String konvertiert wird.
Verwenden Sie den Operator delete, um den XML-Knoten zu entfernen.
Parameter
| child:Object — Das anzuhängende XML-Objekt.
|
Rückgabewerte
| XML — Das resultierende XML-Objekt.
|
Siehe auch
Beispiel
In diesem Beispiel wird am Ende der untergeordneten Liste eines XML-Objekts ein neues Element angehängt:
var xml:XML =
<body>
<p>hello</p>
</body>;
xml.appendChild(<p>world</p>);
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>
AS3 function attribute(attributeName:*):XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt den XML-Wert des Attributs zurück, das den mit dem Parameter attributeName übereinstimmenden Namen besitzt. Attribute befinden sich innerhalb von XML-Elementen. Im folgenden Beispiel hat das Element ein Attribut mit dem Namen "gender" und dem Wert "boy": <first gender="boy">John</first>.
Der Parameter attributeName kann einen beliebigen Datentyp besitzen; allerdings ist String der am häufigsten verwendete Datentyp. Wenn Sie ein beliebiges Objekt übergeben, das kein QName-Objekt ist, verwendet der Parameter attributeName die Methode toString(), um den Parameter in einen String zu konvertieren.
Wenn Sie eine qualifizierte Namensreferenz benötigen, können Sie ein QName-Objekt übergeben. Ein QName-Objekt definiert einen Namespace und den lokalen Namen, den Sie verwenden können, um den qualifizierten Namen eines Attributs zu definieren. Daher ist es nicht dasselbe, ob Sie attribute(qname) oder attribute(qname.toString()) aufrufen.
Parameter
| attributeName:* — Der Name des Attributs.
|
Rückgabewerte
| XMLList — Ein XMLList-Objekt oder ein leeres XMLList-Objekt. Gibt ein leeres XMLList-Objekt zurück, wenn ein Attributwert nicht definiert worden ist.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird ein QName-Objekt in eine
attribute()-Methode übergeben. Die Eigenschaft
localName hat den Wert
attr, und die Eigenschaft
namespace hat den Wert
ns.
var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />
var qn:QName = new QName("http://uri", "attr");
trace(xml.attribute(qn)); // 7 Um ein Attribut mit einem Namen zurückzugeben, der einem in ActionScript reservierten Wort entspricht, verwenden Sie die
attribute()-Methode anstelle des (@)-Operators, der als Attributbezeichner dient (siehe folgendes Beispiel):
var xml:XML = <example class="first" />
trace(xml.attribute("class"));
AS3 function attributes():XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt eine Liste von Attributwerten für ein bestimmtes XML-Objekt zurück. Verwenden Sie die Methode name() mit der Methode attributes(), um den Namen eines Attributs zurückzugeben. Verwenden Sie @*, um die Namen aller Attribute zurückzugeben.
Rückgabewerte
| XMLList — Die Liste der Attributwerte.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird der Name des Attributs zurückgegeben:
var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color
In diesem Beispiel werden die Namen aller Attribute zurückzugeben:
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;
trace(attNamesList is XMLList); // true
trace(attNamesList.length()); // 2
for (var i:int = 0; i < attNamesList.length(); i++)
{
trace(typeof (attNamesList[i])); // xml
trace(attNamesList[i].nodeKind()); // attribute
trace(attNamesList[i].name()); // id and color
}
AS3 function child(propertyName:Object):XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Listet die untergeordneten Knoten eines XML-Objekts auf. Bei einem untergeordneter XML-Knoten kann es sich um ein XML-Element, einen Textknoten, einen Kommentar oder eine Verarbeitungsanweisung handeln.
Verwenden Sie den Parameter propertyName, um den Inhalt eines bestimmten untergeordneten XML-Knotens aufzulisten. Um beispielsweise den Inhalt des untergeordneten Knotens mit dem Namen <first> auszugeben, verwenden Sie child.name("first"). Sie erzeugen dasselbe Ergebnis, wenn Sie die Indexnummer des untergeordneten Knotens verwenden. Die Indexnummer identifiziert die Position des untergeordneten Knotens in der Liste weiterer untergeordneter XML-Knoten. name.child(0) beispielsweise gibt den ersten untergeordneten Knoten in einer Liste zurück.
Verwenden Sie ein Sternchen (*), um alle untergeordneten Knoten eines XML-Dokuments auszugeben. Zum Beispiel doc.child("*").
Verwenden Sie die Methode length() mit dem Sternparameter (*) der Methode child(), um die Gesamtanzahl der untergeordneten Knoten auszugeben. Zum Beispiel numChildren = doc.child("*").length().
Parameter
| propertyName:Object — Der Elementname oder die Ganzzahl des untergeordneten XML-Elements.
|
Rückgabewerte
| XMLList — Ein XMLList-Objekt mit untergeordneten Knoten, die dem input-Parameter entsprechen.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, wie Sie mithilfe der
child()-Methode untergeordnete Elemente mit einem angegebenen Namen identifizieren:
var xml:XML =
<foo>
<bar>text1</bar>
<bar>text2</bar>
</foo>;
trace(xml.child("bar").length()); // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>
AS3 function childIndex():int
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Identifiziert die nullindizierte Position dieses XML-Objekts innerhalb des Kontexts des übergeordneten Objekts.
Rückgabewerte
| int — Die Position des Objekts. Gibt -1 zurück sowie alle positiven Ganzzahlen.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, wie Sie die
childIndex()-Methode verwenden:
var xml:XML =
<foo>
<bar />
text
<bob />
</foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2
AS3 function children():XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Listet die untergeordneten Knoten des XML-Objekts auf, und zwar in der Reihenfolge, in der sie erscheinen. Bei einem untergeordneten XML-Knoten kann es sich um ein XML-Element, einen Textknoten, einen Kommentar oder eine Verarbeitungsanweisung handeln.
Rückgabewerte
| XMLList — Ein XMLList-Objekt mit den Knoten, die dem XML-Objekt untergeordnet sind.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, wie Sie die
children()-Methode verwenden:
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML =
<foo id="22">
<bar>44</bar>
text
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>
AS3 function comments():XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Listet die Eigenschaften des XML-Objekts auf, die XML-Kommentare enthalten.
Rückgabewerte
| XMLList — Ein XMLList-Objekt der Eigenschaften, die Kommentare enthalten.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, wie Sie die
comments()-Methode verwenden:
XML.ignoreComments = false;
var xml:XML =
<foo>
<!-- example -->
<!-- example2 -->
</foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->
AS3 function contains(value:XML):Boolean
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Vergleicht das XML-Objekt mit dem angegebenen value-Parameter.
Parameter
| value:XML — Ein mit dem aktuellen XML-Objekt zu vergleichender Wert.
|
Rückgabewerte
| Boolean — Wenn das XML-Objekt mit dem Parameter value übereinstimmt, lautet der Wert true; andernfalls false.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, wie Sie die
contains()-Methode verwenden:
var xml:XML =
<order>
<item>Rice</item>
<item>Kung Pao Shrimp</item>
</order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false
AS3 function copy():XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt eine Kopie des gegebenen XML-Objekts zurück. Die Kopie ist ein Duplikat der gesamten Knotenbaumstruktur. Das kopierte XML-Objekt hat kein übergeordnetes Objekt und gibt den Wert null zurück, wenn Sie versuchen, die parent()-Methode aufzurufen.
Rückgabewerte
| XML — Die Kopie des Objekts.
|
Siehe auch
Beispiel
Aus dem folgenden Beispiel geht hervor, dass die
copy()-Methode eine neue Instanz eines XML-Objekts erstellt. Das Original bleibt unverändert, wenn Sie die Kopie bearbeiten:
var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1
AS3 static function defaultSettings():Object
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt ein Objekt zurück, bei dem die folgenden Eigenschaften auf die Standardwerte gesetzt sind: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent und prettyPrinting. Die Standardwerte lauten wie folgt:
ignoreComments = trueignoreProcessingInstructions = trueignoreWhitespace = trueprettyIndent = 2prettyPrinting = true
Hinweis: Sie wenden diese Methode nicht auf eine Instanz der XML-Klasse an, sondern, wie im folgenden Code gezeigt, auf XML: var df:Object = XML.defaultSettings().
Rückgabewerte
| Object — Ein Objekt, dessen Eigenschaften auf die Standardwerte gesetzt sind.
|
Siehe auch
Beispiel
Das folgende Beispiel veranschaulicht: wie Sie benutzerdefinierte Einstellungen (um Kommentare und Verarbeitungsanweisungen einzuschließen) anwenden, bevor Sie ein XML-Objekt einrichten; wie Sie dann die Standardeinstellungen wiederherstellen, bevor Sie ein weiteres XML-Objekt einrichten; und wie Sie dann wieder die benutzerdefinierte Einstellungen einrichten (um weitere XML-Objekte einzurichten):
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();
var xml1:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml1.toXMLString());
// <foo>
// <!-- comment -->
// <?instruction ?>
// </foo>
XML.setSettings(XML.defaultSettings());
var xml2:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml2.toXMLString());
AS3 function descendants(name:Object = *):XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt alle Nachfahren (untergeordnete und über mehrere Zweige hinweg untergeordnete Knoten) des XML-Objekts zurück, die dem gegebenen name-Parameter entsprechen. Der Parameter name ist optional. Der name-Parameter kann ein QName-Objekt sein, ein Objekt des Datentyps String oder jeglichen sonstigen Datentyps, der sich in einen String konvertieren lässt.
Um alle Nachfahren zurückzugeben, verwenden Sie den Sternparameter (*). Wird kein Parameter übergeben, wird der String "*" übergeben, sodass alle Nachfahren des XML-Objekts zurückgegeben werden.
Parameter
| name:Object (default = *) |
Rückgabewerte
| XMLList — Ein XMLList-Objekt mit den übereinstimmenden Nachfahren. Wenn es keine Nachfahren gibt, wird ein leeres XMLList-Objekt zurückgegeben.
|
Siehe auch
Beispiel
Um Nachfolger mit Namen zurückzugeben, die in ActionScript reservierten Worten entsprechen, verwenden Sie im XML-Code die Methode
descendants() anstelle des Nachfolger-Operators (..). Dies wird in dem folgenden Beispiel veranschaulicht:
var xml:XML =
<enrollees>
<student id="239">
<class name="Algebra" />
<class name="Spanish 2"/>
</student>
<student id="206">
<class name="Trigonometry" />
<class name="Spanish 2" />
</student>
</enrollees>
trace(xml.descendants("class")); Im folgenden Beispiel wird veranschaulicht, dass die
descendants()-Methode ein XMLList-Objekt zurückgibt, das
alle Nachfolgerobjekte enthält (auch über mehrere Unterordnungsstufen hinweg) usw.:
XML.ignoreComments = false;
var xml:XML =
<body>
<!-- comment -->
text1
<a>
<b>text2</b>
</a>
</body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>
AS3 function elements(name:Object = *):XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Listet die Elemente eines XML-Objekts auf. Ein Element besteht aus einem Start- und End-Tag, z. B. <first></first>. Der Parameter name ist optional. Der name-Parameter kann ein QName-Objekt sein, ein Objekt des Datentyps String oder jeglichen sonstigen Datentyps, der sich in einen String konvertieren lässt. Verwenden Sie den Parameter name, um ein bestimmtes Element aufzulisten. Im folgenden Beispiel gibt das Element "first" beispielsweise "John" zurück: <first>John</first>.
Um alle Element zurückzugeben, verwenden Sie das Sternchen (*) als Parameter. Das Sternchen ist auch der Standardparameter.
Verwenden Sie die Methode length() mit dem Sternparameter (*), um die Gesamtanzahl der Elemente auszugeben. Beispielsweise numElement = addressbook.elements("*").length().
Parameter
| name:Object (default = *)first" der Name (name): <first></first>.
|
Rückgabewerte
| XMLList — Ein XMLList-Objekt mit dem Inhalt des Elements. Der Inhalt des Elements liegt zwischen dem Start- und dem End-Tag. Wenn Sie das Sternchen (*) verwenden, um alle Elemente aufzurufen, werden sowohl die Tags als auch der Inhalt des Elements zurückgegeben.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, dass die
elements()-Methode nur eine Liste mit Elementen zurückgibt; sie enthält keinen Kommentare, Texteigenschaften oder Verarbeitungsanweisungen:
var xml:XML =
<foo>
<!-- comment -->
<?instruction ?>
text
<a>1</a>
<b>2</b>
</foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b> Um Elemente mit Namen zurückzugeben, die in ActionScript reservierten Worten entsprechen, verwenden Sie im XML-Code die Methode
elements() anstelle des XML-Punkt-Operators (.). Dies wird in dem folgenden Beispiel veranschaulicht:
var xml:XML =
<student id="206">
<class name="Trigonometry" />
<class name="Spanish 2" />
</student>
trace(xml.elements("class"));
AS3 function hasComplexContent():Boolean
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Prüft, ob das XML-Objekt komplexen Inhalt enthält. Ein XML-Objekt enthält komplexen Inhalt, wenn es untergeordnete Elemente besitzt. XML-Objekte, die Attribute, Kommentare, Verarbeitungsanweisungen oder Textknoten repräsentieren, haben keinen komplexen Inhalt. Doch auch ein Objekt, das diese Knoten enthält, kann komplexen Inhalt haben (nämlich wenn es zudem untergeordnete Elemente besitzt).
Rückgabewerte
| Boolean — true, wenn das XML-Objekt einen komplexen Inhalt hat; andernfalls false.
|
Siehe auch
Beispiel
Im folgenden Beispiel sehen Sie ein XML-Objekt mit einer Eigenschaft namens
a und einfachem Inhalt sowie eine Eigenschaft namens
a und komplexem Inhalt:
var xml:XML =
<foo>
<a>
text
</a>
<a>
<b/>
</a>
</foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true
trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false
AS3 function hasOwnProperty(p:String):Boolean
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Überprüft, ob die Eigenschaft des Objekts vom Parameter p angegeben wird.
Parameter
| p:String — Die zu vergleichende Eigenschaft.
|
Rückgabewerte
| Boolean — true, wenn die Eigenschaft vorhanden ist; andernfalls false.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird mithilfe der
hasOwnProperty()-Methode sichergestellt, dass eine Eigenschaft (
b) vorhanden ist, bevor ein Ausdruck (
b == "11") der diese Eigenschaft verwendet, bewertet wird:
var xml:XML =
<foo>
<a />
<a>
<b>10</b>
</a>
<a>
<b>11</b>
</a>
</foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11")); Von Flash Player würde eine Ausnahme ausgelöst werden, wenn die letzte Zeile in diesem Beispiel wie folgt lauten würde, da das erste Element mit dem Namen
a keine Eigenschaft mit dem Namen
b aufweist:
trace(xml.a.(b == "11"));
Im folgenden Beispiel wird mithilfe der
hasOwnProperty()-Methode sichergestellt, dass eine Eigenschaft (
item) vorhanden ist, bevor ein Ausdruck (
item.contains("toothbrush")) der diese Eigenschaft verwendet, bewertet wird:
var xml:XML =
<orders>
<order id='1'>
<item>toothbrush</item>
<item>toothpaste</item>
</order>
<order>
<returnItem>shoe polish</returnItem>
</order>
</orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush")));
AS3 function hasSimpleContent():Boolean
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Prüft, ob das XML-Objekt komplexen Inhalt enthält. Ein XML-Objekt enthält einfachen Inhalt, wenn es einen Textknoten, einen Attributknoten oder ein XML-Element ohne untergeordnete Elemente enthält. XML-Objekte, die Kommentare und Verarbeitungsanweisungen repräsentieren, enthalten keinen einfachen Inhalt.
Rückgabewerte
| Boolean — true, wenn das XML-Objekt einen einfachen Inhalt hat; andernfalls false.
|
Siehe auch
Beispiel
Im folgenden Beispiel sehen Sie ein XML-Objekt mit einer Eigenschaft namens
a und einfachem Inhalt sowie eine Eigenschaft namens
a und komplexem Inhalt:
var xml:XML =
<foo>
<a>
text
</a>
<a>
<b/>
</a>
</foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true
trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false
AS3 function inScopeNamespaces():Array
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Listet, basierend auf dem übergeordneten Objekt, die Namespaces für das XML-Objekt auf.
Rückgabewerte
| Array — Ein Array an Namespace-Objekten.
|
Siehe auch
AS3 function insertChildAfter(child1:Object, child2:Object):*
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Fügt den gegebenen child2-Parameter nach dem child1-Parameter in dieses XML-Objekt ein, und gibt das resultierende Objekt zurück. Hat der Parameter child1 den Wert null, fügt die Methode den Inhalt des Parameters child2 vor allen untergeordneten Knoten des XML-Objekts ein (oder anders ausgedrückt: nach none). Hat child1 jedoch einen Wert, existiert aber nicht im XML-Objekt, wird das XML-Objekt nicht geändert und es wird undefined zurückgegeben.
Wenn Sie diese Methode für einen untergeordneten XML-Knoten aufrufen, der kein Element ist (sondern Text, Attribut, Kommentar oder Verarbeitungsanweisung), so wird undefined zurückgegeben.
Verwenden Sie den Operator delete, um den XML-Knoten zu entfernen.
Parameter
| child1:Object — Das Objekt in dem Quellobjekt, das Sie vor child2 einfügen.
|
| |
| child2:Object — Das einzufügende Objekt.
|
Rückgabewerte
| * — Das resultierende XML-Objekt oder undefined.
|
Siehe auch
Beispiel
In diesem Beispiel wird am Ende der child-Elemente eines XML-Objekts ein Element angehängt:
var xml:XML =
<menu>
<item>burger</item>
<item>soda</item>
</menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml); Die
trace()-Ausgabe lautet wie folgt:
<menu>
<item>burger</item>
<saleItem>fries</saleItem>
<item>soda</item>
</menu>
AS3 function insertChildBefore(child1:Object, child2:Object):*
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Fügt den gegebenen child2-Parameter vor dem child1-Parameter in dieses XML-Objekt ein und gibt das resultierende Objekt zurück. Hat der Parameter child1 den Wert null, fügt die Methode den Inhalt des Parameters child2 nach allen untergeordneten Knoten des XML-Objekts ein (oder anders ausgedrückt: vor none). Hat child1 jedoch einen Wert, existiert aber nicht im XML-Objekt, wird das XML-Objekt nicht geändert und es wird undefined zurückgegeben.
Wenn Sie diese Methode für einen untergeordneten XML-Knoten aufrufen, der kein Element ist (sondern Text, Attribut, Kommentar oder Verarbeitungsanweisung), so wird undefined zurückgegeben.
Verwenden Sie den Operator delete, um den XML-Knoten zu entfernen.
Parameter
| child1:Object — Das Objekt in dem Quellobjekt, das Sie nach child2 einfügen.
|
| |
| child2:Object — Das einzufügende Objekt.
|
Rückgabewerte
| * — Das resultierende XML-Objekt oder undefined.
|
Siehe auch
Beispiel
In diesem Beispiel wird am Ende der child-Elemente eines XML-Objekts ein Element angehängt:
var xml:XML =
<menu>
<item>burger</item>
<item>soda</item>
</menu>;
xml.insertChildBefore(xml.bar[0], <saleItem>fries</saleItem>);
trace(xml); Die
trace()-Ausgabe lautet wie folgt:
<menu>
<saleItem>fries</saleItem>
<item>burger</item>
<item>soda</item>
</menu>
AS3 function length():int
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Für XML-Objekte gibt diese Methode immer die Ganzzahl 1 zurück. Die length()-Methode der XMLList-Klasse gibt für ein XMLList-Objekt, das nur einen Wert enthält, den Wert 1 zurück.
Rückgabewerte
| int — Gibt für XML-Objekte immer den Wert 1 zurück.
|
Siehe auch
AS3 function localName():Object
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt den Lokalteil des qualifizierten Namens des XML-Objekts zurück.
Rückgabewerte
| Object — Der Lokalteil des Namens ist entweder ein String oder null.
|
Siehe auch
Beispiel
Das folgende Beispiel veranschaulicht, wie Sie die
localName()-Methode verwenden:
var xml:XML =
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
<soap:Body xmlns:wx = "http://example.com/weather">
<wx:forecast>
<wx:city>Quito</wx:city>
</wx:forecast>
</soap:Body>
</soap:Envelope>;
trace(xml.localName()); // Envelope
AS3 function name():Object
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt den qualifizierten Namen des XML-Objekts zurück.
Rückgabewerte
| Object — Der qualifizierte Namen ist entweder ein Qname oder null.
|
Siehe auch
Beispiel
Das folgende Beispiel veranschaulicht, wie Sie mit der
name()-Methode den qualifizierten Namen eines XML-Objekts abrufen:
var xml:XML =
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
<soap:Body xmlns:wx = "http://example.com/weather">
<wx:forecast>
<wx:city>Quito</wx:city>
</wx:forecast>
</soap:Body>
</soap:Envelope>;
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope" Das folgende Beispiel veranschaulicht, wie Sie die
name()-Methode für eine XML-Eigenschaft, ein Textelement und ein Attribut aufrufen:
var xml:XML =
<foo x="15" y="22">
text
</foo>;
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x
AS3 function namespace(prefix:String = null):*
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Wenn kein Parameter angegeben wird, gibt diese Methode den mit dem qualifizierten Namen dieses XML-Objekts verbundenen Namespace zurück. Wird ein prefix-Parameter angegeben, gibt die Methode den Namespace zurück, der dem prefix-Parameter entspricht und sich im Gültigkeitsbereich des XML-Objekts befindet. Gibt es keinen solchen Namespace, gibt die Methode den Wert undefined zurück.
Parameter
| prefix:String (default = null) |
Rückgabewerte
| * — Gibt null, undefined oder einen Namespace zurück.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird mithilfe der
namespace()-Methode der Namespace eines XML-Objekts abgerufen und einem Namespace-Objekt namens
soap zugewiesen, mit dem dann eine Eigenschaft des
xml-Objekts identifiziert wird (
xml.soap::Body[0]):
var xml:XML =
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
<soap:Body xmlns:wx = "http://example.com/weather">
<wx:forecast>
<wx:city>Quito</wx:city>
</wx:forecast>
</soap:Body>
</soap:Envelope>;
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope
var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather" Im folgenden Beispiel wird mithilfe der
namespace()-Methode zum einen der Standard-Namespace für einen Knoten abgerufen sowie der Namespace für ein bestimmtes Präfix (
"dc"):
var xml:XML =
<rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns="http://purl.org/rss/1.0/">
<!-- ... -->
</rdf:RDF>;
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined
AS3 function namespaceDeclarations():Array
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Listet Namespace-Deklarationen auf, die mit dem XML-Objekt im Kontext des übergeordneten Knotens verbunden wurden.
Rückgabewerte
| Array — Ein Array an Namespace-Objekten.
|
Siehe auch
Beispiel
Im folgenden Beispiel werden die Namespace-Deklarationen eines XML-Objekts ausgegeben:
var xml:XML =
<rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns="http://purl.org/rss/1.0/">
<!-- ... -->
</rdf:RDF>;
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
var ns:Namespace = xml.namespaceDeclarations()[i];
var prefix:String = ns.prefix;
if (prefix == "") {
prefix = "(default)";
}
trace(prefix + ":", ns.uri);
} Die
trace()-Ausgabe lautet wie folgt:
rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
dc: http://purl.org/dc/elements/1.1/
(default): http://purl.org/rss/1.0/
AS3 function nodeKind():String
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt den Typ des Knotens an: Text-, Kommentar-, Verarbeitungsanweisungs-, Attribut- oder Elementknoten.
Rückgabewerte
| String — Der verwendete Knotentyp.
|
Siehe auch
Beispiel
Im folgenden Beispiel werden alle 5 Knotentypen verfolgt:
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML =
<example id="10">
<!-- this is a comment -->
<?test this is a pi ?>
and some text
</example>;
trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute
AS3 function normalize():XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Für das XML-Objekt und alle seine Nachfahren werden benachbarte Textknoten vermischt und leere Textknoten entfernt.
Rückgabewerte
| XML — Das resultierende normalisierte XML-Objekt.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, wie sich das Aufrufen der
normalize()-Methode auswirkt:
var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1
AS3 function parent():*
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt den übergeordneten Knoten des XML-Objekts zurück. Besitzt das XML-Objekt keinen übergeordneten Knoten, gibt die Methode den Wert undefined zurück.
Rückgabewerte
| * — Das übergeordnete XML-Objekt. Gibt entweder String oder null zurück.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird mithilfe der
parent()-Methode das übergeordnete Element eines bestimmten Elements in einer XML-Struktur identifiziert:
var xml:XML =
<body>
<p id="p1">Hello</p>
<p id="p2">Test:
<ul>
<li>1</li>
<li>2</li>
</ul>
</p>
</body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2
AS3 function prependChild(value:Object):XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Fügt eine Kopie des bereitgestellten child-Objekts vor irgendwelchen vorhandenen XML-Eigenschaften für dieses Element in das XML-Element ein.
Verwenden Sie den Operator delete, um den XML-Knoten zu entfernen.
Parameter
| value:Object — Das einzufügende Objekt.
|
Rückgabewerte
| XML — Das resultierende XML-Objekt.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird mithilfe der
prependChild()-Methode am Anfang der child-Liste eines XML-Objekts ein neues Element hinzugefügt:
var xml:XML =
<body>
<p>hello</p>
</body>;
xml.prependChild(<p>world</p>);
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>
AS3 function processingInstructions(name:String = "*"):XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Wird ein name-Parameter bereitgestellt, werden alle untergeordneten Knoten des XML-Objekts aufgelistet, die Verarbeitungsanweisungen mit diesem Namen (name) enthalten. Ohne Parameter listet diese Methode alle untergeordneten Knoten des XML-Objekts auf, die irgendwelche Verarbeitungsanweisungen enthalten.
Parameter
| name:String (default = "*") |
Rückgabewerte
| XMLList — Eine Liste an passenden untergeordneten Objekten.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird mithilfe der
processingInstructions()-Methode ein Array mit Verarbeitungsanweisungen für ein XML-Objekt abgerufen:
XML.ignoreProcessingInstructions = false;
var xml:XML =
<body>
foo
<?xml-stylesheet href="headlines.css" type="text/css" ?>
<?instructionX ?>
</body>;
trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet
AS3 function propertyIsEnumerable(p:String):Boolean
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Prüft, ob sich die Eigenschaft p in dem Satz an Eigenschaften befindet, die in einer auf das XML-Objekt angewendeten for..in-Anweisung durchlaufen werden können. Gibt nur true zurück, wenn toString(p) == "0".
Parameter
| p:String — Die Eigenschaft, die überprüft werden soll.
|
Rückgabewerte
| Boolean — Wenn die Eigenschaft in einer for..in-Anweisung durchlaufen werden kann, lautet der Wert true; andernfalls false.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, dass die
propertyNameIsEnumerable()-Methode für ein XML-Objekt den Wert
true nur für den Wert
0 zurückgibt; dagegen lautet bei einem XMLList-Objekt der Rückgabewert
true für jeden gültigen Indexwert des XMLList-Objekts:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
</body>;
trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false
for (var propertyName:String in xml) {
trace(xml[propertyName]);
}
var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false
for (var propertyName:String in list) {
trace(list[propertyName]);
}
AS3 function removeNamespace(ns:Namespace):XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Entfernt den gegebenen Namespace für dieses Objekt und alle Nachfahren. Die Methode removeNamespaces() entfernt keinen Namespace, wenn vom qualifizierten Namen des Objekts darauf verwiesen wird oder vom qualifizierten Namen des Objektattributs.
Parameter
Rückgabewerte
| XML — Eine Kopie des resultierenden XML-Objekts.
|
Siehe auch
Beispiel
Das folgende Beispiel veranschaulicht, wie Sie eine Namespace-Deklaration aus einem XML-Objekt entfernen:
var xml:XML =
<rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns="http://purl.org/rss/1.0/">
<!-- ... -->
</rdf:RDF>;
trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); //
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2
AS3 function replace(propertyName:Object, value:XML):XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Ersetzt die im Parameter propertyName angegebenen Eigenschaften durch den gegebenen value-Parameter. Werden keine Eigenschaften gefunden, die mit propertyName übereinstimmen, bleibt das XML-Objekt unverändert.
Parameter
| propertyName:Object — Kann ein numerischer Wert sein, ein nicht qualifizierter Name für ein Set an XML-Elementen, ein qualifizierter Name für ein Set an XML-Elementen oder der Sternchenplatzhalter ("*"). Einen nicht qualifizierten Namen verwenden Sie, um XML-Elemente im Standard-Namespace zu identifizieren.
|
| |
| value:XML — Der Ersetzungswert. Das kann ein XML-Objekt sein, ein XMLList-Objekt oder jeder beliebige Wert, der mit toString() umgewandelt werden kann.
|
Rückgabewerte
| XML — Das resultierende XML-Objekt, in dem die übereinstimmenden Eigenschaften ersetzt worden sind.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird die
replace()-Methode mit einer Ganzzahl als erstem Parameter aufgerufen:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
<hr/>
</body>;
xml.replace(1, <p>Bob</p>);
trace(xml); Der Code ergibt die folgende
trace()-Ausgabe:
<body>
<p>Hello</p>
<p>Bob</p>
<hr/>
</body>
Im folgenden Beispiel wird die
replace()-Methode mit einem String als erstem Parameter aufgerufen:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
<hr/>
</body>;
xml.replace("p", <p>Hi</p>);
trace(xml); Der Code ergibt die folgende
trace()-Ausgabe:
<body>
<p>Hi</p>
<hr/>
</body>;
Im folgenden Beispiel wird die
replace()-Methode mit einem "QName" als erstem Parameter aufgerufen:
var xml:XML =
<ns:body xmlns:ns = "myNS">
<ns:p>Hello</ns:p>
<ns:p>World</ns:p>
<hr/>
</ns:body>;
var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);
Der Code ergibt die folgende
trace()-Ausgabe:
<ns:body xmlns:ns = "myNS">
<p>Bob</p>
<hr/>
</ns:body>
Im folgenden Beispiel wird die
replace()-Methode zusammen mit dem String
"*" als erstem Parameter aufgerufen:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
<hr/>
</body>;
xml.replace("*", <img src = "hello.jpg"/>);
trace(xml); Der Code ergibt die folgende
trace()-Ausgabe:
<body>
<img src="hello.jpg"/>
</body>
AS3 function setChildren(value:Object):XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Ersetzt die untergeordneten Eigenschaften des XML-Objekts durch das angegebene Set an XML-Eigenschaften, das im Parameter value bereitgestellt wird.
Parameter
| value:Object — Die zu ersetzenden XML-Eigenschaften. Dabei kann es sich um ein einzelnes XML-Objekt handeln oder um ein XMLList-Objekt.
|
Rückgabewerte
| XML — Das resultierende XML-Objekt.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird das Aufrufen der
setChildren()-Methode veranschaulicht, und zwar zuerst mit einem XML-Objekt als Parameter und dann mit einem XMLList-Objekt als Parameter:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
</body>;
var list:XMLList = xml.p;
xml.setChildren(<p>hello</p>);
trace(xml);
// <body>
// <p>hello</p>
// </body>
xml.setChildren(list);
trace(xml);
// <body>
// <p>Hello</p>
// <p>World</p>
// </body>
AS3 function setLocalName(name:String):void
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Ändert den Lokalteil des XML-Objektnamens in den gegebenen name-Parameter.
Parameter
| name:String — Der im Lokalteil zu ersetzende Name.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird mithilfe der
setLocalName()-Methode der lokale Name eines XML-Elements geändert:
var xml:XML =
<ns:item xmlns:ns="http://example.com">
toothbrush
</ns:item>;
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>
AS3 function setName(name:String):void
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Setzt den Namen des XML-Objekts auf den gegebenen qualifizierten Namen oder Attributnamen.
Parameter
| name:String — Der neue Name für das Objekt.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird mithilfe der
setName()-Methode der Name eines XML-Elements geändert:
var xml:XML =
<item>
toothbrush
</item>;
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>
AS3 function setNamespace(ns:Namespace):void
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Setzt den mit dem XML-Objekt verbundenen Namespace.
Parameter
Siehe auch
Beispiel
Im folgenden Beispiel wird der
soap-Namespace, der in einem XML-Objekt definiert wurde, auf den Namespace eines anderen XML-Objekts angewendet (
xml2):
var xml1:XML =
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
<!-- ... -->
</soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");
var xml2:XML =
<Envelope>
<Body/>
</Envelope>;
xml2.setNamespace(ns);
trace(xml2);
AS3 static function setSettings(... rest):void
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Setzt die Werte für die folgenden XML-Eigenschaften: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent und prettyPrinting. Im folgenden sind die Standardeinstellungen aufgelistet, die anwendet werden, wenn kein setObj-Parameter bereitgestellt wird.
XML.ignoreComments = trueXML.ignoreProcessingInstructions = trueXML.ignoreWhitespace = trueXML.prettyIndent = 2XML.prettyPrinting = true
Hinweis: Sie wenden diese Methode nicht auf eine Instanz der XML-Klasse an, sondern auf XML, wie im folgenden Code gezeigt: XML.setSettings().
Parameter
| ... rest — Ein Objekt mit jeder der folgenden Eigenschaften:
ignoreCommentsignoreProcessingInstructionsignoreWhitespaceprettyIndentprettyPrinting
|
Siehe auch
Beispiel
Das folgende Beispiel veranschaulicht: wie Sie benutzerdefinierte Einstellungen (um Kommentare und Verarbeitungsanweisungen einzuschließen) anwenden, bevor Sie ein XML-Objekt einrichten; wie Sie dann die Standardeinstellungen wiederherstellen, bevor Sie ein weiteres XML-Objekt einrichten; und wie Sie anschließend wieder die benutzerdefinierte Einstellungen einrichten (um weitere XML-Objekte einzurichten):
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();
var xml1:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml1.toXMLString());
// <foo>
// <!-- comment -->
// <?instruction ?>
// </foo>
XML.setSettings(XML.defaultSettings());
var xml2:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml2.toXMLString());
AS3 static function settings():Object
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Ruft die folgenden Eigenschaften ab: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent und prettyPrinting.
Rückgabewerte
| Object — Ein Objekt mit den folgenden XML-Eigenschaften:
ignoreCommentsignoreProcessingInstructionsignoreWhitespaceprettyIndentprettyPrinting
|
Siehe auch
Beispiel
Das folgende Beispiel veranschaulicht: wie Sie benutzerdefinierte Einstellungen (um Kommentare und Verarbeitungsanweisungen einzuschließen) anwenden, bevor Sie ein XML-Objekt einrichten; wie Sie dann die Standardeinstellungen wiederherstellen, bevor Sie ein weiteres XML-Objekt einrichten; und wie Sie dann wieder die benutzerdefinierte Einstellungen einrichten (um weitere XML-Objekte einzurichten):
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();
var xml1:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml1.toXMLString());
// <foo>
// <!-- comment -->
// <?instruction ?>
// </foo>
XML.setSettings(XML.defaultSettings());
var xml2:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml2.toXMLString());
AS3 function text():XMLList
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt ein XMLList-Objekt zurück mit allen XML-Eigenschaften des XML-Objekts, die XML-Textknoten darstellen.
Rückgabewerte
| XMLList — Die Liste der Eigenschaften.
|
Siehe auch
Beispiel
Das folgende Beispiel veranschaulicht, wie Sie mit der
text()-Methode die Textknoten eines XML-Objekts abgerufen:
var xml:XML =
<body>
text1
<hr/>
text2
</body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2
AS3 function toString():String
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt das XML-Objekt als String zurück. Nach welchen Regeln diese Konvertierung vollzogen wird, ist abhängig davon, ob das XML-Objekt einen einfachen oder komplexen Inhalt hat:
- Hat das XML-Objekt einen einfachen Inhalt, gibt
toString() den String-Inhalt des XML-Objekts zurück, wobei das Start-Tag, vorhandene Attribute, Namespace-Deklarationen und das Endtag entfernt werden.
- Hat das XML-Objekt einen komplexen Inhalt, gibt
toString() das gesamte XML-Objekt als XML-kodierten String zurück, einschließlich Start-Tag, Attributen, Namespace-Deklarationen und End-Tag.
Damit jedes Mal das gesamte XML-Objekt zurückgegeben wird, verwenden Sie die Methode toXMLString().
Rückgabewerte
| String — Die Stringdarstellung des XML-Objekts.
|
Siehe auch
Beispiel
Im folgende Beispiel wird veranschaulicht, was die
toString()-Methode zurückgibt, wenn das XML-Objekt einen einfachen Inhalt hat:
var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example
Im folgende Beispiel wird veranschaulicht, was die
toString()-Methode zurückgibt, wenn das XML-Objekt einen komplexen Inhalt hat:
var test:XML =
<type name="Joe">
<base name="Bob"></base>
example
</type>;
trace(test.toString());
// <type name="Joe">
// <base name="Bob"/>
// example
// </type>
AS3 function toXMLString():String
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt das XML-Objekt als String zurück. Im Gegensatz zur Methode toString() gibt die Methode toXMLString() immer das Start-Tag, vorhandene Attribute und das End-Tag des XML-Objekts zurück, unabhängig davon, ob das XML-Objekt einen einfachen oder komplexen Inhalt hat. (Die Methode toString() entfernt alle diese Elemente für XML-Objekte mit einfachem Inhalt.)
Rückgabewerte
| String — Die Stringdarstellung des XML-Objekts.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird die unterschiedliche Wirkung der
toString()-Methode (die standardmäßig auf alle Parameter einer
trace()-Methode angewendet wird) und der
toXMLString()-Methode veranschaulicht:
var xml:XML =
<p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>
AS3 function valueOf():XML
| Sprachversion : | ActionScript 3.0 |
| Player-Version : | Flash Player 9 |
Gibt das XML-Objekt zurück.
Rückgabewerte
| XML — Der Grundwert einer XML-Instanz.
|
Siehe auch
Beispiel
Im folgenden Beispiel wird veranschaulicht, dass der Rückgabewert der
valueOf()-Methode identisch ist mit dem XML-Quellobjekt:
var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true
Im folgenden Beispiel wird zunächst eine XML-Variable erstellt, zu der dann Knoten hinzugefügt werden. Anschließend wird mithilfe von XML-Eigenschaften nach XML-Knoten gesucht, die dann gedruckt werden. Beachten Sie, dass das "at"-Symbol (
@) bei mehreren Aufrufen von
trace() verwendet wird, um Informationen anhand des Attributnamens zu finden.
package {
import flash.display.Sprite;
public class XmlExample extends Sprite {
public function XmlExample() {
var employees:XML =
<employees>
<employee ssn="123-123-1234">
<name first="John" last="Doe"/>
<address>
<street>11 Main St.</street>
<city>San Francisco</city>
<state>CA</state>
<zip>98765</zip>
</address>
</employee>
<employee ssn="789-789-7890">
<name first="Mary" last="Roe"/>
<address>
<street>99 Broad St.</street>
<city>Newton</city>
<state>MA</state>
<zip>01234</zip>
</address>
</employee>
</employees>;
trace(employees.employee[0].address.zip); // 98765
trace(employees.employee[1].@ssn); // 789-789-7890
trace(employees.employee.name); // <name first="John" last="Doe"/>
// <name first="Mary" last="Roe"/>
trace(employees..zip[0]); // 98765
trace(employees..@ssn[1]); // 789-789-7890
trace(employees..name); // <name first="John" last="Doe"/>
// <name first="Mary" last="Roe"/>
trace(employees.employee[0].address.*); // <street>11 Main St.</street>
// <city>San Francisco</city>
// <state>CA</state>
// <zip>98765</zip>
var node:String = "zip";
trace(employees.employee[0].address[node]); // 98765
var attribute:String = "ssn";
trace(employees.employee[1].@[attribute]); // 789-789-7890
for each (var num:XML in employees..@ssn) {
trace(num); // 123-123-1234
} // 789-789-7890
var ssnToFind:String = "789-789-7890";
trace(employees.employee.(@ssn == ssnToFind).toXMLString());
// <employee ssn="789-789-7890">
// <name first="Mary" last="Roe"/>
// <address>
// <street>99 Broad St.</street>
// <city>Newton</city>
// <state>MA</state>
// <zip>01234</zip>
// </address>
// </employee>
}
}
}
© 2004-2007 Adobe Systems Incorporated. All rights reserved.
Fri Oct 12 2007, 2:03 AM GMT-07:00
Aktuelle Seite: http://livedocs.adobe.com/flash/9.0_de/ActionScriptLangRefV3/XML.html
Object
Vererbte öffentliche Eigenschaften verbergen
Vererbte öffentliche Eigenschaften anzeigen