Flash 8 Documentation

ActionScript 2.0 Language Reference > ActionScript classes > Array > sort (Array.sort method)

sort (Array.sort method)

Sorts the elements in an array. Flash sorts according to Unicode values. (ASCII is a subset of Unicode.)

By default, Array.sort() works as described in the following list:

• Sorting is case-sensitive (Z precedes a).
• Sorting is ascending (a precedes b).
• The array is modified to reflect the sort order; multiple elements that have identical sort fields are placed consecutively in the sorted array in no particular order.
• Numeric fields are sorted as if they were strings, so 100 precedes 99, because "1" is a lower string value than "9".

If you want to sort an array by using settings that deviate from the default settings, you can either use one of the sorting options described in the entry for the options parameter or you can create your own custom function to do the sorting. If you create a custom function, you can use it by calling the sort() method, using the name of your custom function as the first parameter (compareFunction).

Availability: ActionScript 1.0; Flash Player 5 - Array sorting option added in Flash Player 7.

Parameters

compareFunction:Object [optional] - A comparison function used to determine the sorting order of elements in an array. Given the elements A and B, the result of compareFunction can have one of the following three values:

• -1, if A should appear before B in the sorted sequence
• 0, if A equals B
• 1, if A should appear after B in the sorted sequence

options:Number [optional] - One or more numbers or names of defined constants, separated by the | (bitwise OR) operator, that change the behavior of the sort from the default. The following values are acceptable for the options parameter:

• Array.CASEINSENSITIVE or 1
• Array.DESCENDING or 2
• Array.UNIQUESORT or 4
• Array.RETURNINDEXEDARRAY or 8
• Array.NUMERIC or 16

For more information about this parameter, see the Array.sortOn() method.

Note: Array.sort() is defined in ECMA-262, but the array sorting options introduced in Flash Player 7 are Flash-specific extensions to the ECMA-262 specification.

Returns

Array - The return value depends on whether you pass any parameters, as described in the following list:

• If you specify a value of 4 or Array.UNIQUESORT for the options parameter and two or more elements being sorted have identical sort fields, Flash returns a value of 0 and does not modify the array.
• If you specify a value of 8 or Array.RETURNINDEXEDARRAY for the options parameter, Flash returns an array that reflects the results of the sort and does not modify the array.
• Otherwise, Flash returns nothing and modifies the array to reflect the sort order.

Example

Usage 1: The following example shows the use of Array.sort() with and without a value passed for options:

var fruits_array:Array = new Array("oranges", "apples", "strawberries", "pineapples", "cherries");
trace(fruits_array); // Displays oranges,apples,strawberries,pineapples,cherries.
fruits_array.sort();
trace(fruits_array); // Displays apples,cherries,oranges,pineapples,strawberries.
trace(fruits_array); // Writes apples,cherries,oranges,pineapples,strawberries.
fruits_array.sort(Array.DESCENDING);
trace(fruits_array); // Displays strawberries,pineapples,oranges,cherries,apples.
trace(fruits_array); // Writes strawberries,pineapples,oranges,cherries,apples.

Usage 2: The following example uses Array.sort() with a compare function. The entries are sorted in the form name:password. Sort using only the name part of the entry as a key:

var passwords_array:Array = new Array("mom:glam", "ana:ring", "jay:mag", "anne:home", "regina:silly");
function order(a, b):Number {
    var name1:String = a.split(":")[0];
    var name2:String = b.split(":")[0];
    if (name1<name2) {
    return -1;
    } else if (name1>name2) {
    return 1;
    } else {
    return 0;
    }
}
trace("Unsorted:");
//Displays Unsorted:
trace(passwords_array);
//Displays mom:glam,ana:ring,jay:mag,anne:home,regina:silly.
//Writes mom:glam,ana:ring,jay:mag,anne:home,regina:silly
passwords_array.sort(order);
trace("Sorted:");
//Displays Sorted:
trace(passwords_array);
//Displays ana:ring,anne:home,jay:mag,mom:glam,regina:silly.
//Writes ana:ring,anne:home,jay:mag,mom:glam,regina:silly.

See also

| bitwise OR operator, sortOn (Array.sortOn method)

Version 8

Comments

Add Comment

matmal said on Feb 12, 2006 at 6:11 AM :

In my opinion this function doesn't work right. I tried to implement my own Array.max and Array.min functions and it turned out that Array.sort() doesn't work ok. Here is the code, paste it in Action window and execute it.

Is there something wrong I am doing or it is in fact a faulty function?

// CODE

var arr:Array = [36, 36, 36, 37, 40, 40, 43, 45, 45, 156, 164, 164];
Array.prototype.min = function() {
return (this.sort(Array.DESCENDING))[0];
};
Array.prototype.max = function() {
return (this.sort())[0];
}
trace("Base_Array: "+arr);
trace("Array sorted ASCENDING: "+arr.sort());
trace("Array.max: "+arr.max());
trace("Array sorted DESCENDING: "+arr.sort(Array.DESCENDING));
trace("Array.min: "+arr.min());

// END OF CODE

Output:

Base_Array: 36,36,36,37,40,40,43,45,45,156,164,164
Array sorted ASCENDING: 156,164,164,36,36,36,37,40,40,43,45,45
Array.max: 156
Array sorted DESCENDING: 45,45,43,40,40,37,36,36,36,164,164,156
Array.min: 45

Francis Cheng said on Feb 12, 2006 at 10:08 PM :

The sort() method is string-based, which is why "156" appears before "36" in the sorted array. You must use the NUMERIC option to sort numerically. If you add the NUMERIC option to each of your calls to sort(), you will get the expected results. For example:

arr.sort(Array.NUMERIC);
arr.sort(Array.DESCENDING | Array.NUMERIC)

RSS feed | Send me an e-mail when comments are added to this page | Comment Report

Current page: http://livedocs.adobe.com/flash/8/main/00001915.html

Add Comment