El paquete flash.net contiene funciones de nivel de paquete para la apertura de una nueva ventana del navegador, el envío de una solicitud de URL a un servidor y la gestión de alias de clases.
Funciones públicas
 FunciónDefinido por
  
Busca una clase con una alias previamente registrado mediante una llamada al método registerClassAlias().
flash.net
  
navigateToURL(request:URLRequest, window:String = null):void
Abre o reemplaza una ventana de la aplicación con el contenedor de Flash Player (suele ser un navegador).
flash.net
  
registerClassAlias(aliasName:String, classObject:Class):void
Se conserva la clase (el tipo) de un objeto si el objeto está codificado con formato de mensaje de acción (AMF).
flash.net
  
Envía una solicitud URL a un servidor, pero ignora cualquier respuesta.
flash.net
Información sobre funciones
getClassByAlias()función
public function getClassByAlias(aliasName:String):Class

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Busca una clase con una alias previamente registrado mediante una llamada al método registerClassAlias().

Este método no interactúa con el método flash.utils.getDefinitionByName().

Parámetros

aliasName:String — El alias que se va a buscar.

Valor devuelto
Class — La clase asociada al alias dado. Si no se encuentra, se emitirá una excepción.

Emite
ReferenceError — No se registró el alias.

Véase también

navigateToURL()función 
public function navigateToURL(request:URLRequest, window:String = null):void

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Abre o reemplaza una ventana de la aplicación con el contenedor de Flash Player (suele ser un navegador).

Nota: en el contenido local que se ejecuta en el navegador, las llamadas a la función navigateToURL() que especifiquen un seudoprotocolo "javascript:" (por ejemplo, navigateToURL("javascript:someFunction()")) sólo están permitidas si el archivo SWF y la página Web que lo contiene (en caso de haber una) se encuentran en el entorno limitado local de confianza. Para más información, consulte las siguientes secciones:

Parámetros

request:URLRequest — Un objeto URLRequest que especifica la URL a la que se navega.
 
window:String (default = null) — La ventana del navegador o el fotograma HTML donde se muestra el documento indicado por el parámetro request. Puede introducir el nombre en una ventana concreta o utilizar los valores siguientes:
  • "_self" especifica el fotograma actual en la ventana actual.
  • "_blank" especifica una nueva ventana.
  • "_parent" especifica el elemento principal del fotograma actual.
  • "_top" especifica el fotograma de nivel superior de la ventana actual.

Si no especifica ningún valor para este parámetro, se creará una nueva ventana vacía. En el reproductor autónomo, puede especificar una nueva ventana ("_blank") o una con nombre. El resto de valores no son aplicables.

Nota: si el código de un archivo SWF que se ejecuta en el entorno limitado local con el sistema de archivos llama a la función navigateToURL() y especifica un nombre de ventana personalizado para el parámetro window, el nombre de la ventana pasará a ser un nombre aleatorio. El nombre se escribe con la forma "_flashXXXXXXXX", donde cada X representa un dígito aleatorio hexadecimal. En una misma sesión (hasta que se cierre la ventana del navegador), si se vuelve a llamar a la función y se especifica el mismo nombre para el parámetro window, se utilizará la misma cadena aleatoria.


Emite
SecurityError — Este error se emite en los casos siguientes:
  • Los archivos SWF locales que no son de confianza no pueden comunicarse en Internet. Puede solucionar este problema reclasificando el archivo SWF como archivo local de red o archivo de confianza.
  • Una operación de navegación intentó evaluar una pseudoURL de secuencia de comandos, pero el documento que contiene (normalmente un documento HTML en un navegador) proviene de un entorno limitado al que no se tiene acceso. Este problema se puede solucionar especificando allowScriptAccess="always" en el documento que lo contiene.
  • No es posible navegar por las ventanas especiales "_self", "_top" o "_parent" si el archivo SWF está contenido en una página HTML con allowScriptAccess establecido como "none" o como "sameDomain" si el dominio del archivo HTML no coincide con el del archivo SWF.
  • No se puede navegar por una ventana con nombre no predeterminado desde un archivo SWF ubicado en el entorno limitado local con el sistema de archivos.

Véase también


Ejemplo

En el ejemplo siguiente, se abre la URL http://www.adobe.com en una nueva ventana del navegador y se transfieren los datos relacionados con la sesión del usuario (capturados en un objetos URLVariables) al servidor Web.
package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class NavigateToURLExample extends Sprite {

        public function NavigateToURLExample() {
            var url:String = "http://www.adobe.com";
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "Your Name";
            var request:URLRequest = new URLRequest(url);
            request.data = variables;
            try {
                navigateToURL(request);
            }
            catch (e:Error) {
                // handle error here
            }
        }
    }
}
registerClassAlias()función 
public function registerClassAlias(aliasName:String, classObject:Class):void

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Se conserva la clase (el tipo) de un objeto si el objeto está codificado con formato de mensaje de acción (AMF). Al codificar un objeto con AMF, la función guarda el alias para la clase para que ésta se pueda recuperar al descodificar el objeto. Si el contexto de la codificación no registró ningún alias para la clase del objeto, éste se codificará como un objeto anónimo. De forma similar, si el contexto de la descodificación no tiene el mismo alias registrado, se creará un objeto anónimo para los datos descodificados.

Algunos ejemplos de clases que codifican objetos con AMF son: LocalConnection, ByteArray, SharedObject, NetConnection y NetStream.

No es necesario que los contextos de la codificación y la descodificación utilicen la misma clase para un alias; pueden cambiar las clases intencionadamente, siempre y cuando la clase de destino contenga todos los miembros serializados por la clase de origen.

Parámetros

aliasName:String — El alias que se va a utilizar.
 
classObject:Class — La clase asociada al alias dado.


Emite
TypeError — Si algún parámetro es null.

Véase también


Ejemplo

Este ejemplo utiliza la función registerClassAlias() para registrar un alias (com.example.eg) para la clase ExampleClass. Como hay un alias registrado para la clase, se podrá deserializar el objeto como una instancia de ExampleClass, y el resultado del código dará como resultado true. Si se eliminase la llamada a registerClassAlias(), el código daría como resultado false.
package {
    import flash.display.Sprite;
    import flash.net.registerClassAlias;
    import flash.utils.ByteArray;

    public class RegisterClassAliasExample extends Sprite {
        public function RegisterClassAliasExample() {
            registerClassAlias("com.example.eg", ExampleClass);
            var eg1:ExampleClass = new ExampleClass();
            var ba:ByteArray = new ByteArray();
            ba.writeObject(eg1);
            ba.position = 0;
            var eg2:* = ba.readObject();
            trace(eg2 is ExampleClass); // true
        }
    }
}

class ExampleClass {}
sendToURL()función 
public function sendToURL(request:URLRequest):void

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Envía una solicitud URL a un servidor, pero ignora cualquier respuesta.

Para examinar la respuesta del servidor, utilice el método URLLoader.load().

En Flash Player 9 y versiones posteriores, se puede impedir que un archivo SWF utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.

Para más información, consulte el documento técnico sobre la seguridad de Flash Player 9 en http://www.adobe.com/go/fp9_0_security_es.

Parámetros

request:URLRequest — Un objeto URLRequest que especifica la URL a la que se van a enviar datos.


Emite
SecurityError — Los archivos SWF locales que no son de confianza no pueden comunicarse en Internet. Puede solucionar este problema reclasificando el archivo SWF como archivo local de red o archivo de confianza.

Véase también


Ejemplo

En el ejemplo siguiente, se transfieren los datos de una sesión de usuario, capturados en un objeto URLVariables, a la aplicación de http://www.yourDomain.com/application.jsp.
 package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.net.URLVariables;
    import flash.net.sendToURL;

    public class SendToURLExample extends Sprite {

        public function SendToURLExample() {
            var url:String = "http://www.yourDomain.com/application.jsp";
            var variables:URLVariables = new URLVariables();
            variables.sessionId = new Date().getTime();
            variables.userLabel = "Your Name";

            var request:URLRequest = new URLRequest(url);
            request.data = variables;
            trace("sendToURL: " + request.url + "?" + request.data);
            try {
                sendToURL(request);
            }
            catch (e:Error) {
                // handle error here
            }
        }
    }
}

 

Enviarme un mensaje de correo electrónico cuando se añadan comentarios a esta página | Informe de comentarios

Página actual: http://livedocs.adobe.com/flash/9.0_es/ActionScriptLangRefV3/flash/net/package.html