Flash CS3 文档

ActionScript 2.0 语言参考 > ActionScript 类 > Key > addListener（Key.addListener 方法）

addListener（Key.addListener 方法）

注册一个对象，以便接收 onKeyDown 和 onKeyUp 通知。当按下或释放某个键时，不管输入焦点情况如何，所有用 addListener() 注册的侦听对象都将调用其 onKeyDown 方法或 onKeyUp 方法。可以有多个对象侦听键盘通知。如果已经注册了侦听器 newListener，则不会发生任何更改。

Flash 应用程序只能监视其焦点内发生的键盘事件。Flash 应用程序无法检测其它应用程序中的键盘事件。

可用性：ActionScript 1.0、Flash Player 6

参数

listener:Object ― 具有 onKeyDown 和 onKeyUp 方法的对象。

示例

下面的示例创建新的侦听器对象，并为 onKeyDown 和 onKeyUp 定义函数。最后一行使用 addListener() 向 Key 对象注册该侦听器，以使该对象可接收 key down 和 key up 事件的通知。

var myListener:Object = new Object();
myListener.onKeyDown = function () {
trace ("You pressed a key.");
}
myListener.onKeyUp = function () {
trace ("You released a key.");
}
Key.addListener(myListener);

下面的示例将快捷键 Ctrl+7 分配给实例名为 my_btn 的按钮，并向屏幕阅读器（请参阅 _accProps）提供有关该快捷键的信息。在此示例中，当您按 Ctrl+7 时，myOnPress 函数就在“输出”面板上显示 hello 文本。

function myOnPress() {
trace("hello");
}
function myOnKeyDown() {
// 55 is key code for 7
if (Key.isDown(Key.CONTROL) && Key.getCode() == 55) {
Selection.setFocus(my_btn);
my_btn.onPress();
}
}
var myListener:Object = new Object();
myListener.onKeyDown = myOnKeyDown;
Key.addListener(myListener);
my_btn.onPress = myOnPress;
my_btn._accProps.shortcut = "Ctrl+7";
Accessibility.updateProperties();

请参阅

getCode（Key.getCode 方法）, isDown（Key.isDown 方法）, onKeyDown（Key.onKeyDown 事件侦听器）, onKeyUp（Key.onKeyUp 事件侦听器）, removeListener（Key.removeListener 方法）

Flash CS3

评论添加到页面后给我发送电子邮件 | 评论报告

当前页: http://livedocs.adobe.com/flash/9.0_cn/main/00001749.html

添加评论