Flash CS3 Documentation

ActionScript 2.0 Language Reference > ActionScript language elements > Operators > {} object initializer operator

{} object initializer operator

object = { name1 : value1 , name2 : value2 ,... nameN : valueN }
{expression1; [...expressionN]}

Creates a new object and initializes it with the specified name and value property pairs. Using this operator is the same as using the new Object syntax and populating the property pairs using the assignment operator. The prototype of the newly created object is generically named the Object object.

This operator is also used to mark blocks of contiguous code associated with flow control statements (for, while, if, else, switch) and functions.

Availability: ActionScript 1.0; Flash Player 5

Operands

object : Object - The object to create. name1,2,...N The names of the properties. value1,2,...N The corresponding values for each name property.

Returns

Object -

Usage 1: An Object object.

Usage 2: Nothing, except when a function has an explicit return statement, in which case the return type is specified in the function implementation.

Example

The first line of the following code creates an empty object using the object initializer ({}) operator; the second line creates a new object using a constructor function:

var object:Object = {}; 
var object:Object = new Object(); 

The following example creates an object account and initializes the properties name, address, city, state, zip, and balance with accompanying values:

var account:Object = {name:"Adobe", address:"601 Townsend Street", city:"San Francisco", state:"California", zip:"94103", balance:"1000"}; 
for (i in account) { 
 trace("account." + i + " = " + account[i]); 
} 

The following example shows how array and object initializers can be nested within each other:

var person:Object = {name:"Gina Vechio", children:["Ruby", "Chickie", "Puppa"]}; 

The following example uses the information in the previous example and produces the same result using constructor functions:

var person:Object = new Object(); 
person.name = "Gina Vechio"; 
person.children = new Array(); 
person.children[0] = "Ruby"; 
person.children[1] = "Chickie"; 
person.children[2] = "Puppa"; 

The previous ActionScript example can also be written in the following format:

var person:Object = new Object(); 
person.name = "Gina Vechio"; 
person.children = new Array("Ruby", "Chickie", "Puppa"); 

See also

Object

Flash CS3