Flash CS3 文档

学习 Adobe Flash 中的 ActionScript 2.0 > 使用文本和字符串 > 使用层叠样式表设置文本格式 > 将样式表应用于 TextArea 组件

将样式表应用于 TextArea 组件

要将样式表应用于 TextArea 组件，您可以创建一个样式表对象，并使用 TextField.StyleSheet 类为其分配 HTML 样式。然后为 TextArea 组件的 styleSheet 属性分配样式表。

下例创建了一个样式表对象 styles，并将其分配给 myTextArea 组件实例。

在 TextArea 组件中使用样式表：

1. 创建一个新的 Flash 文档，并将其保存为 textareastyle.fla。
2. 将 TextArea 组件从“组件”面板的“User Interface”文件夹拖动到舞台上，并为其指定实例名称 myTextArea。
3. 将下面的 ActionScript 添加到主时间轴中的第 1 帧：

   // 创建一个新的样式表对象并设置其样式。
   var styles:TextField.StyleSheet = new TextField.StyleSheet();
   styles.setStyle("html", {fontFamily:'Arial,Helvetica,sans-serif',
                       fontSize:'12px',
                       color:'#0000FF'});
   styles.setStyle("body", {color:'#00CCFF',
                       textDecoration:'underline'});
   styles.setStyle("h1",{fontFamily:'Arial,Helvetica,sans-serif',
                       fontSize:'24px',
                       color:'#006600'});
   
   /* 将样式表对象分配给 myTextArea 组件。将 html 属性设置为 true，将 styleSheet 属性设置为样式表对象。 */
   myTextArea.styleSheet = styles;
   myTextArea.html = true;
   
   var myVars:LoadVars = new LoadVars();
   // 定义 onData 处理函数并加载要显示的文本。
   myVars.onData = function(myStr:String):Void {
       if (myStr != undefined) {
           myTextArea.text = myStr;
       } else {
           trace("Unable to load text file.");
       }
   };
   myVars.load("http://www.helpexamples.com/flash/myText.htm");
   

   上面的代码块创建了一个新的 TextField.StyleSheet 实例，该实例定义三种分别用于 html、body 和 h1 HTML 标签的样式。接着，将该样式表对象应用于 TextArea 组件并启用 HTML 格式设置。其余的 ActionScript 定义了一个 LoadVars 对象，该对象加载一个外部 HTML 文件并使用加载的文本填充文本区域。

4. 选择“控制”>“测试影片”对该 Flash 文档进行测试。

Flash CS3

评论添加到页面后给我发送电子邮件 | 评论报告

当前页: http://livedocs.adobe.com/flash/9.0_cn/main/00000913.html

添加评论