cfdocumentitem

Description

Specifies action items for a PDF or FlashPaper document created by the cfdocument tag. Actions include the following:

Page break
Header
Footer

Syntax

<cfdocument ...>
Syntax 1
<cfdocumentitem type = "pagebreak"/>

Syntax 2
   <cfdocumentitem 
      type = "header" or "footer">
header/footer text
</cfdocumentitem>

</cfdocument>

History

ColdFusion MX 7: Added this tag.

Attributes

Attribute Req/Opt Default Description

Attribute	Req/Opt	Default	Description
type	Required		Specifies the action: pagebreak: start a new page at the location of the tag. header: use the text between the `<cfdocumentitem>` and `</cfdocumentitem>` tags as the running header. footer: use the text between the `<cfdocumentitem>` and `</cfdocumentitem>` tags as the running footer.

type

Required

Specifies the action:

pagebreak: start a new page at the location of the tag.
header: use the text between the <cfdocumentitem> and </cfdocumentitem> tags as the running header.
footer: use the text between the <cfdocumentitem> and </cfdocumentitem> tags as the running footer.

Usage

Use the cfdocumentitem tag to control the formatting of a PDF or FlashPaper report. This tag must be wrapped inside a <cfdocument> </cfdocument> pair.

Write code for one cfdocumentitem tag for each pagebreak, running header, or running footer.

You can use the cfdocument scope variable, cfdocument.currentpagenumber, to display the current page number in a header or footer. You can also use cfdocument.totalpagecount to display the total number of pages. For example:

...
<cfdocumentItem type= "footer>
   #cfdocument.currentpagenumber# of #cfdocument.totalpagecount#
</cfdocumentitem>

You can use cfdocumentitem tags with or without the cfdocumentsection tag, as follows:

Without cfdocumentsection The cfdocumentitem attribute applies to the entire document, as follows:

If the tag is at the top of the document, it applies to the entire document.
If the tag is in the middle of the document, it applies to the rest of the document.
If the tag is at the end of the document, it has no affect.

With cfdocumentsection tags The cfdocumentitem attribute applies only to the section and overrides previously specified header and footer specifications.

Example

<cfquery datasource="cfdocexamples" name="parksQuery">
SELECT parkname, suptmgr from parks
</cfquery>

<cfdocument format="PDF">
  <cfdocumentitem type="header">National Parks Report</cfdocumentitem>
  <!--- Use a footer with current page of totalpages format --->
  <cfdocumentitem type="footer">
    <cfoutput>Page #cfdocument.currentpagenumber# of #cfdocument.totalpagecount#</cfoutput>
 </cfdocumentitem>

<h1>Park list</h1>
<table width="95%" border="2" cellspacing="2" cellpadding="2" >
  <tr >
    <th>Park</th>
    <th>Manager</th>
  </tr>
 <cfoutput query="parksQuery">
   <tr>
    <td><font size="-1">#parkname#</font></td>
    <td><font size="-1">#suptmgr#</font></td>
   </tr>
 </cfoutput>
</table>
</cfdocument>

Version 7

Comments

Solas said on Apr 5, 2005 at 3:08 PM :

<style type="text/css">
@import url(/Assets/Stylesheet.css);
</style>

I just used that text and I got around it. The cfinclude didn't work when I tried. Then I realized that it needed to be in a <style..> tag .. then I realized I can just use the tag itself.

jshuusko said on Aug 12, 2005 at 5:53 AM :

LyndoPatton said: If <cfdocumentitem type="header"> is used it overwrites data in the body of the document.

You need to adjust the margitop attribute of <cfdocument> -tag to fit with your header element.

RSS feed | Send me an e-mail when comments are added to this page | Comment Report

Current page: http://livedocs.adobe.com/coldfusion/7/htmldocs/00000237.htm