The MIME content type of any POST data.

Note:The FileReference.upload() and FileReference.download() methods do not support the URLRequest.contentType parameter.

An object containing data to be transmitted with the URL request.

This property is used with the method property. If the value of URLRequest.method is POST, the data is transmitted with the URLRequest object with the HTTP POST method.

If the value of URLRequest.method is GET, the data defines variables to be sent with the URLRequest object with the HTTP GET method.

The URLRequest API offers binary POST support and support for URL-encoded variables, as well as support for strings. The data object can be of ByteArray, URLVariables, or String type.

The way in which the data is used depends on the type of object used:

• If the object is a ByteArray object, the binary data of the ByteArray object is used as POST data. For GET, data of ByteArray type is not supported. Also, data of ByteArray type is not supported for FileReference.upload() and FileReference.download().
• If the object is a URLVariables object and the method is POST, the variables are encoded using x-www-form-urlencoded format and the resulting string is used as POST data. An exception is a call to FileReference.upload(), in which the variables are sent as separate fields in a multipart/form-data post.
• If the object is a URLVariables object and the method is GET, the URLVariables object defines variables to be sent with the URLRequest object.
• Otherwise, the object is converted to a string, and the string is used as the POST or GET data.

This data is not sent until a method, such as navigateToURL() or FileReference.upload(), uses the URLRequest object.

See also

Highlights of the example follow:

1. The constructor function creates a URLRequest instance named request, taking the URL of the remote application as a parameter.
2. A URLVariables object is created and two of its properties are assigned values.
3. The URLVariables object is assigned to the data property of the URLRequest object.
4. The example calls navigateToURL, which opens a new browser window to the remote application's URL.

Note: To run the example, the remote application URL in the example must be replaced with a working URL. Additionally, you would need server code to process the information captured by Flash Player in the URLVariables object.

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Specifies whether redirects are to be followed (true) or not (false).

The default value is true.

Specifies whether the HTTP protocol stack should manage cookies for this request. When true, cookies are added to the request and response cookies are remembered. If false, cookies are not added to the request and response cookies are not remembered, but users can manage cookies themselves by direct header manipulation.

On Mac OS, cookies are shared with Safari. To clear cookies on Mac OS:

1. Open Safari.
2. Select Safari | Preferences, and click the Security panel.
3. Click the Show Cookies button
.
4. Click the Reomove All button.

To clear cookies on Windows:

1. Open the Internet Properties control panel, and click the General tab.
2. Click the Delete Cookies button.

The default value is true.

Controls the HTTP form submission method.

For SWF content running in Flash Player (in the browser), this property is limitted to GET or POST operation, and valid values are URLRequestMethod.GET or URLRequestMethod.POST. For content running in the Apollo runtime, if the content is in the application security domain, you can use any string value; otherwise (if the content is not in the Apollo application security domain) you are still restricted to using GET or POST.

The default value is URLRequestMethod.GET.

See also

Highlights of the example follow:

1. The constructor function creates a URLRequest instance named request, taking the URL of the remote application as a parameter.
2. A URLVariables object is created and two of its properties are assigned values.
3. The URLVariables object is assigned to the data property of the URLRequest object.
4. The value of the URLRequest.method property is set to URLRequestMethod.POST.
5. The example calls navigateToURL, which opens a new browser window to the remote application's URL.

Note: To run the example, the remote application URL in the example must be replaced with a working URL. Additionally, you would need server code to process the information captured by Flash Player in the URLVariables object.

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

The array of HTTP request headers to be appended to the HTTP request. The array is composed of URLRequestHeader objects. Each object in the array must be a URLRequestHeader object that contains a name string and a value string, as follows:

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
  

Flash Player imposes certain restrictions on request headers; for more information, see the URLRequestHeader class description.

The FileReference.upload() and FileReference.download() methods do not support the URLRequest.requestHeaders parameter.

See also

Specifies whether authentication requests should be handled (true or not (false) for this request. If false, authentication challenges return an HTTP error.

The supported authentication methods are:

• Windows—HTTP Basic/Digest, Windows Integrate Authentication (including NTLM, Kerberos, and Passport), SSL Certificate Authentication.
• Mac—HTTP Basic/Digest, NTLM, Kerberos, SSL Certificate Authentication.

The default value is true.

Specifies whether successful response data should be cached for this request.

The default value is true.

The URL to be requested.

For content running in Flash Player, by default, the URL must be in exactly the same domain as the calling SWF file, including subdomains. For example, SWF files at www.adobe.com and store.adobe.com are in different domains. To load data from a different domain, put a cross-domain policy file on the server that is hosting the SWF file. For more information, see the security documentation described in the URLRequest class description.

For content running in Apollo, files in the application security domain — files installed with the Apollo application — can access URLs using any of the following URL schemes:

• http and https
• file
• app-storage
• app-resource

Content running in Apollo that is not in the application security domain observes the same restrictions as content running in Flash Player (in the browser), and loading is governed by the content's domain and any permissions granted in cross-domain policy files.

Specifies whether the local cache should be consulted before this URLRequest fetches data.

The default value is true.

Specifies the user-agent string to be used in the HTTP request.

The default value is the same string used by Flash Player, which is different on Mac and Windows.

Creates a URLRequest object. If System.useCodePage is true, the request is encoded using the system code page, rather than Unicode. If System.useCodePage is false, the request is encoded using Unicode, rather than the system code page.

See also

To run this example, place a file named XMLFile.xml in the same directory as your SWF file.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}