Returns the number of bytes of data available for reading in the input buffer. User code must call bytesAvailable to ensure that sufficient data is available before trying to read it with one of the read methods.

The byte order for the data, either the BIG_ENDIAN or LITTLE_ENDIAN constant from the Endian class.

Used to determine whether the AMF3 or AMF0 format is used when writing or reading binary data using the readObject() or writeObject() method. The value is a constant from the ObjectEncoding class. By default, the AMF3 format is used.

See also

The current position in the file. This value is modified in any of the following ways:

• When you set the property explicitly
• When reading from the FileStream object (with one of the read methods)
• When writing to the FileStream object

The position is defined as a Number (instead of uint) in order to support files larger than 2³² bytes in length. The value of this property is always a whole number less than 2⁵³. If you set this value to a number with a fractional component, the value is rounded down to the nearest integer.

When reading files asynchronously, the amount of data requested.

This property determines how much data an asynchronous stream will attempt to read beyond the current position. The default value of this property is infinity: by default a file opened to read asynchronously will read as far as the end of the file.

Reading data from the read buffer does not change the value of the readAhead property. When you read data from the buffer, new data is read in to refill the read buffer.

The readAhead property has no effect on files opened synchronously.

As data is read in asynchronously, the FileStream object dispatches progress events. In the event handler method for the progress event, check to see that the required number of bytes are available (by checking the bytesAvailable property), and then read the data from the read buffer by using a read method.

import flash.filesystem.*;

var file:File = File.documentsDirectory.resolve("Apollo Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.readAhead = 100;
fileStream.addEventListener(ProgressEvent.PROGRESS, readProgressHandler)
fileStream.openAsync(file, FileMode.READ);
var results:ByteArray;

function readProgressHandler(event:ProgressEvent):void {
    if (fileStream.bytesAvailable >= 100) {
        fileStream.readBytes(results, 0, 100);
    }
}

Creates a FileStream object. Use the open() or openAsync() method to open a file.

See also

Closes the FileStream object. You cannot read or write any data after you call the close() method. If the file was opened asynchronously (the FileStream object used the openAsync() to open the file), calling the close() method causes the object to dispatch the close event.

Closing the application automatically closes all files associated with FileStream objects in the application. However, it is best to register for a closed event on all FileStream objects opened asynchronously that have pending data to write, before closing the application (to ensure that data is written).

You can reuse the FileStream object by calling the open() or the openAsync() method. This will close any file associated with the FileStream object, but the object does not dispatch the close event.

For a FileStream object opened asynchronously (using the openAsync() method), even if you call the close() event for a FileStream object and delete properties and variables that reference the object, the FileStream object is not garbage collected as long as there are pending operations and event handlers are registered for their completion. In particular, an otherwise unreferenced FileStream object will persist as long as any of the following are still possible:

• For file reading operations, the end of the file has not been reached (and the complete event has not been dispatched).
• Output data is still available to written, and output-related events (such as the outputProgress event or the ioError event) have registered event listeners.

See also

import flash.filesystem.*;
import flash.events.Event;
            
var file:File = File.documentsDirectory;
file = file.resolve("Apollo Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.openAsync(file, FileMode.WRITE);
fileStream.writeUTFBytes("Hello");
fileStream.addEventListener(Event.CLOSE, fileClosed);
fileStream.close();

function fileClosed(event:Event):void {
    trace("closed");
}

import flash.filesystem.*;
            
var file:File = File.documentsDirectory;
file = file.resolve("Apollo Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF("Hello");
fileStream.close();

Opens the FileStream object synchronously, pointing to the specified file. If the FileStream object is already open, calling the method closes the file before opening and no further events (including close) are delivered for the previously-opened file.

On systems that support file locking, a file opened in "write" or "update" mode (FileMode.WRITE or FileMode.UPDATE) is not readable as until it is closed.

See also

import flash.filesystem.*;

var file:File = File.documentsDirectory;
file = file.resolve("Apollo Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);
fileStream.close();

Opens the FileStream object asynchronously, pointing to the specified file. If the FileStream object is already open, calling the method closes the file before opening and no further events (including close) are delivered for the previously-opened file.

If the fileMode parameter is set to FileMode.READ or FileMode.UPDATE, Apollo reads data into the input buffer as soon as the file is opened, and progress and open events are dispatched as the data is read to the input buffer.

On systems that support file locking, a file opened in "write" or "update" mode (FileMode.WRITE or FileMode.UPDATE) is not readable as until it is closed.

See also

import flash.filesystem.*;
import flash.events.Event;

var file:File = File.documentsDirectory;
file = file.resolve("Apollo Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.addEventListener(Event.COMPLETE, fileCompleteHandler)
fileStream.openAsync(file, FileMode.READ);

function fileCompleteHandler(event:Event):void {
    var str:String = fileStream.readMultiByte(fileStream.bytesAvailable, File.systemCharset);
    trace(str);
    fileStream.close();
}

Reads a Boolean value from the file stream, byte stream, or byte array. A single byte is read, and true is returned if the byte is nonzero, false otherwise.

Reads a signed byte from the file stream, byte stream, or byte array.

Reads the number of data bytes, specified by the length parameter, from the file stream, byte stream, or byte array. The bytes are read into the ByteArray objected specified by the bytes parameter, starting at the position specified by offset.

Reads an IEEE 754 double-precision floating point number from the file stream, byte stream, or byte array.

Reads an IEEE 754 single-precision floating point number from the file stream, byte stream, or byte array.

Reads a signed 32-bit integer from the file stream, byte stream, or byte array.

Reads a multibyte string of specified length from the file stream, byte stream, or byte array using the specified character set.

See also

Reads an object from the file stream, byte stream, or byte array, encoded in AMF serialized format.

Reads a signed 16-bit integer from the file stream, byte stream, or byte array.

Reads an unsigned byte from the file stream, byte stream, or byte array.

Reads an unsigned 32-bit integer from the file stream, byte stream, or byte array.

Reads an unsigned 16-bit integer from the file stream, byte stream, or byte array.

Reads a UTF-8 string from the file stream, byte stream, or byte array. The string is assumed to be prefixed with an unsigned short indicating the length in bytes.

This method is similar to the readUTF() method in the Java IDataInput interface.

Reads a sequence of length UTF-8 bytes from the file stream, byte stream, or byte array, and returns a string.

Truncates the file at the position specified by the position property of the FileStream object. Bytes from the position specified by the position property to the end of the file are deleted. The file must be open for writing.

See also

import flash.filesystem.*;

var file:File = File.documentsDirectory;
file = file.resolve("Apollo Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.UPDATE);
if (file.size > 100) {
    fileStream.position = 100;
    fileStream.truncate();
}
fileStream.close();

var file:File = File.documentsDirectory;
file = file.resolve("Apollo Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.openAsync(file, FileMode.UPDATE);
trace("start", file.size)
if (file.size > 100) {
    fileStream.position = 100;
    fileStream.truncate();
}
fileStream.addEventListener(Event.CLOSE, fileClosed);
fileStream.close();
function fileClosed(event:Event):void {
    trace("closed", file.size); 
}

Writes a Boolean value. A single byte is written according to the value parameter, either 1 if true or 0 if false.

Writes a byte. The low 8 bits of the parameter are used. The high 24 bits are ignored.

Writes a sequence of length bytes from the specified byte array, bytes, starting offset(zero-based index) bytes into the file stream, byte stream, or byte array.

If the length parameter is omitted, the default length of 0 is used; Flash Player writes the entire buffer starting at offset. If the offset parameter is also omitted, the entire buffer is written.

If the offset or length parameter is out of range, they are clamped to the beginning and end of the bytes array.

Writes an IEEE 754 double-precision (64-bit) floating point number.

Writes an IEEE 754 single-precision (32-bit) floating point number.

Writes a 32-bit signed integer.

Writes a multibyte string to the file stream, byte stream, or byte array, using the specified character set.

See also

Writes an object to the file stream, byte stream, or byte array, in AMF serialized format.

Writes a 16-bit integer. The low 16 bits of the parameter are used. The high 16 bits are ignored.

Writes a 32-bit unsigned integer.

Writes a UTF-8 string to the file stream, byte stream, or byte array. The length of the UTF-8 string in bytes is written first, as a 16-bit integer, followed by the bytes representing the characters of the string.

Writes a UTF-8 string. Similar to writeUTF(), but does not prefix the string with a 16-bit length word.

Indicates that the stream has been closed by an explicit call to the close() method.

Defines the value of the type property of a close event object.

This event has the following properties:

See also

Signals that the end of the stream has been reached.

Defines the value of the type property of a complete event object.

This event has the following properties:

See also

Indicates that an error occurred during an asynchronous file I/O operation.

Defines the value of the type property of an ioError event object.

This event has the following properties:

Signals that buffered data has been written to the file.

Signals the availability of new data on the stream.

Defines the value of the type property of a progress event object.

This event has the following properties: