package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}

Comments

ohad1 said on May 3, 2007 at 4:34 AM :

The Compute spectrum function is inncorect.
A signal's spectrum is needed to be shown in the frequncy domain.
The compute spectrum function displays the signal on the time domain(similar to osciloscope).
In order to show the signal in the frequncy domain, a DFT transformation is needed to be applied.
I've genereted such code:

//Init
var s:Sound = new Sound();
var sound_channel:SoundChannel;
var ba:ByteArray = new ByteArray();
var array:Array;
s.load(new URLRequest("song.mp3"));
sound_channel = s.play(0,1000);
this.addEventListener(Event.ENTER_FRAME, spectrum);
var a:Number = 0;
var N:Number = 32; //Signal's length in time
var K:Number = 16; //Signal's length in frequency
var X_r:Array = new Array(); //real part
var X_i:Array = new Array(); // imaginary part
function spectrum(event:Event)
{

// Clear the array
for(var k=0; k < 16; k++)
X_r[k]=X_i[k]=0;
a = 0;
graphics.clear();
SoundMixer.computeSpectrum(ba,true,0);
// DFT
for(var n=0; n < N; n++)
{
a=ba.readFloat();

for(k=0; k < 16; k++)
{
var ang:Number=2*Math.PI*n*k/N;
X_r[k]+=a*Math.cos(2*Math.PI*n*k/N);
X_i[k]+=a*Math.sin(2*Math.PI*n*k/N);

}

}
// show DFT
for(k=0; k < 16; k++)
{graphics.lineStyle(0,0);
var amp=Math.log(1+Math.sqrt(Math.pow(X_r[k],2)+Math.pow(X_i[k],2)));
graphics.beginFill(0x0000FF|(amp*100<<9));
graphics.drawRect(k*8,0,7,-10*(amp));
}



}

pisikopatikalistor said on Jun 22, 2007 at 12:52 AM :

ohad1, is this code working? I want to use compute spectrum, but I don't know how is it working exactly?

minigunbang said on Jun 29, 2007 at 12:51 AM :

pisikopatikalistor, this code is working exactly,
but the _y property is smaller than 0,
so you couldn't see the spectrum

change the code

graphics.drawRect(k*8,0,7,-10*(amp));

====> graphics.drawRect(k*8 + 50 ,50,7,-10*(amp));

pisikopatikalistor said on Jul 20, 2007 at 8:07 AM :

thanks a lot, minigunbang

pisikopatikalistor said on Jul 23, 2007 at 10:31 AM :

I have a problem with computing spectrum
if there is another swf in other IE windows or firefox tabs an error occuring about security like that:
----------------------------------------------------------------------------------------------
SecurityError: Error #2121: Security sandbox violation: SoundMixer.computeSpectrum: http://www.mydomain.com/spectrumEx.swf cannot access http://www.anotherdomain.com/aswfwhichcontainssound.swf. This may be worked around by calling Security.allowDomain.
at flash.media::SoundMixer$/computeSpectrum()
at spectrumEx_fla::MainTimeline/spectrum()
--------------------------------------------------------------------------------------

how can I solve this problem? do U have any idea?

pisikopatikalistor said on Jul 26, 2007 at 1:50 AM :

I updated my player to 9.0.47 from 9.0.45
and everthing is ok

David Stiller said on Aug 8, 2007 at 5:44 AM :

The general description for this class states that SoundMixer "controls embedded streaming sounds in a SWF; it does not control dynamically created Sound objects" -- but in my experience, SoundMixer does indeed act like a truly global sound control. Volume, panning, the stopAll() method ... each one affects all sounds, dynamic or not, in my tests. In timeline audio, this affects both Stream and Event sounds.

ZoD- said on Sep 7, 2007 at 9:55 AM :

Hey pisikopatikalistor,
the Error #2121 happens when you try to call the computeSpectrum function when another flash file with sound is loaded from a different domain.
For example, if you have youtube open when trying to view a flash file that uses computeSpectrum, it will fail because youtube did not grant your domain access to get its sound info. So instead of just returning the byteArray for the sounds that it can access, Adobe (for some silly reason) decided to have computeSpectrum leave the byte array untouched! I know...STUPID! Why not just return the byte array for the sounds that it CAN access?!

It appears the only "solution" is to put your computeSpectrum in a try/catch block (or use areSoundsInaccessable method before calling computeSpectrum ) and simply notify the user that a flash file in a different window is interfering with your sound visualizations!

Hopefully adobe will update the implementation of computeSpectrum. :(

podlium said on Oct 30, 2007 at 5:14 PM :

Hi,

it seems that computeSpectrum only gets frequencies from 0 to 11025?
i wasn't able to get >11025 frequencies with readFloat().
Am i right or is there another way?

FreDeVos said on Nov 5, 2007 at 1:38 AM :

Hi,

it seems that computeSpectrum only gets frequencies from 0 to 11025?
i wasn't able to get >11025 frequencies with readFloat().
Am i right or is there another way?

That's because of the sampling frequency of 22050 Hz (depending on stretchFactor in computeSpectrum(), in your case = 1).

Read this:
http://en.wikipedia.org/wiki/Nyquist_frequency

In particular:
"For example, audio CDs have a sampling frequency of 44100 Hz. The Nyquist frequency is therefore 22050 Hz, which is an upper bound on the highest frequency the data can unambiguously represent."

podlium said on Nov 6, 2007 at 3:59 AM :

yes, but stretchFactor in my case is set to 0, and still i get 256 float values for each channel that respond only to frequencies 0-11050 Hz.

i posted this on the adobe forum
http://www.adobe.com/cfusion/webforums/forum/messageview.cfm?forumid=15&catid=288&threadid=1311004&enterthread=y