The key code value of the key pressed to trigger a keyFocusChange event.

A reference to the complementary InteractiveObject instance that is affected by the change in focus. For example, when a focusOut event occurs, the relatedObject represents the InteractiveObject instance that has gained focus.

Indicates whether the Shift key modifier is activated, in which case the value is true. Otherwise, the value is false. This property is used only if the FocusEvent is of type keyFocusChange.

Creates an Event object with specific information relevant to focus events. Event objects are passed as parameters to event listeners.

See also

Creates a copy of the FocusEvent object and sets the value of each property to match that of the original.

Returns a string that contains all the properties of the FocusEvent object. The string is in the following format:

[FocusEvent type=value bubbles=value cancelable=value relatedObject=value shiftKey=value]

Defines the value of the type property of a focusIn event object.

This event has the following properties:

See also

Defines the value of the type property of a focusOut event object.

This event has the following properties:

See also

Defines the value of the type property of a keyFocusChange event object.

This event has the following properties:

See also

Defines the value of the type property of a mouseFocusChange event object.

This event has the following properties:

See also

1. It declares the properties child (of type Sprite) and childCount (of type uint).
2. A for loop creates five light blue squares at (0,0). It begins by assigning child to a new CustomSprite instance. Each time a CustomSprite object is created, the following happens:
• The size property of type uint is set to 50 pixels and bgColor is set to light blue.
• The buttonMode and useHandCursor properties of the Sprite class are set to true within the constructor.
• An event listener of type click is instantiated, along with the associated subscriber clickHandler(). The subscriber method creates a local variable target of type Sprite and assigns it whichever box was clicked. The Stage's focus is then assigned to target.
• The draw() method is called, which creates a 50 x 50 pixel square by calling the beginFill(), drawRect(), and endFill() methods of the Graphics class and the instance properties.
3. In the for loop, the configureListeners() method is called, which instantiates three event listeners/subscribers:
• focusIn/focusInHandler() is dispatched after the click event for whichever display list object (box) is clicked.
• focusOut/focusOutHandler() is dispatched when another box is clicked or if the focus leaves the Stage (for example, by clicking outside Flash Player).
• keyFocusChange/keyFocusChangeHandler() is dispatched if you use the Tab key or the left-arrow or right-arrow keys to select a display list object. The keyFocusChangeHandler() method traps the left-arrow and right-arrow keys, however, and calls the preventDefault() method to disable them.
4. In the for loop, each square is added to the display list and displayed (all in the same area) by means of addChild().
5. The constructor then calls refreshLayout(), which distributes the orange squares across the top (y = 0) of the display with 5 pixels separating each square.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}